CDS标准视图：功能位置可用标签 I_FUNCNLLOCALTERNATIVELABEL

• 视图名称：功能位置可用标签 I_FUNCNLLOCALTERNATIVELABEL
• 视图类型：基础
• 视图代码：

点击查看代码

@EndUserText.label: 'Functional Location Alternative Labels'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'IFUNCTLOCALTLBL'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true

@ObjectModel: {
  representativeKey: 'FunctionalLocationLabelVersion',
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #C,
    sizeCategory: #L
  }
}

@Analytics: {
  dataCategory: #DIMENSION,
  dataExtraction: {
    enabled: true,
    delta.byElement : {
      name: 'LastChangeDateTime'
    }
  }
}

@Metadata: {
  ignorePropagatedAnnotations,
  allowExtensions
}
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET]

define view I_FuncnlLocAlternativeLabel
  as select from I_FunclocationLabelInternal
  association [0..1] to I_FunctionalLocation as _FunctionalLocation on $projection.FunctionalLocation = _FunctionalLocation.FunctionalLocation
  association [0..1] to I_Indicator          as _IsPrimaryLabel     on $projection.FuncnlLocLabelIsPrimaryLabel = _IsPrimaryLabel.IndicatorValue
  association [0..1] to I_Indicator          as _IsActive           on $projection.FunctionalLocLabelIsActive = _IsActive.IndicatorValue
   -- Extension, do not expose as association:
  association [0..1] to E_FunctionalLocation as _FunctionalLocationExtension on _FunctionalLocationExtension.FunctionalLocation = $projection.FunctionalLocation
{
      //I_FunclocationLabelInternal
      @ObjectModel.foreignKey.association: '_FunctionalLocation'
  key FunctionalLocation,
      @ObjectModel.foreignKey.association: '_FunctionalLocLabelingSyst'
  key FunctionalLocLabelingSyst,
  key FunctionalLocationLabelVersion,

      @ObjectModel.foreignKey.association: '_IsActive'
      FunctionalLocLabelIsActive,

      FunctionalLocationLabelName,

      @ObjectModel.foreignKey.association: '_IsPrimaryLabel'
      FuncnlLocLabelIsPrimaryLabel,

      @Semantics.systemDate.createdAt: true
      CreationDate,

      @Semantics.user.createdBy: true
      CreatedByUser,

      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,

      /* Associations */
      //I_FunclocationLabelInternal
      _FunctionalLocLabelingSyst,

      _FunctionalLocation,
      _IsActive,
      _IsPrimaryLabel
}

• 事务代码：IL03

• 视图结构：

字段名称	设备名称
功能位置	FUNCTIONALLOCATION
标志系统	FUNCTIONALLOCLABELINGSYST
版本	FUNCTIONALLOCATIONLABELVERSION
活动版本	FUNCTIONALLOCLABELISACTIVE
功能位置	FUNCTIONALLOCATIONLABELNAME
主要	FUNCNLLOCLABELISPRIMARYLABEL
创建日期	CREATIONDATE
创建人	CREATEDBYUSER
时戳	LASTCHANGEDATETIME