FlashSocke 通过flash进行socket通信(as代码)

在早期的项目中, 因为需要用IE上连接socket进行通信, 所以不得不借助于flash的socket功能,于是有了下面这个`FlashSocke`,供JavaScript调用 和 回调JavaScript.

code:

 package
 {
 import flash.external.*;
 import flash.display.Sprite;
 //import flash.external.ExternalInterface;
 import flash.events.*;
 import flash.net.Socket;
 import flash.system.*;
 import flash.utils.Timer;

 //==============================================================================
 public class Main extends Sprite
 {
     static var socket:Socket = null;
     static var bConnecting:Boolean = false;
     static var charSet:String;
     static var Obj:String;
     static var ReConNum:Number=0;
     //var str:String;

     public function Main()
     {
         //添加JS调用的函数的接口。
         ExternalInterface.addCallback("Connect",Connect);
         ExternalInterface.addCallback("SendMsg",SendMsg);
         ExternalInterface.addCallback("Close",Close);
         ExternalInterface.addCallback("GetState",GetState);
     }
     //事件回调,当连接更改时
     public function OnConnect(evt:Event=null):void
     {
         if(socket.connected)
             bConnecting=false;
         Debug(evt.toString());
         ExternalInterface.call(Obj+"OnConnect",socket.connected);
     }
     //事件回调,被动关闭才会触发
     public function OnClose(evt:Event):void
     {
         Debug(evt.toString());
         bConnecting=false;
         ExternalInterface.call(Obj+"OnClose");
     }

     /*===============Flax事件回调函数==============================================*/

     //事件回调,出错回调
     public function errorHandler(evt:ErrorEvent):void
     {
         OnError(evt.errorID,evt.toString());
     }
     //事件回调,接收回调
     public function ReciveHandler(evt:ProgressEvent):void
     {
         try
         {
             //OnMsg( socket.readUTFBytes(socket.bytesAvailable) );//UTF
             //OnMsg( socket.readUTF());//Error #2030
             //str=socket.readMultiByte(socket.bytesAvailable,charSet);
             //Debug(str);
             //ExternalInterface.call(Obj+"OnMsg",str.replace(new RegExp("\\", 'g'),"\\\\"));
             ExternalInterface.call(Obj+"OnMsg",socket.readMultiByte(socket.bytesAvailable,charSet).replace(/\\/g,"\\\\"));
             //OnMsg(socket.readMultiByte(socket.bytesAvailable,charSet));
         }
         catch (err:Error)
         {
             OnError(err.errorID,"接收数据时发生错误："+err.toString());
         }
     }

     /*===============Flax调用JS函数==============================================*/

     //调用JS函数OnError,出错回调
     public function OnError(code:int,msg:String):int
     {
         ExternalInterface.call(Obj+"OnError",code,msg);
         return code;
     }
     //调用JS函数Logs,显示日志信息
     public function Debug(str:String):void
     {
         ExternalInterface.call(Obj+"Logs","[Flash]"+str);
     }

     /*===============JS调用Flax函数==============================================*/

     //通过JS调用Connect，初始化Socket,并连接
     public function Connect(ip:String, port:int, obj:String="", charset:String="GBK", pf:String="")
     {
         //trace("Connect...");
         try
         {
             if (socket && socket.connected)
             {
                 ExternalInterface.call(Obj+"OnMsg","{}");
                 return Debug("已连接"),1;
             }
             if(bConnecting&&ReConNum<10)//连接次数小于10
             {
                 ReConNum++;
                 return Debug("连接中... Connecting... Wait Please."),1;
             }
             ReConNum=0;
             if (ip == "" || port == 0)
                 return OnError(-99,"不正确的IP或端口参数"),0;

             charSet=charset;
             if(obj!="")
                 Obj=obj+".";//JS对象名; 这样可以调用JS对象的函数

             Debug("Ver:2015-1120-1720");
             Debug("Connect("+ip+", "+port+")");

             try{
               if(socket!=null)
                 socket.close();
             }catch (error1:Error){}

             bConnecting=true;

             socket = new Socket  ;
             socket.timeout = 10000;//超时事件会被捕获为securityError事件,不知道为啥
             socket.addEventListener(Event.CONNECT,OnConnect);//连接状态变化时,经常不执行;用定时器检查去了
             socket.addEventListener(Event.CLOSE,OnClose);
             socket.addEventListener(ErrorEvent.ERROR,errorHandler);
             socket.addEventListener(IOErrorEvent.IO_ERROR,errorHandler);
             socket.addEventListener(SecurityErrorEvent.SECURITY_ERROR,errorHandler);
             socket.addEventListener(ProgressEvent.SOCKET_DATA,ReciveHandler,false,0,true);

             //"http://" + serverIP + ":" + webport + "/crossdomain.xml";
             //Security.allowDomain("*");
             if (pf != "")
                 Security.loadPolicyFile(pf);

             socket.connect(ip,port);//连接是异步的
             return 1;
         }
         catch (err:Error)
         {
             bConnecting=false;
             socket.close();
             return OnError(err.errorID,"连接时发生错误："+err.toString()),0;
         }
     }

     //JS调用Close，关闭Socket
     public function Close()
     {//trace("Close.................");
         try
         {
             socket.close();
         }
         catch (err:Error)
         {
             OnError(err.errorID,"关闭Socket时发生错误："+err.toString());
         }
         bConnecting=false;
     }
     //JS调用GetState，返回Socket连接状态
     public function GetState():Boolean
     {
         try
         {
             if(socket!=null)
                 return socket.connected;
             else
                 return false;
         }
         catch(err:Error)
         {
             OnError(err.errorID,"GetState发生错误："+err.toString());
         }
         return false;
     }
     //JS调用Send，发送数据,返回发送的数据的长度
     public function SendMsg(msg:String):int
     {
         var len:int = 0;
         if (socket && socket.connected)
         {
             try
             {
                 //var ba:ByteArray = new ByteArray ;
                 //ba.writeUTFBytes(msg);
                 //socket.writeBytes(ba);
                 socket.writeMultiByte(msg,charSet);
                 //socket.writeUTF(msg+"\n");
                 socket.flush();
                 //sleep(50);
                 len = msg.length;
                 Debug("SendMsgLen:"+len);
             }
             catch (err:Error)
             {
                 len = err.errorID;
                 OnError(err.errorID,"发送数据时发生错误："+err.toString());
             }
         }
         else
         {
             len = -96;
             OnError(-96,"未连接或已断开,需要重新连接/登陆.");
         }
         return len;
     }

 }//End class Main

 }//end package

当然,后来 浏览器们都纷纷更新,支持H5, 就是用WebSocket了, 于是不再是用这个破旧的东西了, 毕竟是插件嘛, 稳定性啥的,,,,(ps:flash会经常崩溃呀)

调用说明:

[FlashSocket:提供的函数接口]
//通过JS调用Connect，初始化Socket，并连接
//obj:设置函数的回调前缀(对象名,如:"fsObj"),使能回调象的函数(如"fsObj.OnMsg")
//charset:设置往来消息的字符编码,默认编码"GBK"
//pf:设置Security.loadPolicyFile 的地址
Connect(ip:String, port:int, obj:String="", charset:String="GBK", pf:String=""):void

//通过JS调用SendMsg，发送数据,返回发送的数据的长度
SendMsg(msg:String):int

//通过JS调用Close，关闭Socket
Close():void

//通过JS调用GetState，返回Socket连接状态。
GetState():Boolean

//通过JS调用GetServerIP，返回服务器IP地址
GetServerIP():String

//通过JS调用GetServerPort，返回服务器端口
GetServerPort():int

[JavaScript:提供的回调函数接口]
OnConnect(bool)
OnClose()
OnError(code,msg)
OnMsg(msgstr)
Logs(logstr)

那啥,编译成 `.swf` 就可以使用了.

要注意异步.