[ActionScript3.0] 使用FileReferenceList处理多个文件上载

 package
 {
     import flash.display.Sprite;
     import flash.events.DataEvent;
     import flash.events.Event;
     import flash.events.MouseEvent;
     import flash.events.ProgressEvent;
     import flash.net.FileFilter;
     import flash.net.FileReference;
     import flash.net.FileReferenceList;
     import flash.net.URLRequest;
     import flash.net.URLRequestMethod;
     import flash.net.URLVariables;
     import flash.text.TextField;
     import flash.text.TextFieldAutoSize;
     /**
     * ...
     * @author Frost.Yen
     */
     public class UploadListAS3 extends Sprite
     {
         private var _label:TextField;
         private var _button:TextField;
         private var _fileRefer:FileReferenceList;
         private var _count:int = 0;
         private var _request:URLRequest = new URLRequest("http://localhost/yanzimen/");
         public function UploadListAS3()
         {
             if(stage) init();
             else addEventListener(Event.ADDED_TO_STAGE,init);
         }
         private function init(e:Event = null):void
         {
             _label = new TextField();
             _label.text = "please select file";
             _label.autoSize = TextFieldAutoSize.LEFT;
             _label.background = true;
             _label.width = 300;
             _label.wordWrap = true;
             _label.backgroundColor = 0xffffff;
             _label.border = true;
             _button = new TextField();
             _button.text = "click here to select file";
             _button.autoSize = TextFieldAutoSize.LEFT;
             _button.selectable = false;
             _button.background = true;
             _button.backgroundColor = 0xE29966;
             _button.border = true;
             this.addChild(_label);
             this.addChild(_button);
             _button.x = 310;

             _fileRefer = new FileReferenceList();
             _button.addEventListener(MouseEvent.CLICK,toSelect);
             _fileRefer.addEventListener(Event.SELECT,onSelect);
             _fileRefer.addEventListener(Event.CANCEL,onCancel);
         }
         private function toSelect(e:MouseEvent):void
         {
             _fileRefer.browse(); //browse(typeFilter:Array=null) 使用 typeFilter 参数，可决定对话框显示哪些文件。
             _button.removeEventListener(MouseEvent.CLICK,toSelect);
         }
         private function onProgress(e:ProgressEvent):void
         {
             _label.text = Number(Math.round(e.bytesLoaded / e.bytesTotal*100))+"%";
             //label.text = e.bytesLoaded+"/"+e.bytesTotal;
         }
         private function onComplete(e:Event):void
         {
             e.target.removeEventListener(Event.COMPLETE,onComplete);
             e.target.removeEventListener(ProgressEvent.PROGRESS,onProgress);

             if(_count<_fileRefer.fileList.length-1){
                 _label.text = "load complete "+(_count+1)+" file";
                 _count++;
             }else{
                 _count=0;
                 _button.addEventListener(MouseEvent.CLICK,toUpload);
                 _label.text = "all files load complete!";
                 _button.text = "to upload";
             }
         }
         private function toUpload(e:MouseEvent):void{
             onUpLoad(_fileRefer.fileList[_count]);
         }
         private function onSelect(e:Event):void
         {
             _label.text = "";
             for(var i:int = 0;i<_fileRefer.fileList.length;i++){
                 trace("the name of the selected file:",_fileRefer.fileList[i].name);
                 _label.appendText("file "+(i+1)+":"+_fileRefer.fileList[i].name+"\n");
                 _fileRefer.fileList[i].addEventListener(Event.COMPLETE,onComplete);
                 _fileRefer.fileList[i].addEventListener(ProgressEvent.PROGRESS,onProgress);
                 (_fileRefer.fileList[i] as FileReference).load();
             }
         }
         private function onCancel(e:Event):void
         {
             trace("cancel to upload");
             _button.addEventListener(MouseEvent.CLICK,toSelect);
         }
         /**
          * 调用FileReference的实例方法upload()实现文件上传
          * @param    file
          */
         private function onUpLoad(file:FileReference):void
         {
             _label.text = "file "+(_count+1)+" size"+Number(file.size/1024/1024).toFixed(2)+"M";
             var variables:URLVariables = new URLVariables();
             variables.fileName = file.name;
             _request.data = variables;
             _request.method = URLRequestMethod.POST;
             file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
             file.addEventListener(Event.COMPLETE, completeHandler);
             file.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA,completeDataHandler);
             try
             {
                 file.upload(_request);
             }
             catch(error:Error)
             {
                 trace(error.message);
             }

             function progressHandler(e:ProgressEvent):void
             {
                 _label.text = "file "+(_count+1)+" uploading "+Math.round(100 * e.bytesLoaded / e.bytesTotal) + "%";
             }
             function completeHandler(e:Event):void
             {
                 var file:FileReference = FileReference(e.target);
                 file.removeEventListener(ProgressEvent.PROGRESS, progressHandler);
                 file.removeEventListener(Event.COMPLETE, completeHandler);
                 _button.removeEventListener(MouseEvent.CLICK,toUpload);
                 _button.addEventListener(MouseEvent.CLICK,toSelect);

                 if(_count<_fileRefer.fileList.length-1){
                     _label.text = "upload complete "+(_count+1)+" file";
                     _count++;
                     onUpLoad(_fileRefer.fileList[_count]);
                 }else{
                     _label.text = "all files upload complete";
                     _button.text = "click here to select file";
                 }
             }
             function completeDataHandler(e:DataEvent):void
             {
                 var file:FileReference = FileReference(e.target);
                 file.removeEventListener(DataEvent.UPLOAD_COMPLETE_DATA,completeHandler);
                 if(_count==_fileRefer.fileList.length-1){
                     trace("upload_complete_data",e.data);//上传成功后，从后台返回的数据
                 }
             }
         }
         /**
          * FileFilter 类用于表示在调用 FileReference.browse() 方法、FileReferenceList.browse() 方法或调用 File、FileReference 或 FileReferenceList 对象的 browse 方法时显示的文件浏览对话框中显示用户系统上的哪些文件。
          * @return
          */
         private function getImageTypeFilter():FileFilter {
             return new FileFilter("Images (*.jpg, *.jpeg, *.gif, *.png)", "*.jpg;*.jpeg;*.gif;*.png");
         }

         private function getTextTypeFilter():FileFilter {
             return new FileFilter("Text Files (*.txt, *.rtf)", "*.txt;*.rtf");
         }
     }
 }