CDS标准视图：维修工单工艺数据 I_MAINTORDEROPERATIONDATA

• 视图名称：维修工单工艺数据 I_MAINTORDEROPERATIONDATA
• 视图类型：基础
• 视图代码：

点击查看代码

@EndUserText.label: 'Maintenance Order Operation Data'
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'IPMORDOPERDATA'
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'I_MaintOrderOperation_DEX'

@Analytics: {
  dataCategory: #FACT,
  dataExtraction: {
    enabled: true,
        delta.changeDataCapture: {
            mapping:[
  {
                    table: 'afvc', role: #MAIN,
                    viewElement: [ 'MaintOrderRoutingNumber', 'MaintOrderOperationCounter'],
                    tableElement: ['aufpl', 'aplzl']
                }
                ,
                {
                    table: 'afko', role:  #LEFT_OUTER_TO_ONE_JOIN,
                    viewElement: ['MaintenanceOrder'],
                    tableElement: ['aufnr']}
                    ]

                 }
              }
          }

@ObjectModel: {
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #XL
  }
}

@ObjectModel.supportedCapabilities:     [ #EXTRACTION_DATA_SOURCE ]

@Metadata.ignorePropagatedAnnotations: true

// A more comprehensive view for order (sub)operation data, created as a replacement for BW extractor 2LIS_17_I3OPER

define view I_MaintOrderOperationData
  as select from I_MaintOrderOperAndSubOper
  association [0..1] to I_LogisticsOrder              as _Order                      on  _Order.OrderID = $projection.MaintenanceOrder // AUFK (Order master data) and AFKO (Order Header data )
  association [0..1] to I_LocationAccountAssignment   as _LocationAccountAssignment  on  $projection.maintobjectlocacctassgmtnmbr = _LocationAccountAssignment.MaintObjectLocAcctAssgmtNmbr
  association [0..1] to I_Equipment                   as _Equipment                  on  $projection.equipment = _Equipment.Equipment
{
  key MaintenanceOrder,
  key cast( MaintOrderOperationCounter as operationinternalid preserving type )                                                                          as MaintOrderOperationCounter,

      // Order Header:
       MaintOrderRoutingNumber,
      _MaintenanceOrder._LocationAccountAssignment.FunctionalLocation,
      _MaintenanceOrder.Equipment,
      _MaintenanceOrder.Assembly,
      _MaintenanceOrder.MaintenanceActivityType,
      _MaintenanceOrder.MaintenancePlannerGroup,
      _MaintenanceOrder.MaintenancePlanningPlant,

      _MaintenanceOrder.MaintenanceOrderType,
      _MaintenanceOrder.MaintenancePlant,
      _MaintenanceOrder.MaintObjectLocAcctAssgmtNmbr,

      // Order Operation (MCVGIH)
      MaintenanceOrderOperation,
      MaintenanceOrderSubOperation,
      OperationPersonResponsible,
      OperationControlKey,
      OperationDescription,
      _WorkCenter.WorkCenter,
// note 3197880: WorkCenterPlant get it from operation (in case work center initial)
//    _WorkCenter.Plant                                                                                                                                  as WorkCenterPlant,
      Plant                                                                                                                                              as WorkCenterPlant,
      @Semantics.quantity.unitOfMeasure: 'OperationPlannedWorkUnit'
      _OperationPlanningValues.OperationPlannedWork,
      @ObjectModel.foreignKey.association: '_PlannedWorkUnitOfMeasure'
      @Semantics.unitOfMeasure:true
      _OperationPlanningValues.OperationPlannedWorkUnit,
      @Semantics.quantity.unitOfMeasure: 'OperationPlannedWorkUnit'
      _OperationPlanningValues.ConfirmationTotalQuantity,
      @Semantics.quantity.unitOfMeasure: 'OperationQuantityUnit'
      _OperationPlanningValues.OperationQuantity,
      @ObjectModel.foreignKey.association: '_OperationQtyUnitOfMeasure'
      @Semantics.unitOfMeasure: true
      _OperationPlanningValues.OperationQuantityUnit,
      Assembly                                                                                                                                           as OperationAssembly,
      CostCtrActivityType,
      CostElement,
      MaterialGroup,
      OperationUnloadingPointName,
      PurchaseRequisition,

      cast( case when _StatusObjectActiveStatus[ StatusCode = 'I0013' ].StatusCode is not null then 'X' else ' ' end as eam_is_deleted preserving type ) as IsDeleted,

      @Semantics.systemDate.createdAt: true
      _MaintenanceOrder._Order.CreationDate,
      @Semantics.systemDateTime.lastChangedAt: true
      _MaintenanceOrder.LastChangeDateTime,

      MaintOrderConfirmation,
      MaintOrderOperationInternalID,
      SuperiorOperationInternalID,
      OperationWorkCenterInternalID,
      OperationWorkCenterTypeCode,

      /* Associations */
      //I_MaintOrderOperPlanningValues
      _OperationPlanningValues._PlannedWorkUnitOfMeasure,
      _OperationPlanningValues._OperationQtyUnitOfMeasure,

      // For DCL:
      _MaintenanceOrder,
      _PersonResponsible,
      _Order,
      _Equipment,
      _LocationAccountAssignment
}

• 事务代码：IW33/IW49
  
  短描述、创建日期、技术对象、删除标记、完成确认编码、计划数据、工作中心、采购和会计数据

• 视图结构：

字段名称	技术名称
订单	MAINTENANCEORDER
工序内部标识	MAINTORDEROPERATIONCOUNTER
计划工艺路线号	MAINTORDERROUTINGNUMBER
功能位置	FUNCTIONALLOCATION
设备	EQUIPMENT
装配	ASSEMBLY
活动类型	MAINTENANCEACTIVITYTYPE
计划人员组	MAINTENANCEPLANNERGROUP
计划工厂	MAINTENANCEPLANNINGPLANT
订单类型	MAINTENANCEORDERTYPE
工厂	MAINTENANCEPLANT
位置/科目分配	MAINTOBJECTLOCACCTASSGMTNMBR
	MAINTENANCEORDEROPERATION
子工序	MAINTENANCEORDERSUBOPERATION
人员编号	OPERATIONPERSONRESPONSIBLE
控制码	OPERATIONCONTROLKEY
工序短文本	OPERATIONDESCRIPTION
工作中心	WORKCENTER
工厂	WORKCENTERPLANT
工作	OPERATIONPLANNEDWORK
工作单位	OPERATIONPLANNEDWORKUNIT
实际的工作	CONFIRMATIONTOTALQUANTITY
工序数量	OPERATIONQUANTITY
基本单位	OPERATIONQUANTITYUNIT
装配	OPERATIONASSEMBLY
活动类型	COSTCTRACTIVITYTYPE
成本要素	COSTELEMENT
物料组	MATERIALGROUP
卸货点	OPERATIONUNLOADINGPOINTNAME
请购单	PURCHASEREQUISITION
已删除	ISDELETED
创建日期	CREATIONDATE
时戳	LASTCHANGEDATETIME
确认	MAINTORDERCONFIRMATION
对象编号	MAINTORDEROPERATIONINTERNALID
上级工序结点	SUPERIOROPERATIONINTERNALID
对象标识	OPERATIONWORKCENTERINTERNALID
	OPERATIONWORKCENTERTYPECODE