monkey测试小记

本篇中不记录环境搭建，只是介绍一些经验和小秘诀吧。

一、使用安卓模拟器进行测试。

　　在刚刚接触到monkey测试的时候，用的真机进行测试，点击几万次甚至更多的时候，发现系统变慢了。也许是错觉，但是系统经常自动打开音乐什么的，在上班的时候确实很尴尬。于是想到用安卓模拟器来进行测试。

　　开始准备安装安卓官方模拟器，各种配置，FQ不说，好不容易安装好了，发现启动超慢。度娘查询了一下，说是可以打开Intel虚拟加速，然而悲剧的发现，工作的电脑并不支持。

　　好吧，于是开始研究如何使用网上的一些第三方提供的模拟器。首先，瞄准了一款叫逍遥安卓的模拟器，这款模拟器个人感觉还是不错的，平常也使用它玩一些游戏。（下载地址可以度娘）

　　下载安装完成之后，使用如下命令，即可完成连接操作：adb connect 127.0.0.1:21503

　　好了，这就完成了。接下来，就可以安装测试的app以及开始Monkey测试了。再也不用担心乱点击消耗手机的寿命或者打开音乐会尴尬了

二、bat文件自动分析日志

　　我们在进行monkey测试的时候，会将日志写进文档中，但是查看人工查看日志，是不是感觉很麻烦呢？！而且有时候是正常的，找了半天发现并没有问题，有点浪费时间。于是想办法看有么有自动分析日志的。我大天朝人民是伟大的，还真有人分享，不用自己研究如何写，太好了。贴下来，给大家一起分享，作者名字在代码之中，吃水不忘挖井人。下面的代码复制保存为XXX.bat文件，将要分析的日志拖到bat文件上即可自动完成分析。

……………………………………………………分割线，下面是代码………………………………………………………………………………

@ECHO OFF
ECHO.:::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.:: 分析Monkey日志 ::
ECHO.:: 作者：Findyou ::
ECHO.:: 版本 V1.0.1 ::
ECHO.:: 时间：2014.08.26 ::
ECHO.:::::::::::::::::::::::::::::::::::::::::::::::::
REM 方法一：手动设置Monkey日志路径
SET monkeyLogFile=F:\Monkey\20140808\FindyouV1.0.0\20140825181801_monkey.log

REM 方法二：直接将Monkey日志拖到此bat文件上
IF NOT "%1"=="" SET monkeyLogFile=%1

ECHO.[ INFO ] Monkey日志: %monkeyLogFile%
ECHO.[ INFO ] 开始分析
SET blnException=0
ECHO.
ECHO.
REM 如果觉得分析太快，没有感觉，把下面注释去掉假装分析中，有停顿感
REM ping -n 2 127.0.0.1>nul

::ANR日志
FOR /F "delims=" %%a IN ('FINDSTR /C:"ANR" %monkeyLogFile%') DO ( 
SET strANR=%%a
)

::崩溃日志
FOR /F "delims=" %%a IN ('FINDSTR /C:"CRASH" %monkeyLogFile%') DO ( 
SET strCRASH=%%a
)

::异常日志
FOR /F "delims=" %%a IN ('FINDSTR /C:"Exception" %monkeyLogFile%') DO ( 
SET strException=%%a
)

::正常
FOR /F "delims=" %%a IN ('FINDSTR /C:"Monkey finished" %monkeyLogFile%') DO ( 
SET strFinished=%%a
)

IF NOT "%strANR%" == "" (
ECHO.[ INFO ] 分析Monkey日志存在: ANR
ECHO.[ INFO ] ------------------------------------
ECHO. "%strANR%"
SET /a blnException+=1
ECHO.
)

IF NOT "%strCRASH%" == "" (
ECHO.[ INFO ] 分析Monkey日志存在: CRASH
ECHO.[ INFO ] ------------------------------------
ECHO. "%strCRASH%"
SET /a blnException+=1
ECHO.
)

IF NOT "%strException%" == "" (
ECHO.[ INFO ] 分析Monkey日志存在: 异常
ECHO.[ INFO ] ------------------------------------
ECHO. "%strException%"
SET /a blnException+=1
)

IF NOT "%strFinished%" == "" (
ECHO.[ INFO ] 分析Monkey日志存在: 执行成功标记
ECHO.[ INFO ] ------------------------------------
ECHO. "%strFinished%"
ECHO.
) ELSE (
IF %blnException% EQU 0 ECHO.[ INFO ] 分析Monkey日志结果: Monkey执行异常中断，请重新执行Monkey脚本!
ECHO.
)

REM 如果blnException不为0，说明存在异常，改变字体为淡紫色
IF %blnException% NEQ 0 ( 
Color 0D
ECHO.[ INFO ] 分析Monkey日志结果:存在异常日志，请手工再仔细检查！
ECHO.
) ELSE (
ECHO.[ INFO ] 分析Monkey日志结果:正常
ECHO.
)
ECHO.
ECHO.[ EXIT ] 按任意键关闭窗口...
PAUSE>nul

………………………………………………………………………………………………………………………………………………

Ps：以前在公司的网站上写博客，头一次在博客园写博客，写的不好，大家看看即可，切勿喷我，谢谢大家。