删除空文件夹 清除CS扩展名文件 bat

删除空文件夹。删的干净。删的彻底。

将下列代码复制到txt中保存。并把后缀.txt命成.bat。然后运行即可。

方案１.xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

　　删除指定目录及其子目录下的空文件夹.bat

　　代码：

@echo off
echo.
echo 说明此工具会删除指定目录所在空文件夹及其子目录下的空文件夹，以节省空间．
echo.
echo.
echo 本例只限删除１０层内父子目录关系的所有空文件夹。
echo １０层以上请更改下面代码(1 1 10)中的１０数字即可．
echo.
set /p par=请输入空文件夹所在的盘符或目录（如d:\或d:\a\）,输入确认无误后请按回车：
echo.
echo       当前工作目录为： %par%
echo                               任意键   开始删除空文件夹
pause>nul
echo -----------------------------------------------------------------------------
for /l %%i in (1 1 10) do (
  for /f "delims=" %%a in ('dir /b/s/ad %par%') do (
     2>nul rd "%%a\"&&echo 成功删除空文件夹：%%a
  )
)
echo -----------------------------------------------------------------------------
echo    按任意键退出
pause>nul
exit

方案２.xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

　　删除当前所在目录及其子目录下的空文件夹.bat

　　代码：

@echo off
setlocal enabledelayedexpansion
mode con cols=80 lines=25
set /a sum=0
echo.
echo.
echo 删除当前所在目录及其子目录下10层内的所有空文件夹，以节省空间。
echo.
echo       当前工作目录为： %cd%
echo.
echo                                                   任意键   开始删除空文件夹
pause>nul
echo -----------------------------------------------------------------------------

for /l %%i in (1 1 10) do (
for /f "delims=" %%i in ('dir /ad /b /s') do (
dir /b "%%i"|findstr .>nul||rd "%%i"&&echo 成功删除空文件夹：%%i&&set /a sum=sum+1
)

)
echo -----------------------------------------------------------------------------
echo      共删除%cd%目录下 空文件夹个数：%sum%
echo.
echo.
echo    按任意键退出
pause>nul
set sum=
exit

方案３.xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

       删除指定目录及其子目录下的空文件夹.bat（安静版） 　　

　　此方案为方案１的特写。没有键盘输入提示。只更改代码。运行后后台安静运行。无界面提示。

　　代码：

@echo off
for /l %%i in (1 1 10)do (
  for /f "delims=" %%a in ('dir /b/s/ad "d:\a\"') do (
     2>nul rd "%%a\"
  )
)

注解：蓝色(1 1 10)其中的10指的是你目录中文件夹的层数。填写大于你文件夹的层数。例：d:\a\b\c\d 这里只有三层就到d了。所　　　以我们只要填４就可以了。一般十层也够多了。当然你也可填100。只不过运行速度稍有影响。

　　　蓝色d:\a\指的是你要删除空文件夹所在的目录。

           例：d:\ (删除d盘下。包括子父级内的所有空文件夹)  或者d:\a\　(删除d盘a目录下。包括子父级内的所有空文件夹)

xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx

删除cs扩展名文件。删的干净。删的彻底。

@ECHO OFF
@echo ===================================================================
@echo 清除svn,vss,cvs标记文件
@echo filename : clearSvnCvsVss.bat
@echo ===================================================================
@ECHO 按Ctrl + C取消。
@pause
@echo 执行批处理：%0 %1 %2 %3
@echo 转到：%1
cd /d %1

@echo (1)开始清除“.SVN”文件夹
@rem for /r %%d in (.) do if exist "%%d\.svn" echo /s /q "%%d\.svn"
@for /r %%d in (.) do if exist "%%d\.svn" rd /s /q "%%d\.svn"

@echo (2)开始清除CVS标记
@for /r %%d in (.) do if exist "%%d\CVS\Root" rd /s/q "%%d\CVS"

@echo (3)开始清除vssver.scc和vssver2.scc文件
attrib -s -h -r -a vssver?.scc /s
for /r . %%i in (vssver?.scc) do if exist %%i del %%i

@echo (4)开始清除VisualStudio中的VSS标记文件
attrib -s -h -r -a *.vssscc /s
attrib -s -h -r -a *.csproj.vspscc /s

for /r . %%i in (*.vssscc) do if exist %%i del %%i
for /r . %%i in (*.csproj.vspscc) do if exist %%i del %%i

@echo (5)开始清除cs,csproj,csproj.user,pdb,resx文件
del /S /F /Q *.cs
del /S /F /Q *.csproj
del /S /F /Q *.csproj.user
del /S /F /Q *.pdb
del /S /F /Q *.resx

@echo 删除完后请检查是否清楚干净。考虑不同的编码工具带有自己的特殊标志，可根据具体情况修改批处理文件中的命令行。
pause
exit