salesforce 零基础开发入门学习（八）数据分页简单制作

本篇介绍通过使用VF自带标签和Apex实现简单的数据翻页功能。

代码上来之前首先简单介绍一下本篇用到的主要知识：

1.ApexPages命名空间

此命名空间下的类用于VF的控制。

主要的类包括但不限于以下：

• ApexPages.StandardController:当为一个标准Controller定义扩展的时候使用此类。StandardController对象为Salesforce提供的预构建VF的控制器对象引用;
• ApexPages.Action:使用Action类和方法用于VF自定义控制器和扩展中，实现前后台交互;
• ApexPages.Message:可以使用此类将信息传递到前台显示，常用于显示异常信息（系统异常or自定义异常）;

2.PageReference类

　　PageReference类位于System命名空间下，用于一个实例化页面的引用。他的作用为可以通过方法将结果导航到其他页面，可以视图。

3.基础知识（当我没说）

　　如果此部分掌握不好，请移步官方PDF文档，先好好钻研一下基础知识。毕竟基础还是最重要的。

　　注：上述只是介绍较为常用的内容，如果需要深入了解关于前后台交互的内容，请详细查阅官方PDF，掌握好ApexPages以及Controller等等之间的关系及交互。

废话少说，上代码，以Goods表为例，前几篇有过介绍，这里只是说一下里面的field主要内容：

GoodsName__c, GoodsType__c, GoodsBrands__c, GoodsPrice__c。

 public class CategoryWrapper {
     public Boolean checked{ get; set; }
     public GOODS__c goods { get; set;}

     public CategoryWrapper(){
         goods = new GOODS__c();
         checked = false;
     }

     public CategoryWrapper(GOODS__c goods){
         this.goods = goods;
         checked = false;
     }
 }

CategoryWrapper类有两个变量，一个为Goods对象，用来获取商品基本信息，一个为布尔类型的checked，用来作为判断数据行是否被选的属性。

 public with sharing class PagingController {

     List<categoryWrapper> categories {get;set;}

     // instantiate the StandardSetController from a query locator
     public ApexPages.StandardSetController con {
         get {
             if(con == null) {
                 con = new ApexPages.StandardSetController(Database.getQueryLocator([SELECT  GOODSBRAND__c,GOODSDESCRIBE__c,GOODSNAME__c, GOODSTYPE__c, GoodsPrice__c, IsStatus__c, Id FROM GOODS__c limit 100]));
                 // sets the number of records in each page set
                 con.setPageSize(20);
             }
             return con;
         }
         set;
     }

     // returns a list of wrapper objects for the sObjects in the current page set
     public List<categoryWrapper> getCategories() {
         categories = new List<categoryWrapper>();
         for (GOODS__c category1 : (List<GOODS__c>)con.getRecords())
             categories.add(new CategoryWrapper(category1));

         return categories;
     }

     // displays the selected items
      public PageReference process() {
          for (CategoryWrapper cw : categories) {
              if (cw.checked)
                  ApexPages.addMessage(new ApexPages.message(ApexPages.severity.INFO,cw.goods.GOODSNAME__c));
          }
          return null;
      }

     // indicates whether there are more records after the current page set.
     public Boolean hasNext {
         get {
             return con.getHasNext();
         }
         set;
     }

     // indicates whether there are more records before the current page set.
     public Boolean hasPrevious {
         get {
             return con.getHasPrevious();
         }
         set;
     }

     // returns the page number of the current page set
     public Integer pageNumber {
         get {
             return con.getPageNumber();
         }
         set;
     }

     // returns the first page of records
      public void first() {
          con.first();
      }

      // returns the last page of records
      public void last() {
          con.last();
      }

      // returns the previous page of records
      public void previous() {
          con.previous();
      }

      // returns the next page of records
      public void next() {
          con.next();
      }

      // returns the PageReference of the original page, if known, or the home page.
      public void cancel() {
          con.cancel();
      }

 }

使用StandardController控制页面显示的内容以及每页显示多少行数据，是否含有上一页下一页等等功能。通过PageReference作为当前页面的引用，控制页面数据。

 <apex:page controller="PagingController">
     <apex:form >
         <apex:pageBlock title="Goods">

             <apex:pageBlockButtons location="top">
                 <apex:commandButton action="{!process}" value="Selected" />
                 <apex:commandButton action="{!cancel}" value="Cancel" />
             </apex:pageBlockButtons>
             <apex:pageMessages />

             <apex:pageBlockSection title="Goods -  Page {!pageNumber}" columns="1">
                 <apex:pageBlockTable value="{!categories}" var="c">
                     <apex:column width="25px">
                         <apex:inputCheckbox value="{!c.checked}" />
                     </apex:column>
                     <apex:column value="{!c.goods.GoodsName__c}" headerValue="Name" />
                     <apex:column value="{!c.goods.GoodsType__c}" headerValue="type" />
                     <apex:column value="{!c.goods.GoodsBrand__c}" headerValue="brand" />
                     <apex:column value="{!c.goods.GoodsPrice__c}" headerValue="Price" />
                 </apex:pageBlockTable>
             </apex:pageBlockSection>
         </apex:pageBlock>

         <apex:panelGrid columns="4">
             <apex:commandLink action="{!first}">First</apex:commandlink>
                 <apex:commandLink action="{!previous}" rendered="{!hasPrevious}">Previous</apex:commandlink>
                     <apex:commandLink action="{!next}" rendered="{!hasNext}">Next</apex:commandlink>
                         <apex:commandLink action="{!last}">Last</apex:commandlink>
         </apex:panelGrid>

     </apex:form>
 </apex:page>

页面显示样式如下：

总结：本篇只是简单的实现数据分页功能，在真正项目中应该很少会有直接使用VF标签和使用Apex接口配合实现分页的（吐槽：自动忽略。。。因为VF的布局很丑），通常使用HTML的布局结合着Controller实现精美样式， 不过可以通过本篇的内容了解ApexPage命名空间里的类和VF页面的关系以及PageReference的用法和作用，如果内容有写的错误的地方欢迎批评指正，如果有问题，请留言。