TRIGGER的使用（修改SP自动触发）

 CREATE TRIGGER [trg_save_change_SP]
 ON DATABASE
 FOR CREATE_PROCEDURE, ALTER_PROCEDURE,DROP_PROCEDURE
 AS
     DECLARE @data XML
     DECLARE @InstanceName nvarchar(200),
         @DBName    nvarchar(100) ,
         @ObjectID int,
         @Version    int ,
         @DBUser    nvarchar(100),
         @InDateTime datetime,
         @HostName nvarchar(200),
         @LoginName nvarchar(100),
         @EventName nvarchar(100),
         @ObjectName nvarchar(200)  ,
         @TSQL nvarchar(max),
         @ObjectType char(2),
         @SeqNo int            

     SET @data = EVENTDATA()

     SELECT
         @InstanceName = @@SERVERNAME   ,
         @DBName = DB_NAME(),
         @HostName = hostname,
         @DBUser = CONVERT(nvarchar(100), CURRENT_USER),
         @LoginName = @data.value('(/EVENT_INSTANCE/LoginName)[1]', 'nvarchar(100)'),
         @EventName = @data.value('(/EVENT_INSTANCE/EventType)[1]', 'nvarchar(100)'),
         @ObjectName= @data.value('(/EVENT_INSTANCE/ObjectName)[1]', 'nvarchar(400)'),
         @TSQL = @data.value('(/EVENT_INSTANCE/TSQLCommand)[1]', 'nvarchar(max)')
     FROM master..sysprocesses WHERE spid = @@spid    

     SELECT     @Version = ISNULL(MAX(Version),0) + 1 FROM admin.dbo.ObjectLog WHERE ObjectName = @ObjectName AND DBName = @DBName

     SELECT @ObjectType = type FROM sys.objects WHERE name = @ObjectName

     SELECT @SeqNo = ISNULL(MAX(SeqNo),0)+1 FROM admin.dbo.ObjectLog

     INSERT admin.dbo.ObjectLog(
         [SeqNo]
       , [DBName]
       , [ObjectID]
       , [ObjectName]
       , [Version]
       , [EventName]
       , [DBUser]
       , [HostName]
       , [LoginName]
       , [InDateTime]
       , [TSQL]
       , [CheckInChk]
       , [InstanceName]
       , [ObjectType]
 )
 VALUES(
           @SeqNo
         , @DBName
         , Object_ID(@ObjectName)
         , @ObjectName
         , @Version
         , @EventName
         , @DBUser
         , LTRIM(RTRIM(@HostName))
         , @LoginName
         , GETDATE()
         , @TSQL
         , ''
         , @InstanceName
         , @ObjectType)