《80x86汇编语言程序设计》保护模式第一个例题

《80x86汇编语言程序设计》保护模式第一个例题的一些个人理解和注视

1. ; 16位偏移的段间直接转移指令的宏定义
2. jump macro selector, offsetv
3. db 0eah                 ; jmp far 的操作码
4. dw offsetv
5. dw selector
6. endm
7. ; 字符显示宏指令定义
8. echoch macro ascii
9. mov ah, 2
10. mov dl, ascii
11. int 21h
12. endm
13. ; 存储段描述符结构类型的定义
14. descriptor struc
15. limitl      dw 0                ; 段界限低16位
16. basel       dw 0                ; 基地址低16位
17. basem       db 0                ; 基地址中8位
18. attributes  dw 0                ; 段属性，包含段界限高4位
19. baseh       db 0                ; 基地址高8位
20. descriptor ends
21. ; 伪描述符结构类型的定义
22. pdesc struc
23. limit       dw 0                ; 16位段界限
24. base        dd 0                ; 32位基地址
25. pdesc ends
26. ; 常量定义
27. atdw = 92h                      ; 存在的可读写数据段属性值
28. atce = 98h                      ; 存在的只执行代码段属性值
29. .386p
30. ; 数据段
31. dseg segment use16
32. gdt     label byte              ; 全局描述符表GDT
33. dummy       descriptor <>             ; 空描述符
34. code        descriptor <0ffffh, , , atce, >
35. code_sel    = code - gdt                ; 代码段描述的选择子
36. datas       descriptor <0ffffh, 0h, 11h, atdw, 0>
37. datas_sel   = datas - gdt               ; 源数据段描述符的选择子
38. datad       descriptor <0ffffh, , , atdw, >
39. datad_sel   = datad - gdt               ; 目标数据段描述符的选择子
40. gdtlen      = $ - gdt
41. vgdtr       pdesc <gdtlen - 1, >          ; 伪描述符
42. bufferlen   = 256                   ; 缓冲区字节长度
43. buffer      db bufferlen dup (0)            ; 缓冲区
44. dseg ends
45. ; 代码段
46. cseg segment use16
47. assume cs:cseg, ds:dseg
48. start:
49. mov ax, dseg
50. mov ds, ax
51. ; 准备要加载到gdtr的伪描述符
52. mov bx, 16
53. mul bx
54. add ax, offset gdt
55. adc dx, 0
56. mov word ptr vgdtr.base, ax
57. mov word ptr vgdtr.base + 2, dx
58. ; 设置代码段描述符
59. mov ax, cs
60. mul bx
61. mov code.basel, ax
62. mov code.basem, dl
63. mov code.baseh, dh
64. ; 设置目标数据段描述符
65. mov ax, ds
66. mul bx
67. add ax, offset buffer
68. adc dx, 0
69. mov datad.basel, ax
70. mov datad.basem, dl
71. mov datad.baseh, dh
72. ; 加载gdtr
73. lgdt fword ptr vgdtr
74. cli
75. call enablea20
76. ; 切换到保护方式
77. xchg bx, bx
78. mov eax, cr0
79. or eax, 1
80. mov cr0, eax
81. ; 清指令欲取队列，并真正进入保护方式
82. jump <code_sel>, <offset virtual>
83. virtual:
84. mov ax, datas_sel
85. mov ds, ax
86. mov ax, datad_sel
87. mov es, ax
88. cld
89. xor si, si
90. xor di, di
91. mov cx, bufferlen / 4
92. repz movsd
93. ; 切换回实方式
94. mov eax, cr0
95. and eax, 0fffffffeh
96. mov cr0, eax
97. ; 清指令预取队列，进入实方式
98. jump <seg real>, <offset real>
99. real:
100. call disablea20
101. sti
102. mov ax, dseg
103. mov ds, ax
104. mov si, offset buffer
105. cld
106. mov bp, bufferlen / 16
107. nextline:
108. mov cx, 16
109. nextch:
110. lodsb
111. push ax
112. shr al, 4
113. call toascii
114. xchg bx, bx
115. echoch al
116. xchg bx, bx
117. pop ax
118. call toascii
119. echoch al
120. echoch ' '
121. loop nextch
122. echoch 0dh
123. echoch 0ah
124. dec bp
125. jnz nextline
126. mov ax, 4c00h
127. int 21h
128. toascii  proc
129. and al, 0fh
130. add al, 30h
131. cmp al, '9'
132. jbe quit
133. add al, 7
134. quit:
135. ret
136. toascii endp
137. enablea20 proc
138. push ax
139. in al, 92h
140. or al, 2
141. out 92h, al
142. pop ax
143. ret
144. enablea20 endp
145. disablea20 proc
146. push ax
147. in al, 92h
148. and al, 0fdh
149. out 92h, al
150. pop ax
151. ret
152. disablea20 endp
153. cseg ends
154. end start

我自己以前的疑问与我自己的答案：

Q：为什么要设置GDTR？

A：应为需要他来找到GDT

Q：

1. mul bx

什么意思？

A：转换为物理地址，就是段值*16

Q：

1. jump <code_sel>, <offset virtual>

什么意思？

A：这条指令是在转换到保护模式之前预取到指令队列的，如果不预取，转换到保护模式后系统会把cs中的值以为是选择子，但其实他是段值，就无法执行下一条指令，也就是jmp，所以要预取这条宏，然后执行时把cs设置为选择子，刷新预取指令队列，引用：

“由此可见，执行这条jmp指令时CPU已经处于“保护方式”了（因为cr0中的PE已经被置成“保护方式”）。如果此条jmp指令如果不是在“实方式”下被预取到指令队列中，就无法执行到它，因为“cr0中的PE被置成保护方式”之后，cs中的值仍为实方式的段值，此时将当前ip加1，然后用cs:ip去取下面的这条jmp指令显然会失败，因为此时处于“保护方式”下的cpu会把cs中的内容理解为“选择子”，所以自然无法取得“紧接着的”jmp指令。”

Q：

1. shr al, 4

啥意思？

A：是要显示其高4位，然后下面pop后显示低四位

Q：

1. mov ax, datas_sel

什么意思？

A：datas_sel为选择子，值为8，换为二进制是1000，低三位分别是0位、1位为RPL，2位为TI，3~15位是描述符表索引，也即第一个描述符

>>>>>>>>>>>>>>>琐碎记忆>>>>>>>>>>>>>>>>>

保护方式下通过选择子的3~15位来定位在描述符表中的描述符，然后获得基地址、界限、属性

http://blog.csdn.net/programmingring/article/details/7385140