30天自制操作系统（二）汇编语言学习与Makefile入门

1 介绍文本编辑器

这部分可直接略过

2 继续开发

helloos.nas中核心程序之前的内容和启动区以外的内容先不讲了，因为还涉及到一些软盘方面的知识。

然后来讲的是helloos.nas这个文件

; hello-os
; TAB=4

        ORG        0x7c00             ; 指明程序的装载地址

; 以下这部分记录的是FAT12格式的软盘

        JMP        entry
        DB         0x90
        DB         "HELLOIPL"         ; 启动扇区的名称可以是任意的字符串 (8字节)
        DW         512                ; 每个扇区(sector)的大小(必须是512字节)
        DB         1                  ; 簇(cluster)的大小 (必须为512字节)
        DW         1                  ; FAT的起始位置 (一般从第一个扇区开始)
        DB         2                  ; FAT的个数 (必须为2)
        DW         224                ; 根目录的大小(一般设成224项)
        DW         2880               ; 该磁盘的大小(必须是2880扇区)
        DB         0xf0               ; 磁盘的种类 (必须是0xf0)
        DW         9                  ; FAT的长度 (必须是9扇区)
        DW         18                 ; 1个磁道(track)有几个扇区(必须是18)
        DW         2                  ; 磁头数 (必须是2)
        DD         0                  ; 不使用分区, 必须是0
        DD         2880               ; 重写一次磁盘大小
        DB         0,0,0x29           ; 意义不明, 固定
        DD         0xffffffff         ; (可能是)卷标号码
        DB         "HELLO-OS   "      ; 磁盘的名称(11字节)
        DB         "FAT12   "         ; 磁盘格式名称 (8字节)
        RESB       18                 ; 先空出18字节

; 程序主体

entry:
        MOV        AX,0               ; 初始化寄存器
        MOV        SS,AX
        MOV        SP,0x7c00
        MOV        DS,AX
        MOV        ES,AX
        MOV        SI,msg
putloop:
        MOV        AL,[SI]
        ADD        SI,1               ; 给SI加1
        CMP        AL,0
        JE         fin
        MOV        AH,0x0e            ; 显示一个文字
        MOV        BX,15              ; 指定字符颜色
        INT        0x10               ; 调用显卡BIOS
        JMP        putloop
fin:
        HLT                           ; 让CPU停止等待指令
        JMP        fin                ; 无限循环

msg:
        DB         0x0a, 0x0a         ; 换行2次
        DB         "hello, world"
        DB         0x0a               ; 换行
        DB         0
        RESB       0x7dfe-$           ; 填写0x00, 直到0x7dfe
        DB         0x55, 0xaa

; 以下是启动区以外部分的输出
        DB         0xf0, 0xff, 0xff, 0x00, 0x00, 0x00, 0x00, 0x00
        RESB       4600
        DB         0xf0, 0xff, 0xff, 0x00, 0x00, 0x00, 0x00, 0x00
        RESB       1469432

ORG指令

ORG指令告诉nask，在开始执行的时候，把这些机器语言指令装载到内存中的哪个地址。

这条指令使得$的含义也发生了变化，不再是指输出文件的第几个字节，而是代表将要读入的内存地址。

ORG是"origin"，"源头、起点"的意思，它会告诉nask，程序要从指定的这个地址开始也就是要把程序装载到内存中的指定地址。

JMP，JE指令

相当于C语言中的goto标签，多年以来我们都被教育不要用goto......

"JMP entry"这个指令就是让CPU执行内存地址为entry处的程序。

标签

在上面的程序中entry，fin，putloop和msg都是标签，相当于一个入口地址，或者标记。

每个标号对应的数字，都是由汇编语言编译器根据ORG指令计算出来的。编译器计算出的"标号的地方对应的内存地址"就是那个标号的值。

MOV指令

CPU中的各种寄存器

汇编中[]取值

MOV AL, SI的意思是将SI寄存器中的值传给AL寄存器，但是MOV AL, [SI]的意思将SI中存储着一个数字，而这个数字代表的是内存中的一个地址，[SI]意思是取出这个地址应对的值。

MOV BYTE [678], 123

MOV WORD [678], 123

数据大小端的问题

INT指令

INT是软件中断指令。意思是打断CPU当前的执行路径，跑去其他的地方执行。

BIOS中存储了为开发人员准备的各种函数的集合，INT指令后面接不通的数字，就调用BIOS中对应的函数了。

HLT指令

HLT让CPU停止动作的指令，不过并不是彻底的停止，而是让CPU进行待机状态，只要外部发生变化，比如按下鼠标键盘，就会醒过来，继续执行程序。

如果没有HLT指令，CPU会不停的只去执行JMP指令，负荷达到100%，非常费电。

0x7c00

现在的内存地址都很大了，尼玛，内存今年涨价好厉害。

内存的0号地址，也就是最开始的地方，是BIOS程序用来实现各种不同功能的地方，如果随便使用就会与BIOS发生冲突。

此外，在内存的0xf0000号地址附近还存放着BIOS程序本身，也不能使用。

内存还有不少地方也是不能使用的，作为操作系统开发者要特别注意。

0x00007c00~0x00007dff：启动区内容的装载地址

程序中ORG指令指的就是这个地址。

文中没有解释为啥是0x7C00，我又在网上找了一下

一下内容来自阮一峰老师博客

=================== start_1 =======================

《计算机原理》课本说，启动时，主引导记录会存入内存地址0x7C00。

这个奇怪的地址，是怎么来的，课本就不解释了。我一直有疑问，为什么不存入内存的头部、尾部、或者其他位置，而偏偏存入这个比 32KB 小1024字节的地方？

昨天，我读到一篇文章，终于解开了这个谜。

首先，如果你不知道，主引导记录（Master boot record，缩写为MBR）是什么，可以先读《计算机是如何启动的？》。

简单说，计算机启动是这样一个过程。

1. 通电

2. 读取ROM里面的BIOS，用来检查硬件
3. 硬件检查通过
4. BIOS根据指定的顺序，检查引导设备的第一个扇区（即主引导记录），加载在内存地址 0x7C00
5. 主引导记录把操作权交给操作系统

所以，主引导记录就是引导"操作系统"进入内存的一段小程序，大小不超过1个扇区（512字节）。

0x7C00这个地址来自Intel的第一代个人电脑芯片8088，以后的CPU为了保持兼容，一直使用这个地址。

1981年8月，IBM公司最早的个人电脑IBM PC 5150上市，就用了这个芯片。

当时，搭配的操作系统是86-DOS。这个操作系统需要的内存最少是32KB。我们知道，内存地址从0x0000开始编号，32KB的内存就是0x0000～0x7FFF。

8088芯片本身需要占用0x0000～0x03FF，用来保存各种中断处理程序的储存位置。（主引导记录本身就是中断信号INT 19h的处理程序。）所以，内存只剩下0x0400～0x7FFF可以使用。

为了把尽量多的连续内存留给操作系统，主引导记录就被放到了内存地址的尾部。由于一个扇区是512字节，主引导记录本身也会产生数据，需要另外留出512字节保存。所以，它的预留位置就变成了：

0x7FFF - 512 - 512 + 1 = 0x7C00

0x7C00就是这样来的。

计算机启动后，32KB内存的使用情况如下。

=================== end_1 =======================

就欣赏阮老师挖到底的情怀

所以其实启动区就放到了0x7c00的位置，比32KB少1KB，记住这个，到时候装个B。

3 先制作启动区

这里作者说并不想用nask来制作整个磁盘映像，而是先只用它来制作启动区，去掉了后半段，程序也改名为ipl.nas。

大概就是这一段内容去掉了，就是只留到了55 AA了，还记得55AA了，第一个扇区最后的两个字节哦。

4 Makefile入门

这里就不讲了，就是把来需要手动输入的编译命令用写成Makefile这个文件。

数据也能执行么？

CPU执行的是啥，指令，指令就是数据，CPU先找指令，再找操作数。你随便给一段数据CPU，CPU也能执行。

这里的意思就是，瞎几把给CPU传指令和数据，CPU执行的结果坑定也是乱七八糟的。