SQL Server 2005/2008/2012中应用分布式分区视图

　　自2000版本起，SQL Server企业版中引入分布式分区视图，允许你为分布在不同的SQL 实例的两个或多个水平分区表创建视图。

　　简要步骤如下：根据Check约束中定义的一组值把大表分割成更小的一些表。Check约束确保每个小表保存着不能保存在其他表的唯一数据。然后使用Union All创建分布式分区视图，把所有这些小表联结成单独的结果集。

　　这样对性能的改善是有益的，例如，如果视图根据日期分区，并用查询来返回仅保存在一个分区表中的行，那么SQL Server会智能地只搜索一个分区而不是分布式分区视图中的所有表。

　　我们假设一个场景，某公司成立上海和北京分公司，分别有各自的SQL Server实例来保存网站数据，都希望用一个表跟踪网站点击。点击量非常大。此时，需要一个视图以在单个视图中引用各自的表。公司希望能查询任意一个服务器，并且返回相同的数据或各自分公司的数据。

　　下面我们通过实例来演示这个场景的具体应用。假定有两个实例：AP4\NET2012和AP4\NET2013（本文所有示例均在SQL Server 2008环境下通过）。

一、创建链接服务器，当然也可以通过OpenRowset（http://msdn.microsoft.com/zh-cn/library/ms190312.aspx）而不创建链接服务器，并创建测试数据库和表。

1. /********* 创建一个分布式分区视图 ***************/
2. /********* 3w@live.cn 邀月 ***************/
3. USE master
4. GO
5. EXEC sp_addlinkedserver
6. 'AP4\NET2013',
7. N'SQL Server'
8. GO
9. -- 跳过远程实例架构表的检查，以提升性能，邀月注
10. EXEC sp_serveroption 'AP4\NET2013', 'lazy schema validation', 'true'
11. GO
12. --创建测试数据库
13. IF NOT EXISTS (SELECT name
14. FROM sys.databases
15. WHERE name = 'RemoteViewTest2012')
16. BEGIN
17. CREATE DATABASE RemoteViewTest2012
18. END
19. GO
20. --打开测试库
21. Use RemoteViewTest2012
22. GO
23. --创建上海分公司的点击表
24. CREATE TABLE dbo.WebHits_ShangHai
25. (WebHitID uniqueidentifier NOT NULL,
26. WebSite varchar(20) NOT NULL ,
27. HitDT datetime NOT NULL,
28. CHECK (WebSite = 'ShangHai'),
29. CONSTRAINT PK_WebHits PRIMARY KEY (WebHitID, WebSite))

第二个实例：

1. /***************　实例 AP4\NET2013(SQL Server 2008) *********/
2. /********* 3w@live.cn 邀月 ***************/
3. USE master
4. GO
5. EXEC sp_addlinkedserver
6. 'AP4\NET2012',
7. N'SQL Server'
8. GO
9. -- 跳过远程实例架构表的检查，以提升性能，邀月注
10. EXEC sp_serveroption 'AP4\NET2012', 'lazy schema validation', 'true'
11. GO
12. IF NOT EXISTS (SELECT name
13. FROM sys.databases
14. WHERE name = 'RemoteViewTest2012')
15. BEGIN
16. CREATE DATABASE RemoteViewTest2012
17. END
18. GO
19. --打开测试库
20. Use RemoteViewTest2012
21. GO
22. --创建北京分公司的点击表
23. CREATE TABLE dbo.WebHits_BeiJing
24. (WebHitID uniqueidentifier NOT NULL,
25. WebSite varchar(20) NOT NULL ,
26. HitDT datetime NOT NULL,
27. CHECK (WebSite = 'BeiJing'),
28. CONSTRAINT PK_WebHits PRIMARY KEY (WebHitID, WebSite))

二、在两个实例中分别创建视图

1. /***************　实例 AP4\NET2012(SQL Server 2008) *********/
2. /********* 3w@live.cn 邀月 ***************/
3. --打开测试库
4. Use RemoteViewTest2012
5. GO
6. --创建分区视图
7. CREATE VIEW dbo.v_WebHits AS
8. SELECT WebHitID,
9. WebSite,
10. HitDT
11. FROM RemoteViewTest2012.dbo.WebHits_ShangHai
12. UNION ALL
13. SELECT WebHitID,
14. WebSite,
15. HitDT
16. FROM [AP4\NET2013].RemoteViewTest2012.dbo.WebHits_BeiJing
17. GO
18. /***************　实例 AP4\NET2013(SQL Server 2008) *********/
19. /********* 3w@live.cn 邀月 ***************/
20. --打开测试库
21. Use RemoteViewTest2012
22. GO
23. --创建分区视图
24. CREATE VIEW dbo.v_WebHits AS
25. SELECT WebHitID,
26. WebSite,
27. HitDT
28. FROM RemoteViewTest2012.dbo.WebHits_BeiJing
29. UNION ALL
30. SELECT WebHitID,
31. WebSite,
32. HitDT
33. FROM [AP4\NET2012].RemoteViewTest2012.dbo.WebHits_ShangHai
34. GO

三、插入测试数据

我们可以选择任意一个实例中插入，下面我们选择AP4\NET2013

1. /***************　实例 AP4\NET2013(SQL Server 2008) *********/
2. /********* 3w@live.cn 邀月 ***************/
3. ----要保证插入，必须打开XACT_ABORT开关，并开启分布式事务协调器，邀月注
4. --打开测试库
5. Use RemoteViewTest2012
6. GO
7. SET XACT_ABORT ON
8. INSERT dbo.v_WebHits
9. (WebHitID, WebSite, HitDT)
10. VALUES(NEWID(), 'ShangHai', GETDATE())
11. INSERT dbo.v_WebHits
12. (WebHitID, WebSite, HitDT)
13. VALUES(NEWID(), 'BeiJing', GETDATE())

　　注意，如果该实例所在的服务器上没有启用MSDTC（Microsoft 分布式事务处理协调器），会抛出一个错误：

　　此时在命令行中输入Net start msdtc以启用该服务。

　　如果还是不能正常启动MSDTC，请查阅MSDN（http://msdn.microsoft.com/zh-cn/library/aa561924%28BTS.10%29.aspx）以获取帮助。

四、进行分布式查询

　　此时，我们在任意一个实例查询的结果都是一致的，也正是我们想要的。

1. /***************　实例 AP4\NET2013(SQL Server 2008) *********/
2. /********* 3w@live.cn 邀月 ***************/
3. /***** 分布式查询 　**************/
4. ----AP4\NET2013上查询
5. --打开测试库
6. Use RemoteViewTest2012
7. GO
8. SET XACT_ABORT ON
9. SELECT WebHitID, WebSite, HitDT
10. FROM dbo.v_WebHits
11. SELECT WebHitID, WebSite, HitDT
12. FROM [AP4\NET2012].RemoteViewTest2012.dbo.WebHits_ShangHai

1. ----AP4\N ET2012上查询
2. --打开测试库
3. Use RemoteViewTest2012
4. GO
5. SET XACT_ABORT ON
6. SELECT WebHitID, WebSite, HitDT
7. FROM dbo.v_WebHits
8. SELECT WebHitID, WebSite, HitDT
9. FROM [AP4\NET2013].RemoteViewTest2012.dbo.WebHits_BeiJing

　　

　　我们欣喜地看到，SQL Server并没有在基础分区表中插入冗余数据，而是自动分发到了Check所约定的相应的表中，这得益于MSDTC的功劳。

　　注意：创建分布式视图的注意事项和必要条件，请看MSDN（http://msdn.microsoft.com/zh-cn/library/ms188299.aspx）。

　　小结：分布式分区视图允许我们跨多个SQL Server实例划分数据。对于超大型数据库和拥有大量事务和读操作的SQL Server实例来说，这种设计让我们获益良多。根据被查询的视图，SQL Server能确定只查询本地分区表是否能满足某个查询请求，远程表是否需要查询，最终，SQL Server会最大限度地减少SQL Server实例间传输的数据总量。

 

邀月注：本文版权由邀月和CSDN共同所有，转载请注明出处。
助人等于自助!   3w@live.cn