[ActionScript 3.0] 如何控制加载swf动画的播放与暂停

此方法适用于用as 1.0或者as2.0以及as3.0编译的swf，因为as1.0和as2.0编译的swf是AVM1Movie类型，因此需要通过类ForcibleLoader.as将其转换为version 9以上的swf，注意，如果加载的swf是3.0代码编译的，且此swf用文档类编译，则文档类必须继承MovieClip,接下来看代码：

首先写一个加载swf的类SwfPlayer.as：

 package com.views
 {
     import com.controls.utils.ForcibleLoader;

     import flash.display.AVM1Movie;
     import flash.display.Loader;
     import flash.display.MovieClip;
     import flash.display.Shape;
     import flash.events.Event;
     import flash.net.URLRequest;

     /**
      * ...
      * @author Frost.Yen
      */
     public class SwfPlayer extends MovieClip
     {
         private var _loader:Loader;;
         private var _urlR:URLRequest;
         private var _url:String;
         private var _container:MovieClip;
         private var _mask:Shape;
         private var _forcibleLoader:ForcibleLoader;
         private var _stageW:Number;//swf实际的舞台宽度
         private var _stageH:Number;//swf实际的舞台高度
         public function SwfPlayer()
         {
             _mask = new Shape();
             _mask.graphics.beginFill(0);
             _mask.graphics.drawRect(0, 0, 10, 10);
             _mask.graphics.endFill();
             this.mask = _mask;
         }
         /**
          * 加载swf
          * @param    url swf路径
          */
         public function Load(url:String):void{
             this._url=url;
             if(!_loader){
                 _loader= new Loader()
             }
             _urlR=new URLRequest(_url);
             _loader.contentLoaderInfo.addEventListener(Event.COMPLETE,onComplete);
             _loader.load(_urlR);
         }

         private function onComplete(event:Event):void {

             if (_loader.content is AVM1Movie) {//如果是as2.0或者1.0代码生成的swf
                 trace("_loader.content is AVM1Movie");
                 _loader.unloadAndStop();
                 _forcibleLoader = new ForcibleLoader(_loader);
                 _forcibleLoader.load(_urlR);
                 return;
             }
             _loader.contentLoaderInfo.removeEventListener(Event.COMPLETE,onComplete);
             trace(_loader.contentLoaderInfo,_loader,"_loader");
             try
             {
                 _container = MovieClip(_loader.content);
                 _stageW = _loader.contentLoaderInfo.width;
                 _stageH = _loader.contentLoaderInfo.height;
                 this.addChild(_container);
             }
             catch(error:Error)
             {
                 trace(_loader.width,"_loader.width");

                 _stageW = _loader.width;
                 _stageH = _loader.height;
                 this.addChild(_loader);
             }

             _mask.width = _stageW;
             _mask.height = _stageH;

             this.addChild(_mask);
             this.dispatchEvent(new Event(Event.COMPLETE));
         }
         /**
          * 播放下一帧
          */
         public function nextPlay():void{
             if(_container.currentFrame==_container.totalFrames){
                 stop();
             }else{
                 _container.nextFrame();
             }
         }
         /**
          * 播放上一帧
          */
         public function prevPlay():void{
             if(_container.currentFrame==1){
                 stop();
             }else{
                 _container.prevFrame();
             }
         }
         /**
          * 开始播放
          */
         public function startPlay():void
         {
             _container.play();
         }
         /**
          * 暂停播放
          */
         public function pausePlay():void
         {
             _container.stop();
         }

         /**
          * 卸载加载的swf
          */
         public function unloadAndStop():void
         {

             if(_loader){
                 _loader.unloadAndStop();
                 _loader = null;

             }
             if(_container){
                 _container.parent.removeChild(_container);
                 _container = null;
             }

         }

         public function get stageW():Number
         {
             return _stageW;
         }

         public function set stageW(value:Number):void
         {
             _stageW = value;
         }

         public function get stageH():Number
         {
             return _stageH;
         }

         public function set stageH(value:Number):void
         {
             _stageH = value;
         }

     }

 }

然后在flash文档类Main.as中调用，flash文档舞台上有两个控制按钮stopBtn，playBtn：

 package
 {
     import com.views.SwfPlayer;
     import flash.display.Sprite;
     import flash.events.MouseEvent;
     /**
      * ...
      * @author Frost.Yen
      */
     public class Main extends Sprite
     {
         private var _swfPlayer:SwfPlayer;
         public function Main()
         {
             _swfPlayer = new SwfPlayer();
             this.addChild(_swfPlayer);
             _swfPlayer.load("D:/Flash学习/flash动画作品/1/1.swf");
             stopBtn.addEventListener(MouseEvent.CLICK,onStop);
             playBtn.addEventListener(MouseEvent.CLICK,onPlay);
         }
         private function onStop(e:MouseEvent):void
         {
             _swfPlayer.pausePlay();//暂停播放
         }
         private function onPlay(e:MouseEvent):void
         {
             _swfPlayer.startPlay();//开始播放
         }
     }
 }

附：此类ForcibleLoader.as可到http://download.csdn.net/detail/yan_frost/4771007下载