asp之FSO大全
<%
Function ShowDriveInfo(strFolder)'显示磁盘信息
'strRootFolder="/"
'strDrivInfo=ShowDriveInfo(strRootFolder)
'Response.Write(strDrivInfo)
Dim strTestFolder,objFSO,objDrive,strDriveInfo
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
strTestFolder=Server.Mappath(strFolder)
Set objDrive=objFSO.GetDrive(objFSO.GetDriveName(strTestFolder))
strDriveInfo="Web服务器根目录:"&objDrive.VolumeName&"<br>"
strDriveInfo=strDriveInfo&"磁盘代号:"&objDrive.DriveLetter&"<br>"
strDriveInfo=strDriveInfo&"磁盘序列号:"&objDrive.SerialNumber&"<br>"
strDriveInfo=strDriveInfo&"磁盘类型:"&objDrive.Drivetype&"<br>"
strDriveInfo=strDriveInfo&"文件系统:"&objDrive.FileSystem&"<br>"
strDriveInfo=strDriveInfo&"总容量:"&FormatNumber(objDrive.TotalSize/1024,0)&"KB<br>"
strDriveInfo=strDriveInfo&"可用空间:"&FormatNumber(objDrive.FreeSpace/1024,0)&"KB<br>"
ShowDriveInfo=strDriveInfo
set objDrive=nothing
set objFSO=nothing
end Function
Function ShowFolderList(strFolder)'显示Web服务器根目录和相关信息
Dim strTestFolder,objFSO,objRootFolder,objFolder,strFolderList
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
strTestFolder=Server.MapPath(strFolder)
Set objRootFolder=objFSO.Getfolder(strTestFolder)
For Each objFolder in objRootFolder.SubFolders
strFolderList=strFolderList&objFolder.name
strFolderList=strFolderList&"<br>"
Next
ShowFolderList=strFolderList
Set objRootFolder=Nothing
Set objFSO=Nothing
end Function
Function ShowFolderInfo(strFolder)'显示文件夹信息
Dim strTestFolder,objFSO,objFolder,strFolderInfo
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
strTestFolder=Server.MapPath(strFolder)
Set objFolder=ObjFSO.GetFolder(StrTestFolder)
strFolderInfo="Web服务器目录:"&UCase(strTestFolder)&"<br>"
strFolderInfo=strFolderInfo&"名称:"&objFolder.Name&"<br>"
strFolderInfo=strFolderInfo&"属性:"&objFolder.Attributes&"<br>"
strFolderInfo=strFolderInfo&"创建时间:"&objFolder.DateCreated&"<br>"
strFolderInfo=strFolderInfo&"访问时间:"&objFolder.DateLastAccessed&"<br>"
strFolderInfo=strFolderInfo&"修改时间:"&objFolder.DateLastModified&"<br>"
strFolderInfo=strFolderInfo&"大小:"&FormatNumber(objFolder.Size/1024,0)&"KB<br>"
ShowFolderInfo=strFolderInfo
Set objFolder=Nothing
Set objFSO=Nothing
End Function
Function CreateFolder(strFolder)'创建文件夹(返回值0,创建失败;1:创建成功)
Dim strTestFolder,objFSO
strTestFolder=Server.MapPath(CStr(strFolder))
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FolderExists(strtestFolder) Then
CreateFolder=0
Else
objFSO.CreateFolder(strTestFolder)
CreateFolder=1
End if
Set objFSO=Nothing
End Function
Function CheckFolderExists(strFolder)'检查文件夹是否存在(返回值0,不存在;1:存在)
Dim strTestFolder,objFSO
strTestFolder=Server.MapPath(CStr(strFolder))
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FolderExists(strTestFolder) Then
CheckFolderExists=1
Else
CheckFolderExists=0
End if
Set objFSO=Nothing
End Function
Function DeleteFolder(strFolder)'删除文件夹(返回值0,删除失败;1:删除成功)
Dim strTestFolder,objFSO
strTestFolder=Server.MapPath(CStr(strFolder))
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FolderExists(strtestFolder) Then
objFSO.DeleteFolder(strTestFolder)
DeleteFolder=1
Else
DeleteFolder=0
End if
Set objFSO=Nothing
End Function
Function MoveFolder(strFolder,strFolder1)'移动文件夹(返回值0,移动失败;1:移动成功)
Dim strTestFolder,strTestFolder1,objFSO
strTestFolder=Server.MapPath(CStr(strFolder))
strTestFolder1=Server.MapPath(CStr(strFolder1))
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FolderExists(strTestFolder) Then
If objFSO.FolderExists(strTestFolder1) Then
MoveFolder=0
Else
objFSO.MoveFolder strTestFolder,strTestFolder1
MoveFolder=1
End if
Else
MoveFolder=0
End if
Set objFSO=Nothing
End Function
Function CopyFolder(strFolder,strFolder1)'复制文件夹(返回值0,复制失败;1:复制成功)
Dim strTestFolder,strTestFolder1,objFSO
strTestFolder=Server.MapPath(CStr(strFolder))
strTestFolder1=Server.MapPath(CStr(strFolder1))
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FolderExists(strTestFolder) Then
If objFSO.FolderExists(strTestFolder1) Then
CopyFolder=0
Else
objFSO.CopyFolder strTestFolder,strTestFolder1
CopyFolder=1
End if
Else
CopyFolder=0
End if
Set objFSO=Nothing
End Function
Function ShowFileList(strFolder)'显示Web服务器目录的文件
Dim strTestFolder,objFSO,objFolder,objFile,strFileList
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
strTestFolder=Server.MapPath(strFolder)
Set objFolder=objFSO.GetFolder(strTestFolder)
For Each objFile in objFolder.Files
strFileList=strFileList&objFile.name
strFileList=strFileList&"<br>"
Next
ShowFileList=strFileList
Set objFolder=Nothing
Set objFSO=Nothing
End Function
Function ShowFileInfo(strFile)'显示文件信息
Dim objFSO,objFile,strFileInfo
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
strFile=Server.MapPath(strFile)
Set objFile=objFSO.GetFile(strFile)
strFileInfo="文件名:"&objFile.Name&"<br>"
strFileInfo=strFileInfo&"类型:"&objFile.Type&"<br>"
strFileInfo=strFileInfo&"位置:"&objFile.Path&"<br>"
strFileInfo=strFileInfo&"属性:"&objFile.Attributes&"<br>"
strFileInfo=strFileInfo&"创建时间:"&objFile.DateCreated&"<br>"
strFileInfo=strFileInfo&"访问时间:"&objFile.DateLastAccessed&"<br>"
strFileInfo=strFileInfo&"修改时间:"&objFile.DateLastModified&"<br>"
strFileInfo=strFileInfo&"大小:"&FormatNumber(objFile.Size/1024,0)&"KB<br>"
ShowFileInfo=strFileInfo
Set objFile=Nothing
Set objFSO=Nothing
End Function
Function CreateFile(strFile)'创建文件(返回值0,创建失败;1:创建成功)
Dim strTestFile,objFSO,objStream
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(strTestFile) Then
CreateFile=0
Else
Set objStream=objFSO.CreateTextFile(strTestFile,True)
CreateFile=1
Set objStream=Nothing
End if
Set objFSO=Nothing
End Function
Function CheckFileExists(strFile)'检查文件是否存在(返回值0,不存在;1:存在)
Dim strTestFile,objFSO
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(strTestFile) Then
CheckFileExists=1
Else
CheckFileExists=0
End if
Set objFSO=Nothing
End Function
Function DeleteFile(strFile)'删除文件(返回值0,删除失败;1:删除成功)
Dim strTestFile,objFSO,objFile
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(strTestFile) Then
Set objFile=objFSO.GetFile(strTestFile)
objFile.Delete
DeleteFile=1
Set objFile=Nothing
Else
DeleteFile=0
End if
Set objFSO=Nothing
End Function
Function MoveFile(strFile,strPath)'移动文件(返回值0,移动失败;1:移动成功)
Dim strTestFile,strTestPath,objFSO,objFile
strTestPath=Server.MapPath(strPath)
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(strTestFile) Then
Set objFile=objFSO.GetFile(strTestFile)
objFile.Move(strTestPath&"/"&objFile.Name)
MoveFile=1
Set objFile=Nothing
Else
MoveFile=0
End if
Set objFSO=Nothing
End Function
Function CopyFile(strFile,strPath)'复制文件(返回值0,复制失败;1:复制成功)
Dim strTestFile,strTestPath,objFSO,objFile
strTestPath=Server.MapPath(strPath)
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(strTestFile) Then
Set objFile=objFSO.GetFile(strTestFile)
objFile.Copy(strTestPath&"/"&objFile.Name)
CopyFile=1
Set objFile=Nothing
Else
CopyFile=0
End if
Set objFSO=Nothing
End Function
Function RanameFile(strFile,strNewFile)'重命名文件(返回值0,重命名失败;1:重命名成功)
'strFile为源文件,包括路径
'strNewFile重命名后的文件,只有文件名
Dim strTestFile,strTestPath,objFSO,objFile
strTestFile=Server.MapPath(strFile)
strTestPath=Left(strTestFile,InStrRev(strTestFile,"\"))
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(strTestFile) Then
Set objFile=objFSO.GetFile(strTestFile)
objFile.Move(strTestPath&strNewFile)
RanameFile=1
Set objFile=Nothing
Else
RanameFile=0
End if
Set objFSO=Nothing
End Function
Function ReadTextFile(strFile)'读取文件的内容
Dim strTestFile,objFSO,objInStream,ForReading
ForReading=1
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
Set objInStream=objFSO.OpenTextFile(strTestFile,ForReading,False,False)
ReadTextFile=objInStream.ReadAll
objInStream.Close
Set objInStream=Nothing
Set objFSO=Nothing
End Function
Sub SaveTextFile(strFile,strFileIn)'保存文件的内容
Dim strTestFile,objFSO,objOutStream,ForWriting
ForWriting=2
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
Set objOutStream=objFSO.OpenTextFile(strTestFile,ForWriting,True,False)
objOutStream.WriteLine(strFileIn)
objOutStream.Close
Set objOutStream=Nothing
Set objFSO=Nothing
End Sub
Sub AppendTextFile(strFile,strAppendLine)'添加文件的内容
Dim strTestFile,objFSO,objOutStream,ForAppending
ForAppending=8
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
Set objOutStream=objFSO.OpenTextFile(strTestFile,ForAppending,True,False)
objOutStream.WriteLine(strFileIn)
objOutStream.Close
Set objOutStream=Nothing
Set objFSO=Nothing
End Sub
Function SearchTextFile(strFile,strSearchText)'查找文本文件的字符串(返回值0,字符串不存在;1:字符串存在)
Dim strTestFile,objFSO,objInStream,strFileContents,isFound,ForReading
isFound=0
ForReading=1
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
Set objInStream=objFSO.OpenTextFile(strTestFile,ForReading,False,False)
strFileContents=objInStream.ReadALL
If InStr(1,strFileContents,strSearchText,1) Then
isFound=1
End if
objInStream.Close
Set objInStream=Nothing
Set objFSO=Nothing
SearchTextFile=isFound
End Function
Function ReplaceTextFile(strFile,strSearchText,strReplaceText)'查找和替换文本文件的字符串
Dim strTestFile,objFSO,objInStream,objOutStream,strFileContents,isFound,ForReading,ForWriting
Dim strInLine,strLeft,strRight,intPos,intBegin
isFound=0
ForReading=1
ForWriting=2
strTestFile=Server.MapPath(strFile)
Set objFSO=Server.CreateObject("Scripting.FileSystemObject")
Set objInStream=objFSO.OpenTextFile(strTestFile,ForReading,False,False)
strFileContents=""
Do while Not objInStream.AtEndOfStream
strInLine=objInstream.ReadLine
intPos=1
Do
intBegin=intPos
intPos=Instr(intBegin,strInLine,strSearchText,1)
If intPos>0 then
strLeft=Left(strInLine,intPos-1)
strRight=Right(strInLine,Len(strInline)-intPos-Len(strSearchText)+1)
strInLine=strLeft&strReplaceText&strRight
isFound=isFound+1
Else
strFileContents=strfileContents&strInLine&Chr(13)&Chr(10)
End if
Loop While intPos<>0
Loop
objInStream.Close
Set objInStream=Nothing
Set objOutStream=objFSO.OpenTextFile(strTestFile,ForWriting,True,False)
objOutStream.WriteLine(strFileContents)
objOutStream.Close
Set objOutStream=Nothing
Set objFSO=Nothing
ReplaceTextFile=isFound
End Function
%>
asp之FSO大全的更多相关文章
- ASP.NET资源大全-知识分享
API 框架 NancyFx:轻量.用于构建 HTTP 基础服务的非正式(low-ceremony)框架,基于.Net 及 Mono 平台.官网 ASP.NET WebAPI:快捷创建 HTTP 服务 ...
- ASP.NET资源大全-知识分享 【转载】
API 框架 NancyFx:轻量.用于构建 HTTP 基础服务的非正式(low-ceremony)框架,基于.Net 及 Mono 平台.官网 ASP.NET WebAPI:快捷创建 HTTP 服务 ...
- .NET初学者推荐课程 asp.net错误代码大全
错误 CS0001 编译器内部错误错误 CS0003 内存溢出错误 CS0004 提升为错误的警告错误 CS0005 编译器选项后应跟正确的参数错误 CS0006 找不到动态链接的元数据文件错误 CS ...
- 各种隐藏 WebShell、创建、删除畸形目录、特殊文件名、黑帽SEO作弊(转自核大大)
其实这个问题,经常有朋友问我,我也都帮大家解决了…… 但是现在这些现象越来越严重,而且手法毒辣.隐蔽.变态,清除了又来了,删掉了又恢复了,最后直接找不到文件了,但是访问网站还在,急的各大管理员.站长抓 ...
- CMS介绍
CMS介绍 CMS是Content Management System的缩写,意为“内容管理系统”,它具有许多基于模板的优秀设计,可以加快网站开发的速度和减少开发的成本. CMS的功能不仅限于处理文本 ...
- asp.net 操作Excel大全
asp.net 操作Excel大全 转:http://www.cnblogs.com/zhangchenliang/archive/2011/07/21/2112430.html 我们在做excel资 ...
- 【转】asp.net c# 网上搜集面试题目大全(附答案)
asp.net c# 网上搜集面试题目大全(附答案) http://www.cnblogs.com/hndy/articles/2234188.html
- ASP函数大全
ASP函数大全 Array() FUNCTION: 返回一个数组 SYNTAX: Array(list) ARGUMENTS: 字符,数字均可 EXAMPLE: <% Dim myArray() ...
- asp.net C# 时间格式大全
asp.net C# 时间格式大全DateTime dt = DateTime.Now;// Label1.Text = dt.ToString();//2005-11-5 13:21:25// ...
随机推荐
- 使用javassist运行时动态重新加载java类及其他替换选择
在不少的情况下,我们需要对生产中的系统进行问题排查,但是又不能重启应用,java应用不同于数据库的存储过程,至少到目前为止,还不能原生的支持随时进行编译替换,从这种角度来说,数据库比java的动态性要 ...
- Sass与Compress实战:第一章
1.消除冗余代码的方式: ▶通过变量来复用属性值 例如,一段冗余的CSS代码: h1#brand { color : #1875e7 } #sidebar { background-color : # ...
- 解决IOS下不支持fixed的问题
我们公司有一个页面底部用到了fixed样式,每当弹出键盘的时候,IOS下fixed就会走样(据我所知android没有该问题). 为此之前我经过产品的同意做了简单的处理(方法1). 方法一: focu ...
- aws部署从无到有
第一次进入aws控制台的时候傻眼了,密密麻麻的菜单都不知道该选哪一个.无从下手 查了好久才找到,就从EC2入手吧,点击后EC2后进入下面页面 点击启动实例,这个页面就亲切多了.不在像看天书了. 本人最 ...
- Java Object 构造方法的执行顺序
Java Object 构造方法的执行顺序 @author ixenos 为了使用类而做的准备工作包括三个步骤 1)加载:类加载器查找字节码(一般在classpath中找),从字节码创建一个Class ...
- 关于python的类方法、实例方法和静态方法区别
python的类方法需要在方法前面加装饰器:@classmethod ,静态方法是在方法前面加装饰器:@staticmethod. 类方法.类属性是属于类自身,属于类自身的命名空间,和实例方法.实例属 ...
- ftp资源调用迅雷下载
<script src='http://pstatic.xunlei.com/js/webThunderDetect.js'></script> <script src= ...
- LeetCode OJ 53. Maximum Subarray
Find the contiguous subarray within an array (containing at least one number) which has the largest ...
- Smarty自定义函数
自定义函数:<{方法名称}> 在html页面是可以直接赋值的:(没啥作用只是知道即可) <{$a = "hello"}><div><{$a ...
- go pkg
fmt Scanln用来读取输入数据 示例: package main import ( "fmt" "os" "time" ) func ...