[ActionScript 3.0] 框选裁剪

 package
 {
     import flash.display.Bitmap;
     import flash.display.BitmapData;
     import flash.display.Loader;
     import flash.display.Shape;
     import flash.display.Sprite;
     import flash.events.Event;
     import flash.events.MouseEvent;
     import flash.geom.Point;
     import flash.geom.Rectangle;
     import flash.net.URLRequest;
     import flash.utils.ByteArray;

     /**
       * ...
       * @author Frost.Yen
       */
     public class CutOut extends Sprite
     {
         private var ldr:Loader;
         private var cutContainer:Sprite;//存放裁剪的图片的容器
         private var primitiveContainer:Sprite;//存放原始图片的容器
         private var frame:Shape;//裁剪框
         private var downPoint:Point=new Point();
         private var bytearr:ByteArray=new ByteArray();

         public function CutOut():void
         {
             init();
         }

         private function init():void
         {
             this.graphics.beginFill(0xcccccc);
             this.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
             this.graphics.endFill();

             cutContainer = new Sprite();
             primitiveContainer = new Sprite();
             frame = new Shape();

             cutContainer.x = 400;

             this.addChild(primitiveContainer);
             this.addChild(cutContainer);
             this.addChild(frame);

             ldr = new Loader();
             ldr.load(new URLRequest("http://hiphotos.baidu.com/frostyen/pic/item/7e49d8b53f6b48ffd9335aa2.jpg"));
             ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);
             primitiveContainer.addChild(ldr);
             this.addEventListener(MouseEvent.MOUSE_DOWN, onStageDown);
             stage.addEventListener(MouseEvent.MOUSE_UP, onStageUp);
         }
         private function onStageDown(e:MouseEvent):void
         {
             while (cutContainer.numChildren>0)
             {
                 cutContainer.removeChildAt(0);
             }

             downPoint.x = mouseX;
             downPoint.y = mouseY;
             frame.graphics.clear();
             primitiveContainer.addEventListener(MouseEvent.MOUSE_MOVE,onMove);
         }

         private function onMove(e:MouseEvent):void
         {
             frame.graphics.clear();
             frame.graphics.lineStyle(1,0xff00ff);
             frame.graphics.drawRect(0, 0, mouseX - downPoint.x, mouseY - downPoint.y);
             frame.x = downPoint.x;
             frame.y = downPoint.y;
         }

         private function onStageUp(e:MouseEvent):void
         {
             primitiveContainer.removeEventListener(MouseEvent.MOUSE_MOVE,onMove);
             if (frame.width != 0)
             {
                 var bmpd1:BitmapData = new BitmapData(primitiveContainer.width,primitiveContainer.height);
                 bmpd1.draw(primitiveContainer);
                 bytearr = bmpd1.getPixels(new Rectangle(frame.x,frame.y,frame.width,frame.height));
                 bytearr.position = 0;
                 var bmpd2:BitmapData = new BitmapData(frame.width,frame.height);
                 try
                 {
                     bmpd2.setPixels(new Rectangle(0,0,frame.width,frame.height),bytearr);
                 }
                 catch (err:Error)
                 {
                     trace(err.message);//若裁剪框拉的范围超出原始图像范围会报此错，若解决，需深究.
                     frame.graphics.clear();
                     return;
                 }
                 var bmp:Bitmap = new Bitmap(bmpd2);
                 cutContainer.addChild(bmp);
             }

         }

         private function onComplete(e:Event):void
         {
             ldr.scaleX = ldr.scaleY = 0.6;
         }

     }

 }