参考：Statements Routines —— 控制语句关键字

01   FOR 循环语句。
02   FOREACH 循环语句。
03   WHILE...DO 循环语句。
04   IF...THEN...ELSE 选择语句。
05   CASE 只执行符合条件的一个语句块。 
06   SWITCH 执行符合条件后面的所有语句块。
07   REPEAT...UNTIL 循环语句。 
08   BEGIN...END 用于显示多条语句。
09   CONTINUE 执行循环语句中的下一条循环。
10   BREAK 从循环、CASE 或 SWITCH 语句中跳出。
序号 名称  

功能说明 & 语法 & 举例
01 FOR  

循环语句。
-----------------------------------------------------------------------------------------------
 FOR variable = init, limit [, Increment] DO statement 
-----------------------------------------------------------------------------------------------
 FOR variable = init, limit [, Increment] DO BEGIN 
    statements                                     
 ENDFOR                                           
-----------------------------------------------------------------------------------------------
◈ init：开始的数
◈ limit：结束的数
◈ Increment：增量值
◈ statement(s)：循环语句内容
  
IDL> FOR i = 1, 10, 4 DO PRINT, i

       1

       5

       9

  FOR i = 1, 10, 4 DO BEGIN

    PRINT, i

  ENDFOR
 02 FOREACH  

循环语句。
-----------------------------------------------------------------------------------------------
 FOREACH Element, Variable [, Index] DO Statement 
-----------------------------------------------------------------------------------------------
 FOREACH Element, Variable [, Index] DO BEGIN 
    statements                                
 ENDFOREACH                  
-----------------------------------------------------------------------------------------------
? Element：每一个元素
◈ Variable：数组变量
◈ Index：元素的索引值
◈ Statement(s)：循环语句内容
  
IDL> strs = ["alex", "bn", "lee"]

IDL> FOREACH e, strs, i DO PRINT, i, "--", e

                     0--alex

                     1--bn

                     2--lee

  strs = ["alex", "bn", "lee"]

  FOREACH e, strs, i DO BEGIN

    PRINT, i, "--", e

  ENDFOREACH
03 WHILE...DO  

循环语句。
-----------------------------------------------------------------------------------------------
 WHILE expression DO statement 
-----------------------------------------------------------------------------------------------
 WHILE expression DO BEGIN 
    statements             
 ENDWHILE                  
-----------------------------------------------------------------------------------------------
◈ expression：判断表达式
◈ statement(s)：循环语句
  
IDL> i = 3

IDL> WHILE(i gt 0) DO PRINT, i--

       3

       2

       1

  i = 3

  WHILE(i gt 0) DO BEGIN

    PRINT, i--

  ENDWHILE
04 IF...THEN...ELSE  

选择语句
-----------------------------------------------------------------------------------------------
 IF expression THEN statement 
-----------------------------------------------------------------------------------------------
 IF expression THEN statement ELSE statement 
-----------------------------------------------------------------------------------------------
 IF expression THEN BEGIN 
   statements             
 ENDIF                    
-----------------------------------------------------------------------------------------------
 IF expression THEN BEGIN 
   statements             
 ENDIF ELSE BEGIN         
   statements             
 ENDELSE                  
-----------------------------------------------------------------------------------------------
◈ expression：判断表达式
◈ statement(s)：语句内容
  
IDL> A = 2

IDL> B = 3

IDL> IF(A EQ 2) AND (B EQ 3) THEN PRINT, 'A = ', A, STRING(13B), 'B = ', B

A =        2

B =        3

IDL> A = 2

IDL> IF(A EQ 2) THEN PRINT, 'A = ', A ELSE PRINT, 'A ≠ ', A

A =        2

  A = 2

  B = 3

  IF(A EQ 2) AND (B EQ 3) THEN BEGIN

    PRINT, 'A = ', A

    PRINT, 'B = ', B

  ENDIF

  A = 2

  IF(A EQ 2) THEN BEGIN

    PRINT, 'A = ', A

  ENDIF ELSE BEGIN

    PRINT, 'A ≠ ', A

  ENDELSE
05 CASE  

只执行符合条件的一个语句块。(多条语句需要使用 BEGIN...END）
------------------------------------------------------------
 CASE expression OF           
     expression: statement(s) 
     ...                      
     expression: statement(s) 
 ENDCASE                      
------------------------------------------------------------
 CASE expression OF           
     expression: statement(s) 
     ...                      
     expression: statement(s) 
   ELSE: satement(s)          
 ENDCASE                      
------------------------------------------------------------
 CASE expression OF           
     expression: statement(s) 
     ...                      
     expression: statement(s) 
   ELSE: BEGIN                
     satement(s)              
   END                        
 ENDCASE                      
------------------------------------------------------------
◈ expression：判断语句
◈ statement(s)：执行语句
  
  x=1

  CASE x OF

     1: PRINT, 'one'

     2: PRINT, 'two'

  ENDCASE

IDL Prints:

one

  x=2

  CASE x OF

     1: PRINT, 'one'

     2: PRINT, 'two'

     ELSE: PRINT, 'You entered: ', x

  ENDCASE

IDL Prints:

two

  x=3

  CASE x OF

     1: PRINT, 'one'

     2: PRINT, 'two'

     ELSE: BEGIN

        PRINT, 'You entered: ', x

        PRINT, 'Please enter a value between 1 and 2'

     END

  ENDCASE

IDL Prints:

You entered: 3

Please enter a value between 1 and 2
06
 SWITCH

执行符合条件后面的所有语句块。       
-----------------------------------------------------------------------------------------------
 SWITCH expression OF         
     expression: statement(s) 
     ...                      
     expression: statement(s) 
 ENDSWITCH                    
-----------------------------------------------------------------------------------------------
 SWITCH expression OF         
     expression: statement(s) 
     ...                      
     expression: statement(s) 
   ELSE: satement(s)          
 ENDSWITCH                    
-----------------------------------------------------------------------------------------------
 SWITCH expression OF         
     expression: statement(s) 
     ...                      
     expression: statement(s) 
   ELSE: BEGIN                
     satement(s)              
   END                               
 ENDSWITCH                   
-----------------------------------------------------------------------------------------------
◈ expression：判断语句
◈ statement(s)：执行语句
  
  x=1

  SWITCH x OF

     1: PRINT, 'one'

     2: PRINT, 'two'

  ENDSWITCH

IDL Prints:

one

two

  x=2

  SWITCH x OF

     1: PRINT, 'one'

     2: PRINT, 'two'

     ELSE: PRINT, 'You entered: ', x

  ENDSWITCH

IDL Prints:

two

You entered:        2

  x=2

  SWITCH x OF

     1: PRINT, 'one'

     2: PRINT, 'two'

     ELSE: BEGIN

        PRINT, 'You entered: ', x

        PRINT, 'Please enter a value between 1 and 2'

     END

  ENDSWITCH

IDL Prints:

two

You entered:        2

Please enter a value between 1 and 2
07 REPEAT...UNTIL  

循环语句（与 WHILE...DO 语句类似）
-----------------------------------------------------------------------------------------------
REPEAT statement UNTIL expression
-----------------------------------------------------------------------------------------------
REPEAT BEGIN
   statements
ENDREP UNTIL expression
-----------------------------------------------------------------------------------------------
◈ statement(s)：执行语句
◈ expression：判断语句
  
IDL> i = 3

IDL> REPEAT PRINT, i-- UNTIL(i lt 0)

       3

       2

       1

       0

  i = 3

  REPEAT BEGIN

    PRINT, i--

  ENDREP UNTIL(i lt 0)
08 BEGIN...END  

用于显示多条语句。
-----------------------------------------------------------------------------------------------
BEGIN
   statements
END | ENDIF | ENDELSE | ENDFOR | ENDFOREACH | ENDREP | ENDWHILE
-----------------------------------------------------------------------------------------------
  
  CASE name OF

    'Moe': BEGIN

      PRINT, 'Stooge'

    END

  ENDCASE

  SWITCH name OF

    'Moe': BEGIN

      PRINT, 'Stooge'

    END

  ENDSWITCH
09  CONTINUE  

执行FOR、WHILE 或 REPEAT 循环语句中下一条循环。
  
  FOR I = 1,10 DO BEGIN

   ; If odd, start next iteration:

   IF (I AND 1) THEN CONTINUE

   PRINT, I

  ENDFOR

IDL Prints:

       2

       4

       6

       8

      10
10  BREAK  

从 FOR、WHILE、REPEAT 循环、CASE 或 SWITCH 语句中跳出。
  
  i = 0

  PRINT, 'Initial value: ', i

  WHILE (1) DO BEGIN

    i = i + 1

    IF (i eq 5) THEN BREAK

    PRINT, 'Loop value: ', i

  ENDWHILE

  PRINT, 'END VALUE: ', i

IDL Prints:

Initial value:        0

Loop value:        1

Loop value:        2

Loop value:        3

Loop value:        4

END VALUE:        5
       

【217】◀▶ IDL 控制语句说明的更多相关文章

  1. Linux Shell 流程控制语句

    * 本文主要介绍一些Linux Shell 常用的流程控制语句* 1. if 条件语句:if-then/if-elif-fi/if- else-fi if [条件判断逻辑1];then command ...

  2. 使用变量 数据类型转换 逻辑控制语句(begin ...end; case...end; if...else; while)

    一:变量 变量分为局部变量和全局变量  (全局变量是系统自定的,是不可手动给值的,若想自己定义全局变量可考虑创建全局临时表!) 局部变量的定义:  declare @变量名  数据类型 (局部变量只能 ...

  3. Sql Server系列：数据控制语句

    数据控制语句用来设置.更改用户或角色的权限,包括GRANT.DENY.REVOKE等语句. GRANT用来对用户授予权限,REVOKE可用于删除已授权的权限,DENY用于防止主体通过GRANT获得特定 ...

  4. 8-04流程控制语句BEGIN ..END

     流程控制语句: 是用来控制程序流程的语句. 常用的流程控制语句的分类: 顺序结构:BEGIN...END 分支结构: IF ..ELSE 或CASE ..END 循环结构:WHILE 顺序结构 语法 ...

  5. javaScript条件控制语句

    当某段代码的执行,需要首先满足某些条件时,我们就需要用到条件控制语句.判断条件是否满足,满足条件才去执行某些代码. 如判断数组中值等于条件值时,将这个值从数组中删除 a.switch <scri ...

  6. JAVA 1.7 流程控制语句 续

    1. Java中的循环控制语句一共有3种,分别是while,do… while以及for循环.2. while循环,形式为:while(布尔表达式){//待执行的代码}3. do…while循环,新式 ...

  7. JAVA 1.6 流程控制语句

    1. 条件运算符(三元表达式),其形式为:type d = a ? b : c; 具体化形式为:int d = 2 < 1 ? 3 : 4;2. 轻量级的文本编辑器:UltraEdit.Edit ...

  8. leetcode 217

    217. Contains Duplicate Given an array of integers, find if the array contains any duplicates. Your ...

  9. IDL中的HRESULT值

    IDL中的HRESULT值

随机推荐

  1. 前端学习——使用Ajax方式POST JSON数据包

    0.前言     本文解释怎样使用Jquery中的ajax方法传递JSON数据包,传递的方法使用POST(当然PUT又有时也是一个不错的选择).POST JSON数据包相比标准的POST格式可读性更好 ...

  2. 读陈浩的《C语言结构体里的成员数组和指针》总结，零长度数组

    原文链接:C语言结构体里的成员数组和指针 复制例如以下: 单看这文章的标题,你可能会认为好像没什么意思.你先别下这个结论,相信这篇文章会对你理解C语言有帮助.这篇文章产生的背景是在微博上,看到@Lar ...

  3. mysql存储过程之循环

    链接: http://www.blogjava.net/rain1102/archive/2011/05/16/350301.html

  4. Model Vaildation

    https://docs.asp.net/en/latest/mvc/models/validation.html 许多有用的验证属性都必须引用命名空间: System.ComponentModel. ...

  5. SDP, RTP, RTCP, RTSP, RTMP 名词解释

    读维基百科里的词条,记录的一点笔记. SDP 会话描述协议 Session Description Protocol 严格来说 SDP 不是一种协议,而是一种格式约定,用于描述流媒体的参数.如协商媒体 ...

  6. 基于EasyIPCamera实现的RTSP跨平台拉模式转发流媒体服务器

    本文转自博客:http://blog.csdn.net/xinlanbobo/article/details/53224445 上一篇博客<EasyIPCamera通过RTSP协议接入海康.大华 ...

  7. java四种线程池简介，使用

    为什么使用线程池 1.减少了创建和销毁线程的次数,每个工作线程都可以被重复利用,可执行多个任务. 2.可以根据系统的承受能力,调整线程池中工作线线程的数目,防止消耗过多的内存 3.web项目应该创建统 ...

  8. 什么是 AQS ？

    1.什么是AQS? AQS是英文单词AbstractQueuedSynchronizer的缩写,翻译过来就是队列同步器. 它是构建锁或者其他同步组件的基础框架(如ReentrantLock.Reent ...

  9. spring IOC（转）

    原文 http://stamen.iteye.com/blog/1489223 引述:IoC(控制反转:Inverse of Control)是Spring容器的内核,AOP.声明式事务等功能在此基础 ...

  10. qt使用中的一些问题(linux)

    ui_xxx.h的问题 工程中(工作空间)中包含的ui_xxx.h文件是系统自动生成的.这个是xxx.ui的创建文件来的,xxx.ui界面上的都是ui_xxx.h在控制的,在项目里是不显示这个头文件的 ...