关于Gen生成try-catch-finally

例1：

class TestExc extends Exception{}
void tryItOut () throws TestExc{}
void handleExc(Object o){}

void catchOne() {
	try {
		tryItOut();
	} catch (TestExc e) {
		handleExc(e);
	}
}

生成的class文件的格式如下：

void catchOne();
    flags:
    Code:
      stack=2, locals=2, args_size=1
         0: aload_0
         1: invokevirtual #2                  // Method tryItOut:()V
         4: goto          13
         7: astore_1
         8: aload_0
         9: aload_1
        10: invokevirtual #4                  // Method handleExc:(Ljava/lang/Object;)V
        13: return
      Exception table:
         from    to  target type
            0     4     7   Class com/test19/Test04$TestExc

其中的catchOne()方法的code码如下：

 2A B6 00 02 A7 00 09 4C 2A 2B B6 00 04 B1

opcode [2A] - 0000: aload_0
opcode [B6] - 0001: invokevirtual 2 [Methodref: com.test19.Test04.tryItOut, parameter = (), returns = void]
opcode [A7] - 0004: goto 9
opcode [4C] - 0007: astore_1
opcode [2A] - 0008: aload_0
opcode [2B] - 0009: aload_1
opcode [B6] - 0010: invokevirtual 4 [Methodref: com.test19.Test04.handleExc, parameter = (java.lang.Object), returns = void]
opcode [B1] - 0013: return

例2：

如上的例子与如下的例子生成的class文件一样，但是Exception Table不一样：

class TestExc1 extends Exception{}
class TestExc2 extends Exception{}

void tryItOut () throws TestExc1,TestExc2{}

void handleExc1(Object o){}
void handleExc2(Object o){}

void nestedCatch() {
    try {
        tryItOut();
    } catch (TestExc1 e) {
        handleExc1(e);
    } catch (TestExc2 e) {
        handleExc2(e);
    }
}

生成的class文件的格式如下：

void nestedCatch();
    flags:
    Code:
      stack=2, locals=2, args_size=1
         0: aload_0
         1: invokevirtual #2                  // Method tryItOut:()V
         4: goto          22
         7: astore_1
         8: aload_0
         9: aload_1
        10: invokevirtual #4                  // Method handleExc1:(Ljava/lang/Object;)V
        13: goto          22
        16: astore_1
        17: aload_0
        18: aload_1
        19: invokevirtual #6                  // Method handleExc2:(Ljava/lang/Object;)V
        22: return
      Exception table:
         from    to  target type
             0     4     7   Class com/test19/Test07$TestExc1
             0     4    16   Class com/test19/Test07$TestExc2 

再举个例子，如下：

void tryItOut () throws TestExc1,TestExc2{}
class TestExc1 extends Exception{}
class TestExc2 extends Exception{}
void handleExc1(Object o){}
void handleExc2(Object o){}

void nestedCatch() {
	try {
		try {
			tryItOut();
		} catch (TestExc1 e) {
			handleExc1(e);
		}
	} catch (TestExc2 e) {
		handleExc2(e);
	}
}

生成的class文件内容如下：

void nestedCatch();
    flags:
    Code:
      stack=2, locals=2, args_size=1
         0: aload_0
         1: invokevirtual #2                  // Method tryItOut:()V
         4: goto          13
         7: astore_1
         8: aload_0
         9: aload_1
        10: invokevirtual #4                  // Method handleExc1:(Ljava/lang/Object;)V
        13: goto          22
        16: astore_1
        17: aload_0
        18: aload_1
        19: invokevirtual #6                  // Method handleExc2:(Ljava/lang/Object;)V
        22: return
      Exception table:
         from    to  target type
             0     4     7   Class com/test19/Test04$TestExc1
             0    13    16   Class com/test19/Test04$TestExc2  

例3：

void tryItOut () {}
void wrapItUp () {}

void tryFinally() {
	try {
		tryItOut();
	} finally {
		wrapItUp();
	}
}

生成的class文件格式如下：

void tryFinally();
    flags:
    Code:
      stack=1, locals=2, args_size=1
         0: aload_0
         1: invokevirtual #2                  // Method tryItOut:()V
         4: aload_0
         5: invokevirtual #3                  // Method wrapItUp:()V
         8: goto          18
        11: astore_1
        12: aload_0
        13: invokevirtual #3                  // Method wrapItUp:()V
        16: aload_1
        17: athrow
        18: return
      Exception table:
         from    to  target type
             0     4    11   any
            11    12    11   any

　

例4：

int tryFinally() {
	try {
		int i = 1;
		return i;
	} finally {
		int j = 2;
		return j;
	}
}

生成的class文件内容如下：

int tryFinally();
    flags:
    Code:
      stack=1, locals=6, args_size=1
         0: iconst_1
         1: istore_1
         2: iload_1
         3: istore_2 // 由于要运行finally，所以需要将这个return的值暂时存储到本地变量表中

         4: iconst_2
         5: istore_3
         6: iload_3
         7: ireturn

         8: astore    4 // 将异常引用类型存储到本地变量表4的位置
        10: iconst_2
        11: istore    5
        13: iload     5 // 将本地变量表5的位置加载到栈中，因为finally中的return值要做为最终值返回
        15: ireturn
      Exception table:
         from    to  target type
             0     4     8   any
             8    10     8   any

例5：

void tryItOut () {}
void wrapItUp1 () {}
void wrapItUp2 () {}

int tryFinally() {
	try {
		try {
			int i = 1;
			return i;
		} finally {
			wrapItUp1();
		}
	} finally {
		wrapItUp2();
	}
}

则生成的代码如下：

stack=1, locals=5, args_size=1
0: iconst_1
1: istore_1
2: iload_1
3: istore_2 // 将变量i的值存储到本地变量表2的位置，以便返回
4: aload_0
5: invokevirtual #2                  // Method wrapItUp1:()V
8: aload_0
9: invokevirtual #3                  // Method wrapItUp2:()V
12: iload_2 // 从本地变量表2的位置取出返回数并返回
13: ireturn

14: astore_3 // 将异常存储到本地变量表3的位置
15: aload_0
16: invokevirtual #2                  // Method wrapItUp1:()V
19: aload_3
// 在这里抛出异常后，在异常表中查看跳转到target，
// 则清空当前操作数栈，异常重新入栈，程序继续执行
20: athrow 

21: astore        4 // 将异常存储到本地变量表4的位置
23: aload_0
24: invokevirtual #3                  // Method wrapItUp2:()V
27: aload         4
29: athrow
Exception table:
from    to  target type
    0     4    14   any
   14    15    14   any
    0     8    21   any
   14    23    21   any

　　

例6：

class TestExc1 extends Exception{}
class TestExc2 extends Exception{}

void tryItOut () throws TestExc1,TestExc2{}

void handleExc1(Object o){}
void handleExc2(Object o){}

void wrapItUp () {}

void nestedCatch() {
    try {
        tryItOut();
    } catch (TestExc1 e) {
        handleExc1(e);
    } catch (TestExc2 e) {
        handleExc2(e);
    }finally {
        wrapItUp();
    }
}