CDS标准视图：设备功能位置变更历史 I_EQUIPINSTALLATIONHISTORYC

• 视图名称：I_EQUIPINSTALLATIONHISTORYC
• 视图类型：基础视图
• 视图代码：

点击查看代码

@EndUserText.label: 'Equipment Installation History - Cube'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'IEQUIDISMANTLEC'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE

@Analytics: {
  dataCategory: #CUBE,
  dataExtraction: {
    enabled: true,
    delta.byElement: {
      name: 'LastChangeDateTime',
      detectDeletedRecords: false
    }
  }
}

@ObjectModel: {
  usageType: {
    dataClass: #MIXED,
    serviceQuality: #C,
    sizeCategory: #XL
  }
}

@Metadata: {
  ignorePropagatedAnnotations,
  allowExtensions
}
@ObjectModel.supportedCapabilities: [#EXTRACTION_DATA_SOURCE]

-- covered with tcl_i_equidismantlec

define view I_EquipInstallationHistoryC
  as select from P_EquipmentInstallationHistory
  association [0..1] to I_UnitOfMeasure as _UnitOfMeasure on _UnitOfMeasure.UnitOfMeasure = $projection.UnitOfMeasure
  -- Extensions, do not expose as association:
  association [0..1] to E_Equipment     as _EquipmentExtension on _EquipmentExtension.Equipment = $projection.Equipment
{
      //P_EquipmentInstallationHistory
  key Equipment,
  key EquipUsagePeriodSequenceNumber,
      @Semantics.businessDate.to: false
  key ValidityEndDate,

      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,

      FunctionalLocation,
      SuperordinateEquipment,

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_UnitOfMeasure'
      cast( 'S' as meins )                                                               as UnitOfMeasure,

      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      --@Semantics.durationInSeconds: true
      cast( DurationInSeconds as bctinstdur )                                            as InstallationDurationInSeconds,
      @DefaultAggregation: #SUM
      cast( NumberOfInstallations as eam_num_inst_loc_changes )                          as NumberOfInstallationLocChanges,

      _Equipment,
      _UnitOfMeasure
}

• 事务代码：IE03/IH08
  
  设备功能位置变更历史

• 视图结构：

字段名称	设备名称
设备	EQUIPMENT
连续号码	EQUIPUSAGEPERIODSEQUENCENUMBER
有效期至	VALIDITYENDDATE
时戳	LASTCHANGEDATETIME
功能位置	FUNCTIONALLOCATION
上级设备	SUPERORDINATEEQUIPMENT
基本单位	UNITOFMEASURE
安装时间总数	INSTALLATIONDURATIONINSECONDS
安装位置变更数	NUMBEROFINSTALLATIONLOCCHANGES