概述

BULK COLLECT 子句会批量检索结果，即一次性将结果集绑定到一个集合变量中，并从SQL引擎发送到PL/SQL引擎。通常可以在SELECT INTO、FETCH INTO以及RETURNING INTO子句中使用BULK COLLECT。

Oracle 使用 bulk collect 子句的用例

  • BULK COLLECT批量绑定 支持复合类型内部的集合类型

  • FETCH数据批量绑定

  • RETURNING 子句的批量绑定 不支持 INSERT returning 使用集合类型

  • 动态SQL批量绑定 不支持动态 INSERT 使用集合类型

#创建自定义数据类型 —— 集合类型、复合类型

create type numberlist is table of number;

create type rec_data is object

(

    ID   integer,

    nums numberlist

);

#创建用例数据表

create table t01 (id)

as

select level as id

from dual

connect by LEVEL <= 100;

#Oracle使用bulk collect子句的例子

declare

    v_numlst numberlist;

    v_recdat rec_data ;

    CURSOR cur_dat IS

        select id

        from t01;

begin

    /*在SELECT INTO中使用BULK COLLECT*/

    begin

        select id bulk collect

        into v_numlst

        from t01

        where id <= 10;

        dbms_output.put_line('v_numlst: ' || v_numlst.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    /*使用 BULK COLLECT INTO 嵌套的集合类型*/

    begin

        select id bulk collect

        into v_recdat.NUMS

        from t01

        where id <= 20;

        dbms_output.put_line('v_recdat.NUMS: ' || v_recdat.NUMS.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    /*嵌套的集合类型变量赋值*/

    begin

        v_recdat.NUMS := v_numlst;

        dbms_output.put_line('v_recdat.NUMS: ' || v_recdat.NUMS.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    /*在FETCH INTO中使用BULK COLLECT*/

    begin

        OPEN cur_dat;

        FETCH cur_dat BULK COLLECT

            INTO v_numlst limit 30;

        close cur_dat;

        dbms_output.put_line('fetch cursor: ' || v_numlst.COUNT);

    exception

        when

            others then

            dbms_output.put_line(sqlerrm);

    end;

    /*在UPDATE RETURNING INTO中使用BULK COLLECT*/

    begin

        update t01

        set id = id + 100

        where id <= 40

        returning id bulk collect into v_numlst;

        rollback ;

        dbms_output.put_line('update returning: ' || v_numlst.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    /*在DELETE RETURNING INTO中使用BULK COLLECT*/

    begin

        delete t01

        returning id bulk collect into v_numlst;

        rollback;

        dbms_output.put_line('delete returning: ' || v_numlst.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    /*在动态SQL中使用BULK COLLECT*/

    begin

        EXECUTE IMMEDIATE 'select id from t01 where id <= 60 '

            bulk collect into v_numlst;

        rollback;

        dbms_output.put_line('dynsql select: ' || v_numlst.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    /*在动态UPDATE中使用BULK COLLECT*/

    begin

        EXECUTE IMMEDIATE 'update t01 set id = id + 1 where id <= 70 returning id into :1'

            RETURNING bulk collect INTO v_numlst;

        rollback;

        dbms_output.put_line('dynsql update returning: ' || v_numlst.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    /*在动态DELETE中使用BULK COLLECT*/

    begin

        EXECUTE IMMEDIATE 'delete t01 where id <= 80 returning id into :1'

            RETURNING bulk collect INTO v_numlst;

        rollback;

        dbms_output.put_line('dynsql delete returning: ' || v_numlst.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    dbms_output.put_line('End ;');

end;

/

v_numlst: 10

v_recdat.NUMS: 20

v_recdat.NUMS: 10

fetch cursor: 30

update returning: 40

delete returning: 50

dynsql select: 60

dynsql update returning: 70

dynsql delete returning: 80

End ;

PL/SQL procedure successfully completed.

KingbaseES 使用 bulk collect 子句的用例

  • BULK COLLECT批量绑定 不支持 复合类型内部的集合类型

  • FETCH数据批量绑定

  • RETURNING 子句的批量绑定 支持 INSERT returning 使用集合类型

  • 动态SQL批量绑定 支持动态 INSERT 使用集合类型

#创建自定义数据类型 —— 集合类型、复合类型

create type numberlist is table of number;

create type rec_data is object

(

    ID   integer,

    nums numberlist

);

#创建用例数据表

create table t01 (id)

as

select level as id

from dual

connect by LEVEL <= 100;

#Oracle使用bulk collect子句的例子

declare

    v_numlst numberlist;

    v_recdat rec_data ;

    CURSOR cur_dat IS

        select id

        from t01;

begin

    /*在SELECT INTO中使用BULK COLLECT*/

    begin

        select id bulk collect

        into v_numlst

        from t01

        where id <= 10;

        dbms_output.put_line('v_numlst: ' || v_numlst.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    /*使用 BULK COLLECT INTO 嵌套的集合类型*/

    begin

        select id bulk collect

        into v_recdat.NUMS

        from t01

        where id <= 20;

        dbms_output.put_line('v_recdat.NUMS: ' || v_recdat.NUMS.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    /*嵌套的集合类型变量赋值*/

    begin

        v_recdat.NUMS := v_numlst;

        dbms_output.put_line('v_recdat.NUMS: ' || v_recdat.NUMS.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    /*在FETCH INTO中使用BULK COLLECT*/

    begin

        OPEN cur_dat;

        FETCH cur_dat BULK COLLECT

            INTO v_numlst limit 30;

        close cur_dat;

        dbms_output.put_line('fetch cursor: ' || v_numlst.COUNT);

    exception

        when

            others then

            dbms_output.put_line(sqlerrm);

    end;

    /*在INERT RETURNING INTO中使用BULK COLLECT*/

    begin

        insert into t01

        select * from t01 where id <=35

        returning id bulk collect into v_numlst;

        rollback;

        dbms_output.put_line('insert returning: ' || v_numlst.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    /*在UPDATE RETURNING INTO中使用BULK COLLECT*/

    begin

        update t01

        set id = id + 100

        where id <= 40

        returning id bulk collect into v_numlst;

        rollback ;

        dbms_output.put_line('update returning: ' || v_numlst.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    /*在DELETE RETURNING INTO中使用BULK COLLECT*/

    begin

        delete t01

        returning id bulk collect into v_numlst;

        rollback;

        dbms_output.put_line('delete returning: ' || v_numlst.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    /*在动态SQL中使用BULK COLLECT*/

    begin

        EXECUTE IMMEDIATE 'select id from t01 where id <= 60 '

            bulk collect into v_numlst;

        rollback;

        dbms_output.put_line('dynsql select: ' || v_numlst.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    /*在动态INSERT中使用BULK COLLECT*/

    begin

        EXECUTE IMMEDIATE 'insert into t01 select * from t01 where id<=65  returning id'

            RETURNING bulk collect INTO v_numlst;

        rollback;

        dbms_output.put_line('dynsql insert returning: ' || v_numlst.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    /*在动态UPDATE中使用BULK COLLECT*/

    begin

        EXECUTE IMMEDIATE 'update t01 set id = id + 1 where id <= 70 returning id into :1'

            RETURNING bulk collect INTO v_numlst;

        rollback;

        dbms_output.put_line('dynsql update returning: ' || v_numlst.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    /*在动态DELETE中使用BULK COLLECT*/

    begin

        EXECUTE IMMEDIATE 'delete t01 where id <= 80 returning id into :1'

            RETURNING bulk collect INTO v_numlst;

        rollback;

        dbms_output.put_line('dynsql delete returning: ' || v_numlst.COUNT);

    exception

        when others then

            dbms_output.put_line(sqlerrm);

    end;

    dbms_output.put_line('End ;');

end;

/

ANONYMOUS BLOCK

v_numlst: 10

cannot mix between single row and multi-row (BULK) in INTO list

v_recdat.NUMS: 10

fetch cursor: 30

insert returning: 35

update returning: 40

delete returning: 50

dynsql select: 60

dynsql insert returning: 65

dynsql update returning: 70

dynsql delete returning: 80

End ;

总结

  1. BULK COLLECT INTO 的目标对象必须是集合类型。

  2. limit减少内存占用，如果数据量较大一次性全部加载到内存中，对PGA来说压力太大，可采用limit的方法一次加载一定数量的数据，建议值通常为1000。 使用limit时注意，循环的时候如果用while cursor_name%found loop，对于最后一次fetch的数据量不足设定值，%found条件就会不成立，可以使用 集合变量.count > 0 作为判断条件。

bulk collect 在KingbaseES和Oracle的使用方法比较的更多相关文章

  1. oracle学习之bulk collect用法

    通过bulk collect减少loop处理的开销,使用Bulk Collect提高Oracle查询效率 Oracle8i中首次引入了Bulk Collect特性,该特性可以让我们在PL/SQL中能使 ...

  2. Oracle forall bulk collect批量数据更新

    对于数据量较大的插入操作可采用此种方法操作,注意: limit减少内存占用,如果数据量较大一次性全部加载到内存中,对PGA来说压力太大,可采用limit的方法一次加载一定数量的数据,建议值通常为100 ...

  3. Oracle数据库之FORALL与BULK COLLECT语句

    Oracle数据库之FORALL与BULK COLLECT语句 我们再来看一下PL/SQL块的执行过程:当PL/SQL运行时引擎处理一块代码时,它使用PL/SQL引擎来执行过程化的代码,而将SQL语句 ...

  4. 【ORACLE】Bulk Processing with BULK COLLECT and FORALL

    https://orablogspot.blogspot.com/2014/09/ https://blogs.oracle.com/oraclemagazine/bulk-processing-wi ...

  5. Oracle bulk collect into 的几种用法

    bulk collect 和 forall 联合应用写起来显得有些啰嗦,不过为了速度,多写两句又何妨 建立两个临时表 create table T_TEST ( TESTID NUMBER(19) n ...

  6. ORACLE fetch bulk collect into limit

    DECLARE TYPE rr IS REF CURSOR; TYPE r_emp IS RECORD( empno ), ename ), job ), mgr ), hiredate DATE, ...

  7. ORACLE PL/SQL开发--bulk collect的用法 .

    刚刚在inthirties老大的博客里看到这篇文章,写的不错,正好自己最近在学习PL/SQL,转过来学习学习. ============================================ ...

  8. Oracle批量查询、删除、更新使用BULK COLLECT提高效率

    BULK COLLECT(成批聚合类型)和数组集合type类型is table of 表%rowtype index by binary_integer用法笔记 例1: 批量查询项目资金账户号为 &q ...

  9. Oracle学习笔记之五sp1，PL/SQL之BULK COLLECT

    Bulk Collect特性可以让我们在PL/SQL中能使用批查询,批查询在某些情况下能显著提高查询效率. BULK COLLECT 子句会批量检索结果,即一次性将结果集绑定到一个集合变量中,并从SQ ...

随机推荐

  1. Java ArrayList和LinkedList

    目录 集合的概念 集合体系结构 常用list集合 list集合的特点 ArrayList LinkedList 创建对象 常用方法 遍历 ArrayList和LinkedList的区别 集合的概念 ​ ...

  2. 跨平台（32bit和64bit）的 printf 格式符 %lld 输出64位的解决方式

    问题描述 在 C/C++ 开发中,使用 printf 打印 64 位变量比较常用,通常在 32 位系统中使用 %lld 输出 64 位的变量,而在 64 位系统中则使用 %ld: 如果在 32 位系统 ...

  3. PTA(BasicLevel)-1014 福尔摩斯的约会

    一.问题描述 大侦探福尔摩斯接到一张奇怪的字条:我们约会吧! 3485djDkxh4hhGE 2984akDfkkkkggEdsb s&hgsfdk d&Hyscvnm.大侦探很快就明 ...

  4. DTCC 干货分享：Real Time DaaS - 面向TP+AP业务的数据平台架构

      2021年10月20日,Tapdata 创始人唐建法(TJ)受邀出席 DTCC 2021(中国数据库技术大会),并在企业数据中台设计与实践专场上,发表主旨演讲"Real Time Daa ...

  5. Elasticsearch深度应用（上）

    索引文档写入和近实时搜索原理 基本概念 Segments in Lucene 众所周知,Elasticsearch存储的基本单元是shard,ES种一个index可能分为多个shard,事实上每个sh ...

  6. Static、Final关键字详解

    1.Static 详情见下面代码讲解 点击查看代码 package com.Tang.oop.demo07; public class Student { private static int age ...

  7. Möbius 反演注记

    目录 基本理论基础 数论函数 线性筛 Mobius 反演 Dirichlet 卷积 数论分块 / 整除分块 拆函数 时间复杂度分析 基本形式 GCD 形 万能 Prod 的莫比乌斯反演 正常例题 YY ...

  8. 1000-ms-maven相关问题

    一.Maven有哪些优点和缺点 优点如下: 简化了项目依赖管理: 易于上手,对于新手可能一个"mvn clean package"命令就可能满足他的工作 便于与持续集成工具(jen ...

  9. Vue 样式绑定 && 条件渲染

    1 <!DOCTYPE html> 2 <html> 3 <head> 4 <meta charset="UTF-8" /> 5 & ...

  10. 选择结构——switch语句

    1.switch语句 语法格式: switch (表达式){ case 常量 1: 语句; break; case 常量 2: 语句; break; case 常量 3: 语句; break; --- ...