Blob分析之board.hdev

* board.hdev: Detection of missing solder
* 获取当前系统参数
get_system ('clip_region', Information)
*设置当前系统参数
set_system ('clip_region', 'true')
*关闭窗体更新
dev_update_window ('off')
*关闭窗体
dev_close_window ()
*打开新窗体
dev_open_window (0, 0, 512, 512, 'black', WindowID)
*读取图像
read_image (Images, ['ic0','ic1','ic2','ic3'])
*把多个单通道图像组合成一个单个多通道图像
channels_to_image (Images, Ic)
*选择第索引等于1的图像
select_obj (Images, Input1, 1)
*显示图像
dev_display (Input1)
*设置显示字体
set_display_font (WindowID, 14, 'mono', 'false', 'false')
*右下角显示 'Press Run (F5) to continue' 这个信息
disp_continue_message (WindowID, 'black', 'true')
stop ()
*选择第索引等于2的图像
select_obj (Images, Input2, 2)
dev_display (Input2)
disp_continue_message (WindowID, 'black', 'true')
stop ()
*选择第索引等于3的图像
select_obj (Images, Input3, 3)
*显示图像
dev_display (Input3)
*右下角显示 'Press Run (F5) to continue' 这个信息
disp_continue_message (WindowID, 'black', 'true')
stop ()
*选择第索引等于4的图像
select_obj (Images, Input4, 4)
*显示图像
dev_display (Input4)
*右下角显示 'Press Run (F5) to continue' 这个信息
disp_continue_message (WindowID, 'black', 'true')
stop ()
*求取多通道图像的平均通道图像
mean_n (Ic, ImageMean)
*显示图像
dev_display (ImageMean)
*阈值分割图像
threshold (Images, Darks, 0, 40)
*联合多个区域成一个区域
union1 (Darks, Dark)
*填充区域
fill_up (Dark, DarkFilled)
*设置显示颜色
dev_set_color ('green')
*显示填充图像
dev_display (DarkFilled)
*右下角显示 'Press Run (F5) to continue' 这个信息
disp_continue_message (WindowID, 'black', 'true')
stop ()
*阈值分割灰度值100-255的图像
threshold (Images, Lights, 100, 255)
*联合多个区域成一个区域
union1 (Lights, Light)
*求取相交区域
intersection (DarkFilled, Light, Intersection)
*显示图像
dev_display (ImageMean)
*显示相交区域
dev_display (Intersection)
*右下角显示 'Press Run (F5) to continue' 这个信息
disp_continue_message (WindowID, 'black', 'true')
stop ()
*求补集区域
complement (DarkFilled, Back)
*设置显示颜色为红色e
dev_set_color ('red')
*显示暗区域
dev_display (Back)
*右下角显示 'Press Run (F5) to continue' 这个信息
disp_continue_message (WindowID, 'black', 'true')
stop ()
*扩张区域，填充小间隙
expand_region (Intersection, Back, RegionExpanded, 10, 'image')
*填充区域
fill_up (RegionExpanded, Good)
*显示图像
dev_display (ImageMean)
dev_set_color ('green')
dev_display (Good)
*右下角显示 'Press Run (F5) to continue' 这个信息
disp_continue_message (WindowID, 'black', 'true')
stop ()
*求区域差集
difference (DarkFilled, Good, Rest)
*设置显示颜色为红色
dev_set_color ('red')
*显示图像
dev_display (Rest)
*右下角显示 'Press Run (F5) to continue' 这个信息
disp_continue_message (WindowID, 'black', 'true')
stop ()
*扩张灰度来填充区域之间的间隙
expand_gray (Rest, Ic, Good, Bad, 6, 'image', 5)
dev_display (Bad)
disp_continue_message (WindowID, 'black', 'true')
stop ()
*联通区域
connection (Bad, ConnectedBad)
*选择面积为150-99999的联通区域
select_shape (ConnectedBad, BigBad, 'area', 'and', 150, 99999)
*求取选择的区域面积和中心
area_center (BigBad, AreaBad, Row, Column)
*求取数量
count_obj (BigBad, NumMissingSolder)
*
AreaMissingSolder := sum(AreaBad)
*显示图像
dev_display (Images)
*设置显示颜色为绿色
dev_set_color ('green')
*设置显示填充形式，两种，margin表示边界，fill表示全部填充
dev_set_draw ('margin')
*设置线宽
dev_set_line_width (3)
*显示图像
dev_display (Good)
*设置显示颜色为红色
dev_set_color ('red')
*显示大斑点
dev_display (BigBad)
*设置显示填充形式，两种，margin表示边界，fill表示全部填充
dev_set_draw ('fill')
*设置线宽
dev_set_line_width (1)
*开启窗体更新
dev_update_window ('on')
*设置系统参数
set_system ('clip_region', Information)