ABAP 中 Table Control例子
实现了Table Control的主要的一些功能，可以作为例子参考，实现的功能有是否可编辑切换，选择某一条记录点击按钮显示详细信息，新增记录，删除记录，选择所有记录，选择光标所有记录，取消选择所有，排序，行选择栏位，列不可编辑，固定列，Table Control标题，分页功能，根据输入A字段的值显示B字段的值，某字段的值如果等于XXX就不可编辑等功能。相信这些功能已经可以满足大部份的开发了。
主程序代码：
DATA: ok_code TYPE sy-ucomm,
save_ok TYPE sy-ucomm.
DATA: l_field TYPE char50,
l_line TYPE i.
TYPES: BEGIN OF ty_spfli,
carrid TYPE spfli-carrid,
connid TYPE spfli-connid,
countryfr TYPE spfli-countryfr,
cityfrom TYPE spfli-cityfrom,
airpfrom TYPE spfli-airpfrom,
mask(1),
END OF ty_spfli.
DATA g_lines TYPE i.
DATA sp2 TYPE TABLE OF ty_spfli WITH HEADER LINE.
DATA sp1 TYPE ty_spfli.
SELECT * INTO CORRESPONDING FIELDS OF TABLE sp2 FROM spfli.
CONTROLS content TYPE TABLEVIEW USING SCREEN 100.
content-top_line = 1.
content-lines = LINES( sp2 ).
CALL SCREEN 100.
LOOP AT sp2.
WRITE: / sp2-carrid,sp2-connid,sp2-countryfr,sp2-cityfrom.
ENDLOOP.
*----------------------------------------------------------------------*
* MODULE status_0100 OUTPUT
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
MODULE status_0100 OUTPUT.
SET PF-STATUS 'STA'.
ENDMODULE. "status_0100 OUTPUT
*----------------------------------------------------------------------*
* MODULE user_command_0100 INPUT
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
MODULE user_command_0100 INPUT.
save_ok = ok_code.
CLEAR ok_code.
CASE save_ok.
WHEN 'EXIT'.
LEAVE TO SCREEN 0.
WHEN 'SWITH'.
PERFORM f_switch.
WHEN 'SORT_UP'.
PERFORM f_sort USING 'UP'.
WHEN 'SORT_DOWN'.
PERFORM f_sort USING 'DOWN'.
WHEN 'DETAIL'.
PERFORM f_detail.
WHEN 'P--'.
PERFORM f_page USING save_ok.
WHEN 'P-'.
PERFORM f_page USING save_ok.
WHEN 'P+'.
PERFORM f_page USING save_ok.
WHEN 'P++'.
PERFORM f_page USING save_ok.
WHEN 'SELECT'.
PERFORM f_select USING 'SELECT'.
WHEN 'BLOCK'.
PERFORM f_select USING 'BLOCK'.
WHEN 'DESELECT'.
PERFORM f_select USING 'DESELECT'.
WHEN 'INSERT'.
PERFORM f_row USING 'INSERT'.
WHEN 'DELETE'.
PERFORM f_row USING 'DELETE'.
ENDCASE.
ENDMODULE. "user_command_0100 INPUT
*----------------------------------------------------------------------*
* MODULE filltab OUTPUT
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
MODULE filltab OUTPUT.
READ TABLE sp2 INTO sp1 INDEX content-current_line.
ENDMODULE. "filltab OUTPUT
*----------------------------------------------------------------------*
* MODULE readtab INPUT
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
MODULE readtab INPUT.
g_lines = sy-loopc.
MODIFY sp2 FROM sp1 INDEX content-current_line.
ENDMODULE. "readtab INPUT
*----------------------------------------------------------------------*
* MODULE chang_val INPUT
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
MODULE chang_val INPUT.
DATA lwa_cols LIKE LINE OF content-cols.
LOOP AT content-cols INTO lwa_cols.
IF lwa_cols-screen-name = 'SP1-COUNTRYFR'
AND sp1-countryfr = 'AA'.
sp1-cityfrom = 'SDSDSD'.
MODIFY sp2 FROM sp1 INDEX content-current_line.
ENDIF.
ENDLOOP.
ENDMODULE. "chang_val INPUT
*----------------------------------------------------------------------*
* MODULE get_cursor INPUT
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
MODULE get_cursor INPUT.
GET CURSOR FIELD l_field LINE l_line.
ENDMODULE. "get_cursor INPUT
*----------------------------------------------------------------------*
* MODULE set_cursor OUTPUT
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
MODULE set_cursor OUTPUT.
SET CURSOR FIELD l_field LINE l_line.
ENDMODULE. "set_cursor OUTPUT
*----------------------------------------------------------------------*
* MODULE SET_EDITABLE
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
MODULE set_editable OUTPUT.
LOOP AT SCREEN.
IF screen-name = 'SP1-CITYFROM'.
IF sp1-cityfrom = 'SDSDSD'.
screen-input = 0.
MODIFY SCREEN.
ENDIF.
ENDIF.
ENDLOOP.
ENDMODULE. "SET_EDITABLE
*&---------------------------------------------------------------------*
*& Form f_page
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* -->CODE text
*----------------------------------------------------------------------*
FORM f_page USING code TYPE sy-ucomm.
DATA: i TYPE i,
j TYPE i.
CASE code.
WHEN 'P--'.
content-top_line = 1.
WHEN 'P-'.
content-top_line = content-top_line - g_lines.
IF content-top_line <= 0.
content-top_line = 1.
ENDIF.
WHEN 'P+'.
i = content-top_line + g_lines.
j = content-lines - g_lines + 1.
IF j <= 0.
j = 1.
ENDIF.
IF i <= j.
content-top_line = i.
ELSE.
content-top_line = j.
ENDIF.
WHEN 'P++'.
content-top_line = content-lines - g_lines + 1.
IF content-top_line <= 0.
content-top_line = 1.
ENDIF.
ENDCASE.
ENDFORM. "f_page
*&---------------------------------------------------------------------*
*& Form f_switch
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
FORM f_switch.
DATA lwa_cols LIKE LINE OF content-cols.
LOOP AT content-cols INTO lwa_cols WHERE index > 2.
IF lwa_cols-screen-input = 0.
lwa_cols-screen-input = 1.
ELSE.
lwa_cols-screen-input = 0.
ENDIF.
MODIFY content-cols FROM lwa_cols INDEX sy-tabix.
ENDLOOP.
ENDFORM. "f_switch
*&---------------------------------------------------------------------*
*& Form F_SORT
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* -->CODE text
*----------------------------------------------------------------------*
FORM f_sort USING code.
DATA: str1 TYPE string,
str2 TYPE string,
lwa_cols LIKE LINE OF content-cols.
READ TABLE content-cols INTO lwa_cols WITH KEY selected = 'X'.
IF sy-subrc = 0.
SPLIT lwa_cols-screen-name AT '-' INTO str1 str2.
IF code = 'UP'.
SORT sp2 STABLE BY (str2) ASCENDING.
ELSEIF code = 'DOWN'.
SORT sp2 STABLE BY (str2) DESCENDING.
ENDIF.
lwa_cols-selected = ''.
MODIFY content-cols FROM lwa_cols TRANSPORTING selected WHERE selected = 'X'.
ENDIF.
ENDFORM. "F_SORT
*&---------------------------------------------------------------------*
*& Form f_detail
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
FORM f_detail.
READ TABLE sp2 INTO sp1 WITH KEY mask = 'X'.
IF sy-subrc = 0 AND sp1-mask = 'X'.
CALL FUNCTION 'POPUP_TO_DISPLAY_TEXT'
EXPORTING
textline1 = sp1-carrid
textline2 = sp1-connid.
ENDIF.
ENDFORM. "f_detail
*&---------------------------------------------------------------------*
*& Form f_select
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* -->CODE text
*----------------------------------------------------------------------*
FORM f_select USING code.
CASE code.
WHEN 'SELECT'.
sp1-mask = 'X'.
MODIFY sp2 FROM sp1 TRANSPORTING mask WHERE mask IS INITIAL.
WHEN 'BLOCK'.
sp1-mask = 'X'.
MODIFY sp2 FROM sp1 INDEX l_line TRANSPORTING mask.
WHEN 'DESELECT'.
sp1-mask = ''.
MODIFY sp2 FROM sp1 TRANSPORTING mask WHERE mask = 'X'.
ENDCASE.
ENDFORM. "f_select
*&---------------------------------------------------------------------*
*& Form F_ROW
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
* -->CODE text
*----------------------------------------------------------------------*
FORM f_row USING code.
DATA lwa_cols LIKE LINE OF content-cols.
DATA: l_int TYPE i,
lt_cols LIKE TABLE OF l_int.
CASE code.
WHEN 'INSERT'.
INSERT INITIAL LINE INTO sp2 INDEX l_line.
WHEN 'DELETE'.
DELETE sp2 WHERE mask = 'X'.
ENDCASE.
ENDFORM. "F_ROW
屏幕100的代码：
PROCESS BEFORE OUTPUT.
MODULE status_0100.
LOOP WITH CONTROL content.
MODULE filltab.
MODULE set_editable.
ENDLOOP.
MODULE set_cursor.
PROCESS AFTER INPUT.
LOOP WITH CONTROL content.
MODULE readtab.
MODULE chang_val.
ENDLOOP.
MODULE get_cursor.
MODULE user_command_0100.
ABAP 中 Table Control例子的更多相关文章
- ABAP table control例子
[转自]http://blog.csdn.net/lhx20/article/details/3039909Table control用于在screen上以表格的形式显示数据,在table contr ...
- ABAP 表格控制(Table Control)和步循环
表格控制(Table Control)和步循环 1.两个标准Demo: SAPMTZ60,SAPMTZ61 2.简介 3.建立Table Control程序的基本流程 4.使用步循环 5.表格 ...
- SAP ABAP编程 Table Control动态隐藏列
在SAP DIALOG设计中,有时候须要动态的隐藏某些列,以下是方法. ***数据定义 CONTROLS: table_control TYPE TABLEVIEW USING SCREEN 0100 ...
- ABAP中的Table Control编程
SAP中,Table Control是在Screen中用的最广泛的控件之一了,可以实现对多行数据的编辑. 简单来说,Table Control是一组屏幕元素在Screen上的重 ...
- ABAP Table Control
SAP中,Table Control是在Screen中用的最广泛的控件之一了,可以实现对多行数据的编辑. 简单来说,Table Control是一组屏幕元素在Screen上的重复出现,这就是它与普通 ...
- 我教女朋友学编程html系列(5) html中table的用法和例子
女朋友不是学计算机的,但是现在从事计算机行业,做技术支持,她想学习编程,因此我打算每天教她一点点,日积月累,带她学习编程,如果其他初学者感兴趣,可以跟着学. 为了将table介绍的简单.生动,具有实战 ...
- abap table control里面各种属性和事件的写法
SAP中,Table Control是在Screen中用的最广泛的控件之一了,可以实现对多行数据的编辑. 简单来说,Table Control是一组屏幕元素在Screen上的重复出现,这就是它与普通屏 ...
- 【ABAP系列】SAP ABAP中ALV使用HTML的例子
公众号:SAP Technical 本文作者:matinal 原文出处:http://www.cnblogs.com/SAPmatinal/ 原文链接:[ABAP系列]SAP ABAP中ALV使用HT ...
- ABAP中使用浏览器打开网页
在SAP ABAP中可以在Screen中嵌入Html control打开网页,也可以通过调用本地的IE浏览器打开. 1.在Screen中嵌入Html control的例子,在系统中有,se38:SAP ...
随机推荐
- centos安装python gcc sqlite
终端中输入命令:yum install gcc -y yum install python -y yum install sqlite -y
- javascript操作元素的css样式
我们经常要使用Javascript来改变页面元素的样式.当中一种办法是改变页面元素的CSS类(Class),这在传统的Javascript里,我们一般是通过处理HTML Dom的classname特性 ...
- android获取View上某点的颜色
//根据坐标获取 ImageView imageView = ((ImageView)v); Bitmap bitmap = ((BitmapDrawable)imageView.getDrawabl ...
- openstack ovs-gre 网速慢解决方案
Hint: if you want to check if this answer will solve your issue, execute ifconfig eth0 mtu 1400 on t ...
- 【Java TCP/IP Socket】TCP Socket通信中由read返回值造成的的死锁问题（含代码）（转）
书上示例 在第一章<基本套接字>中,作者给出了一个TCP Socket通信的例子——反馈服务器,即服务器端直接把从客户端接收到的数据原原本本地反馈回去. 书上客户端代码如下: 1 2 3 ...
- Android SurfaceView实现静态于动态画图效果
本文是基于Android的SurfaceView的动态画图效果,实现静态和动态下的正弦波画图,可作为自己做图的简单参考,废话不多说,先上图, 静态效果: 动态效果: 比较简单,代码注释的也比较详细,易 ...
- 读书与写论文的引导书——leo鉴书60
我是专科直接考的研究生.在论文写作方面基本能够算是初级.MBA毕业那会儿要写论文,在网上找了不少这方面的书,<论文与治学>是当中之中的一个. 这本那时为应景儿卖的书,成了我之后学习与工作的 ...
- asp.net2.0安全性(3)－－验证与授权--转载来自车老师
"验证"与"授权"是对网页资源安全管理的两道门. 验证(Authentication):检查用户是否是合法的用户.就像是网站大门口的保卫,服责验证使用的用户名和 ...
- linux命令:Linux命令大全
Linux命令大全 http://man.linuxde.net/
- 基于Spring的Web缓存
缓存的基本思想其实是以空间换时间.我们知道,IO的读写速度相对内存来说是非常比较慢的,通常一个web应用的瓶颈就出现在磁盘IO的读写上.那么,如果我们在内存中建立一个存储区,将数据缓存起来,当浏览器端 ...