状压DP——【蜀传之单刀赴会】

某王   老师今天考了一套三国题，AK了。。。就挑一道最恶心的题来写一写吧。

题目描述：

【题目背景】

公元215年，刘备取益州，孙权令诸葛瑾找刘备索要荆州。刘备不答应，孙权极为恼恨，便派吕蒙率军取长沙、零陵、桂阳三郡。长沙、桂阳蜀将当即投降。刘备得知后，亲自从成都赶到公安(今湖北公安)，派大将关羽争夺三郡。孙权也随即进驻陆口，派鲁肃屯兵益阳，抵挡关羽。双方剑拔弩张，孙刘联盟面临破裂，在这紧要关头，鲁肃为了维护孙刘联盟，不给曹操可乘之机，决定当面和关羽商谈。“肃邀羽相见，各驻兵马百步上，但诸将军单刀俱会”。双方经过会谈，缓和了紧张局势。随后，孙权与刘备商定平分荆州，“割湘水为界，于是罢军”，孙刘联盟因此能继续维持。

【问题描述】

关羽受鲁肃邀请，为了大局，他决定冒险赴会。他带着侍从周仓，义子关平，骑着赤兔马，手持青龙偃月刀，从军营出发了，这就是历史上赫赫有名的“单刀赴会”。关羽平时因为军务繁重，决定在这次出行中拜访几个多日不见的好朋友。然而局势紧张，这次出行要在限定时间内完成，关公希望你能够帮助他安排一下行程，安排一种出行方式，使得从军营出发，到达鲁肃处赴会再回来，同时拜访到尽可能多的朋友，在满足这些条件下行程最短。注意拜访朋友可以在赴会之前，也可以在赴会之后。现在给出地图，请你完成接下来的任务。

输入

第一行n,m,k,t,代表有n个地点，m条道路,有k个朋友(不包括鲁肃)，以及限定时间t(行走1单位长度的路程用时1单位时间)。

接下来m行，每行有x,y,w三个整数，代表x和y之间有长度为w的道路相连。

接下来一行有k个整数，代表朋友所在的都城编号(保证两两不同，且不在1和n)

（我们约定1是关羽的营地，n是鲁肃的营地）

输出

输出两个整数，分别是最多可以拜访的朋友数，以及在这种情况下最少需要耗费的时间，如果连到达鲁肃再回来都无法完成，输出一个-1就可以了。

样例输入

5 7 2 15

1 2 5

1 3 3

2 3 1

2 4 1

3 4 4

2 5 2

4 5 3

2 4

样例输出

2 14

提示

【数据规模和约定】

有10%数据，n<=10,m<=50,k<=5;

有10%数据,k=0;

有10%数据,k=1;

另30%数据，k<=5;

对于100%数据，n<=10000,m<=50000,k<=15,t<=2147483647,w<=10000

思路分析：

很清楚的数据范围，很好想的状压DP，很恶心的代码实现。

嗯，这就是我对这题的评价了。

读完题目，很清楚，整张图中只有k+2个点是有用的，分别为：关羽的营地、k个朋友的家以及鲁肃的营地。所以我们可以对其进行预处理，跑k+2遍单源最短路（我跑的是Dijkstra），然后就可以开始状压了！

既然是状压DP，那么我们应该压啥呢？——还能压啥啊？压k走起啊！

二进制状态sta，每一位上的0/1表示这个朋友也没有被访问过。那么我们就可以顺利地写出状态：dp[sta,i]表示在状态sta下，关羽现在正在第i位朋友的家中，所花费的时间的最小值。

那么我们便可以通过再枚举一个j表示关羽下一次要去第j个朋友的家，进行转移。转移方程便为：

dp[sta|1<<j-1,j]=min(dp[sta|1<<j-1,j],dp[sta,i]+d[i,a[j]]);

其中d数组，d[i,j]表示以i为源点到城市j的最小时间花费。a数组，a[i]表示关羽的第i位朋友住在城市a[i]。

时间复杂度就是n²*2ⁿ+k*(n+m)log n。

那么有些人可能会想：能不能用类似于【愤怒的小鸟】的优化方法把状压DP的时间优化成n*2ⁿ呢？

深入思考一下发现这其实是不可行的。

我们能把【愤怒的小鸟】优化掉一个n是因为每一只猪都必须被打掉，而且先打和后打是没有区别的，所以我们可以强制让他打一只猪，而这题不一样，关羽并不是一定要访问完k个朋友，没有他一定要访问的朋友，所以不能采用类似的方法来优化。

代码实现：

type
  hehe=record
    dist,id:longint;
end;
var
  f:array[1..2000000]of hehe;
  s:array[1..150000]of longint;
  dp:array[0..150000,0..20]of longint;
  a:array[0..20]of longint;
  head,visit:array[1..10000]of longint;
  d:array[1..20,1..10000]of longint;
  next,vet,dist:array[1..100000]of longint;
  n,m,t,i,j,k,sta,weight,x,y,z,tot,oo,ans,mi:longint;
procedure add(x,y,z:longint);
begin
  inc(tot);
  next[tot]:=head[x];
  head[x]:=tot;
  vet[tot]:=y;
  dist[tot]:=z;
end;
function min(x,y:longint):longint;
begin
  if x<y then exit(x) else exit(y);
end;
procedure swap(x,y:longint);
var
  t:hehe;
begin
  t:=f[x]; f[x]:=f[y]; f[y]:=t;
end;
procedure doit(x,k:longint);
begin
  if x>1<<17 then exit;
  s[x]:=k;
  doit(x*2,k); doit(x*2+1,k+1);
end;
procedure up(x:longint);
begin
  if x=1 then exit;
  if f[x].dist<f[x div 2].dist then begin swap(x,x div 2); up(x div 2); end;
end;
procedure down(x:longint);
var
  k:longint;
begin
  if x*2>weight then exit;
  k:=min(f[x*2].dist,f[x*2+1].dist);
  if f[x].dist>k then
    if k=f[x*2].dist then begin swap(x,x*2); down(x*2); end
    else begin swap(x,x*2+1); down(x*2+1); end;
end;
procedure push(x,id:longint);
begin
  inc(weight);
  f[weight].dist:=x;
  f[weight].id:=id;
  up(weight);
end;
procedure pop;
begin
  x:=f[1].id;
  f[1].dist:=f[weight].dist;
  f[1].id:=f[weight].id;
  f[weight].dist:=oo;
  f[weight].id:=oo;
  dec(weight);
  down(1);
end;
procedure dijkstra(k,s:longint);
var
  y,i:longint;
begin
  fillchar(f,sizeof(f),$7f);
  fillchar(visit,sizeof(visit),0);
  push(0,s); d[k,s]:=0;
  while weight>0 do
  begin
    pop;
    if visit[x]=1 then continue;
    i:=head[x]; visit[x]:=1;
    while i<>0 do
    begin
      y:=vet[i];
      if d[k,y]>d[k,x]+dist[i] then
        begin d[k,y]:=d[k,x]+dist[i]; push(d[k,y],y); end;
      i:=next[i];
    end;
  end;
end;
begin
  doit(1,1);
  read(n,m,k,t);
  for i:=1 to m do
  begin
    read(x,y,z);
    add(x,y,z); add(y,x,z);
  end;
  fillchar(d,sizeof(d),$7f); oo:=d[1,1];
  dijkstra(1,1); inc(k); a[1]:=1;
  for i:=2 to k do
  begin
    read(a[i]);
    dijkstra(i,a[i]);
  end;
  inc(k); a[k]:=n;
  dijkstra(k,n);
  fillchar(dp,sizeof(dp),$7f);
  dp[1,1]:=0;
  for sta:=1 to 1<<k-2 do
    for i:=1 to k do
      if dp[sta,i]<>oo then
      for j:=2 to k do
        dp[(sta)or(1<<(j-1)),j]:=min(dp[(sta)or(1<<(j-1)),j],dp[sta,i]+d[i,a[j]]);
      mi:=oo;
  for sta:=1 to 1<<k-1 do
  if sta>>(k-1)=1 then
    for i:=2 to k do
      if dp[sta,i]+d[i,1]<=t then
        if s[sta]-2>ans then begin ans:=s[sta]-2; mi:=dp[sta,i]+d[i,1]; end
        else
          if (s[sta]-2=ans)and(dp[sta,i]+d[i,1]<mi) then mi:=dp[sta,i]+d[i,1];
  if mi=oo then writeln(-1) else writeln(ans,' ',mi);
end.