Windows环境用Xampp自制证书(certificate), Chrome(版本 60.0.3112.90通过)

标题: Self signed certificate no longer valid as of Chrome 58
(Chrome58以后自制证书不再有效)
原文地址:
https://github.com/webpack/webpack-dev-server/issues/854

解决方法:
Xampp下载(XAMPP是最流行的PHP开发环境)
https://www.apachefriends.org/zh_cn/index.html

将这个bat文件
https://github.com/wilga/win-openssl-self-signed-san/blob/master/makeCert.bat
放到
X:\xampp\apache\bin
下
修改Line 10: SET HOSTNAME=example(自定义的域名)

保存后双击即可! 导入证书(放在受信任的根证书颁发机构下)

bat文件code:

 @echo off

 REM IN YOUR SSL FOLDER, SAVE THIS FILE AS: makeCERT.bat
 REM AT COMMAND LINE IN YOUR SSL FOLDER, RUN: makecert
 REM IT WILL CREATE THESE FILES: example.cnf, example.crt, example.key
 REM IMPORT THE .crt FILE INTO CHROME Trusted Root Certification Authorities
 REM REMEMBER TO RESTART APACHE OR NGINX AFTER YOU CONFIGURE FOR THESE FILES

 REM PLEASE UPDATE THE FOLLOWING VARIABLES FOR YOUR NEEDS.
 SET HOSTNAME=example
 SET DOT=com
 SET COUNTRY=US
 SET STATE=KS
 SET CITY=Olathe
 SET ORGANIZATION=IT
 SET ORGANIZATION_UNIT=IT Department
 SET EMAIL=webmaster@%HOSTNAME%.%DOT%

 (
 echo [req]
 echo default_bits = 2048
 echo prompt = no
 echo default_md = sha256
 echo x509_extensions = v3_req
 echo distinguished_name = dn
 echo:
 echo [dn]
 echo C = %COUNTRY%
 echo ST = %STATE%
 echo L = %CITY%
 echo O = %ORGANIZATION%
 echo OU = %ORGANIZATION_UNIT%
 echo emailAddress = %EMAIL%
 echo CN = %HOSTNAME%.%DOT%
 echo:
 echo [v3_req]
 echo subjectAltName = @alt_names
 echo:
 echo [alt_names]
 echo DNS.1 = *.%HOSTNAME%.%DOT%
 echo DNS.2 = %HOSTNAME%.%DOT%
 )>%HOSTNAME%.cnf

 openssl req -new -x509 -newkey rsa:2048 -sha256 -nodes -keyout %HOSTNAME%.key -days 3560 -out %HOSTNAME%.crt -config %HOSTNAME%.cnf

然后, 将生成的文件 拷贝到 X:\xampp\apache\conf\ssl.crt

重启Apache就可以了