ALV程序设计

ALV 全称SAP LIST VIEW, 是SAP所提供的一个强大的数据报表显示工具。

ALV显示格式分为GRID及LIST两种，两者所显示数据一致，

GRID模式在每个输出字段提供选择按钮，允许用 户自由设置显示格式，操作更为灵活。

LIST模式则固定输出格，适用于较严格的标准报表.

* ALV的属性设置及定义

在调用ALV之前，先要定义Layout的Fieldcat,他们同属于类型池SLIS,具体代码如下：

TYPE-POOLS:slis.
DATA:fieldcat TYPE slis_t_fieldcat_alv WITH HEADER LINE,
     layout   TYPE slis_layout_alv.

ALV的调用主要由以下几个标准函数实现（注意，所以函数的输入输出参数件必须大写，

否则系统会出现常中止），相关函数如下：

1）REUSE_ALV_FLELDCATALOG_MERGE:根据内表结构返回FIELDCAT字段结构信息，

其常用输入输出参数如下：

EXPORTING项：

* I_PROGRAM_NAME:程序名称

* I_INTERNAL_TABNAME:内表名称，必须为输出内表所自定义的STRUCTURE名；

* I_STRUCTURE_NAME:直接参考数据字典中所定义的透明表名或STRUCTURE名，

函数定义时I_INTERNAL_TABNAME或I_STRUCTURE_NAME参数只需一项；

CHANGING项：

* CT_FIELDCAT:导出FIELDCAT内表数据。

2）REUSE_ALV_GRID_DISPLAY/ REUSE_ALV_LIST_DISPLAY:输出ALV报表，

定义其为GEID模式还是LIST模式，两个函数的语法结构一样，其常用输入输出参数EXPORTIN如下：

* I_CALLBACK_PROGRAM:程序名称；

* IS_LAYOUT:程序所定义Layout名称；

* I_GRID_TITLE: 定义FIELDCAT数据；

* TABLES 项：定义输入内表数据；

* T_OUTTAB:输入所需显示的内表数据；

* IT_EVENTS:定义ALV输出事件；

* I_CALLBACK_PF_STATUS_SET:定义触发工具栏定义，通常为一子程序；

* I_CALLBACK_USER_COMMAND:其对应值一般为子程序名，在对ALV操作时触发所定义子程序（如某表字段的双击事件）；

3）Layout为一Structure，其主要字段定义及属性如下：

* EDIT:设置ALV是否为可编辑模式；

* Colwidth_optimize:将ALV字段宽度设置为最优化，按实际输出内容宽度自动匹配；

* NO_VLINE:输出ALV表格不显示垂直格式；

* NO_ULINE_HS:输出ALV表格不显示水平格线；

* INFO_FIELDNAME:设置颜色属性；

* KEY_HOTSPOT:设置关键字段执点；

* NO_COLNAME:是否显示字段名；

* ZEBRA:使ALV表格按斑马线间隔条纹方式显示，以便显示效果更美观；

* BOX_FIELDNAME:设置表格是否显示选择按钮字段；

* INFO_FIELDNAME:用于设置ALV输出报表每一行的颜色，其参数为输出内表的字段名称，要注意的是使用该属性需要同时在内表中定义一个与该参数所定义字段名相同的字段，例如：

layout-info_fieldname = 'COLOR'.

　　倘若其数据输出内表名为LT_OUT,则需要在该内表增加一字段"COLOR",并为内表每行复制，颜色参数范围C000~C999.例如：LT_OUT_COLOR = 'C500'.

4) Fieldcat主要属性介绍

* Key：将定义字段设置为Key值；

* ICON: 将定义字段以ICON的形式显示；

* CHECKBOX: 将定义字段以CHECKBOX的形式显示；

* JUST：定义字段对齐方式（R）RIGHT、（L）Left、（C）Center;

* IZERO: 將定义字段以前导的“0”的形式显示；

* NO_SIGN:将定义字段的符号设置为不显示；

* NO_ZERO:定义字段是否显示；

* EMPHASIZE:设置字段的颜色；

* DO_SUM:对字段进行汇总；

* SELTEXT_L/M/S :设置字段名称描述长、中、短；

* DDICTXT:设置字段显示字符串；

* HOTSPOT: 设置字段是否有热点（热点字段显示有下划线）。

例如：

REPORT  Y001.
TYPE-POOLS:SLIS.
DATA:FIELDCAT TYPE SLIS_T_FIELDCAT_ALV WITH HEADER LINE,
     LAYOUT TYPE SLIS_LAYOUT_ALV,
     W_REPID LIKE SY-REPID.

TABLES:SPFLI.
DATA:LSPFLI LIKE SPFLI OCCURS 0 WITH HEADER LINE.

*DATA:BEGIN OF LSPFLI OCCURS 0.
*  INCLUDE STRUCTURE SPFLI.
*DATA:END OF LSPFLI.

START-OF-SELECTION.
  PERFORM GETDATA.
  PERFORM CATALOG.
  PERFORM ALVSHOW.

*&---------------------------------------------------------------------*
*&      Form  GETDATA
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM GETDATA.
  SELECT * FROM SPFLI
    INTO CORRESPONDING FIELDS OF TABLE LSPFLI.
ENDFORM.                    "GETDATA

*&---------------------------------------------------------------------*
*&      Form  CATALOG
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM CATALOG.
  W_REPID = SY-REPID.
  CLEAR FIELDCAT.

CALL FUNCTION 'REUSE_ALV_FIELDCATALOG_MERGE'
    EXPORTING
      I_PROGRAM_NAME         = W_REPID
      I_STRUCTURE_NAME       = 'SPFLI'
    CHANGING
      CT_FIELDCAT            = FIELDCAT[]
    EXCEPTIONS
      INCONSISTENT_INTERFACE = 1
      PROGRAM_ERROR          = 2
      OTHERS                 = 3.

IF SY-SUBRC <> 0.
    MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
    WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.

* 对FieldCat属性的修改
  READ TABLE FIELDCAT INDEX 2."将第二列设为热点显示
  FIELDCAT-HOTSPOT = 'X'.
  MODIFY FIELDCAT INDEX 2.

READ TABLE FIELDCAT INDEX 4."将第四列设置为Key值字段
  FIELDCAT-KEY = 'X'.
  MODIFY FIELDCAT INDEX 4.

READ TABLE FIELDCAT INDEX 5."将第五列设置为checkBox
  FIELDCAT-CHECKBOX = 'X'.
  MODIFY FIELDCAT INDEX 5.

LAYOUT-COLWIDTH_OPTIMIZE = 'X'."设置LAYOUT输出格式最优化
ENDFORM.                    "CATALOG

*&---------------------------------------------------------------------*
*&      Form  ALVSHOW
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM ALVSHOW.
  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
    EXPORTING
      I_CALLBACK_PROGRAM = W_REPID
      IS_LAYOUT          = LAYOUT
      I_GRID_TITLE       = 'ALV PERPOST TEST'
      IT_FIELDCAT        = FIELDCAT[]
    TABLES
      T_OUTTAB           = LSPFLI
    EXCEPTIONS
      PROGRAM_ERROR      = 1
      OTHERS             = 2.

IF SY-SUBRC <> 0.
    MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
    WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
ENDFORM.                    "ALVSHOW