TWaver Flex开发示例及license下载

做电信项目的朋友一定知道TWaver，而Flex版具有很好的跨平台性，很适合做B/S模式的应用。

Flex版的在线DEMO：http://twaver.servasoft.com/demo/twaver_flex/twaver-flex-online-demo.html

TWaver提供了很多的电信组件，可以方便进行开发。

只是目前在网上很难找到开发用的  twaver.swc 文件，官网上需要申请才可以，而且限制条件颇多。本人幸得一个开发包和到2013.12.30的一个license文件，不敢独享，特在此分享给大家。虽然是测试用的，但不影响我们做DEMO使用。如果商业使用，还请联系TWaver公司，使用授权的版本。

同时奉上开发示例，程序如下：

 <?xml version="1.0" encoding="utf-8"?>
 <mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
                 xmlns:twaver="http://www.servasoftware.com/2009/twaver/flex"
                 applicationComplete="init()">
     <mx:XML source="license.xml" id="license"/>
     <mx:Script>
         <![CDATA[
             /***
              * TWaver Flex 示例程序，license到期时间为2013.12.30
              * author:liongis@163.com
              * date:2013.11.11
              **/ 

             import mx.controls.Alert;
             import mx.core.*;
             import mx.events.*;
             import mx.managers.*;

             import twaver.*;
             import twaver.network.Network;
             import twaver.network.interaction.*;

             private var box:ElementBox;
             private var number:int; 

             private function init():void
             {
                 trace(Utils.validateLicense(this.license).toString());

                 number=0;
                 box=network.elementBox;
                 tree.dataBox=box;
                 table.dataBox=box;
                 var group:Group=new Group();
                 group.name="group";
                 box.add(group);
                 group.addChild(createTWaverNode("node1",200,100));
                 group.addChild(createTWaverNode("node2",300,130));
                 group.expanded=true;
                 var from:Node=createTWaverNode("from",30,30);
                 var to:Node=createTWaverNode("to",70,150);
                 var link:Link=new Link(from,to);
                 link.name="hello TWaver Flex";
                 box.add(link); 

                 var format:String="twaver";
                 network.addEventListener(DragEvent.DRAG_ENTER,function(evt:DragEvent ):void{
                     if( evt.dragSource.hasFormat( format ) )
                     {
                         DragManager.acceptDragDrop(network);
                     }
                 });
                 network.addEventListener(DragEvent.DRAG_DROP,function ( evt:DragEvent ):void{
                     if(evt.dragInitiator==createNodeButton){
                         var centerLocation:Point=network.getLogicalPoint(evt as MouseEvent);
                         var node:Node=new Node();
                         node.centerLocation=centerLocation;
                         var parentNode:ISubNetwork=network.currentSubNetwork;
                         node.parent=parentNode;
                         network.elementBox.add(node);
                     }
                 });
                 createNodeButton.addEventListener(MouseEvent.MOUSE_DOWN,function (evt:MouseEvent ):void
                 {
                     var dragSource:DragSource = new DragSource();
                     dragSource.addData( createNodeButton, format );
                     DragManager.doDrag( createNodeButton, dragSource, evt );
                 });
             } 

             private function createTWaverNode(name:String,x:int,y:int):Node
             {
                 var node:Node=new Node();
                 node.name=name;
                 node.setClient("number",number++);
                 node.setLocation(x,y);
                 box.add(node);
                 return node;
             } 

             protected function button1_clickHandler(event:MouseEvent):void
             {
                 network.setDefaultInteractionHandlers();
             }

             protected function button2_clickHandler(event:MouseEvent):void
             {
                 network.setEditInteractionHandlers();
             }

             protected function button3_clickHandler(event:MouseEvent):void
             {
                 network.interactionHandlers = new Collection([
                     new SelectInteractionHandler(network),
                     new EditInteractionHandler(network),
                     new MoveInteractionHandler(network),
                     new DefaultInteractionHandler(network),
                     new MapFilterInteractionHandler(network),
                 ]);
             }

             protected function button4_clickHandler(event:MouseEvent):void
             {
                 network.interactionHandlers = new Collection([
                     new SelectInteractionHandler(network),
                     new EditInteractionHandler(network),
                     new MoveInteractionHandler(network),
                     new DefaultInteractionHandler(network),
                     new MapFilterInteractionHandler(network, Consts.MAP_FILTER_MAGNIFY),
                 ]);
             }

             protected function button5_clickHandler(event:MouseEvent):void
             {
                 network.setCreateLinkInteractionHandlers();
             }

             protected function button6_clickHandler(event:MouseEvent):void
             {
                 network.setCreateShapeLinkInteractionHandlers(ShapeLink);
             }

             protected function button7_clickHandler(event:MouseEvent):void
             {
                 network.setCreateShapeNodeInteractionHandlers();
             }

         ]]>
     </mx:Script>
     <mx:Panel title="Hello TWaver! - Tree, Network &amp; Table" width="100%" height="100%">
         <mx:HDividedBox width="100%" height="100%">
             <twaver:Tree id="tree" width="30%" height="100%"/>
             <mx:VDividedBox width="100%" height="100%">
                 <mx:Panel title="Hello TWaver! - Network Interaction Mode" width="100%" height="100%" verticalGap="0">
                     <mx:HBox width="100%" horizontalGap="0" >
                         <mx:Button label="Default" click="button1_clickHandler(event)"/>
                         <mx:Button label="Editor" click="button2_clickHandler(event)"/>
                         <mx:Button label="FishEye" click="button3_clickHandler(event)"/>
                         <mx:Button label="Magnify" click="button4_clickHandler(event)"/>
                         <mx:Button label="CreateNode" id="createNodeButton"/>
                         <mx:Button label="CreateLink" click="button5_clickHandler(event)"/>
                         <mx:Button label="CreateShapeLink" click="button6_clickHandler(event)"/>
                         <mx:Button label="CreateShapeNode" click="button7_clickHandler(event)"/>
                     </mx:HBox>
                     <twaver:Network id="network" width="100%" height="100%">
                     </twaver:Network>
                 </mx:Panel>
                 <twaver:Table width="100%" height="30%" id="table" editable="true">
                     <twaver:columns>
                         <twaver:TableColumn dataField="name" headerText="Name"/>
                         <twaver:TableColumn dataField="id" headerText="ID"/>
                         <twaver:TableColumn dataField="icon" headerText="Icon"/>
                         <twaver:TableColumn dataField="C:number" headerText="Number"/>
                     </twaver:columns>
                 </twaver:Table>
             </mx:VDividedBox>
         </mx:HDividedBox>
     </mx:Panel>
 </mx:Application>

程序说明：

<mx:XML source="license.xml" id="license"/>为引用 license 文件。

并在程序初始化完后，使用 Utils.validateLicense(this.license).toString() 进行验证，如果返回的结果为 true 则 license 文件为有效的。

最终运行的效果如下：

有兴趣的朋友可以通过下面的地址下载：

http://files.cnblogs.com/liongis/TWaverTest.zip

license到期时间为2013.12.31，需要的朋友赶快下载。