VB6查看桌面分辨率和工作区大小 2022.08.22 name.vt

VB6查看桌面分辨率和工作区大小 2022.08.22 name.vt

Form1 内代码如下：

' 2022年8月22日 15时15分
' 作者：name.vt

Private Sub cmdClearLeft_Click()
        txtWinL.Text = ""
        txtWinT.Text = ""
        txtWinR.Text = ""
        txtWinB.Text = ""
End Sub

Private Sub cmdClearRight_Click()
        txtWorkL.Text = ""
        txtWorkT.Text = ""
        txtWorkR.Text = ""
        txtWorkB.Text = ""
End Sub

'方法3、API函数 GetWindowRect()。'
'本质上这个函数是获取窗口的尺寸，
'所以实际上是获取“桌面”这个窗口的尺寸。
'注意：如果你的桌面有特殊情况，可能没法获得正确的尺寸，可以用其他方法。
'另外，这个方法还是无法获取工作区域的大小
Private Sub cmdGetWindowRect_Click()
    Dim i As Integer
    Dim uArea As Rect
    i = GetWindowRect(GetDesktopWindow, uArea)
    '如果函数成功，返回值为非零：如果函数失败，返回值为零。若想获得更多错误信息，请调用GetLastError函数。
    If i <> 0 Then
        txtWinL.Text = uArea.Left
        txtWinT.Text = uArea.Top
        txtWinR.Text = uArea.Right
        txtWinB.Text = uArea.Bottom
    Else
        txtWinL.Text = "函数读取失败"
        txtWinT.Text = "函数读取失败"
        txtWinR.Text = "函数读取失败"
        txtWinB.Text = "函数读取失败"
    End If
End Sub

' 方法4
Private Sub cmdSystemParametersInfo_Click()
    Dim i As Integer
    Dim uArea As Rect
    ' &H30 = 0x30 = 48
    i = SystemParametersInfo(&H30, 0, uArea, 0)
    '返回值：如果函数调用成功，返回值非零：如果函数调用失败，那么返回值为零。若想获取更多错误信息，请调用GetLastError函数。
    If i <> 0 Then
        txtWorkL.Text = uArea.Left
        txtWorkT.Text = uArea.Top
        txtWorkR.Text = uArea.Right
        txtWorkB.Text = uArea.Bottom
    Else
        txtWorkL.Text = "函数读取失败"
        txtWorkT.Text = "函数读取失败"
        txtWorkR.Text = "函数读取失败"
        txtWorkB.Text = "函数读取失败"
    End If
End Sub

Private Sub Form_Load()

    txtFangFa3.Text = "API函数 GetWindowRect()。本质上这个函数是获取窗口的尺寸，" & _
"所以实际上是获取“桌面”这个窗口的尺寸GetDesktopWindow。 " & _
"注意：如果你的桌面有特殊情况，可能没法获得正确的尺寸，" & _
"可以用其他方法。另外，这个方法还是无法获取工作区域的大小。"

    txtFangFa4.Text = "方法4、API函数 SystemParametersInfo()获取系统信息。" & _
"SystemParametersInfo(uAction , uParam , lpvParam , fuWinIni) " & _
"uiAction: 该参数指定要查询或设置的系统级参数. " & _
"其取值SPI_GETWORKAREA为检索主显示器的工作区大小. " & _
"工作区是指屏幕上不被系统任务条或应用程序桌面工具遮盖的部分." & _
"参数pvParam必须指向RECT结构以接收工作区的坐标信息，坐标是用虚拟屏幕坐标来表示的。" & _
"为了获取非主显示器的工作区信息，请调用GetMonitorlnfo函数。" & _
"参数ulParam指定宽度，单位是像素。" & _
"SPI_GETWORKAREA = 0x0030,  十进制为48 在vb6使用&H30"

End Sub

Module1中的代码：

' 2022年8月22日 15时15分
' 作者：name.vt
'方法4
Public Declare Function SystemParametersInfo Lib "user32.dll" Alias "SystemParametersInfoA" (ByVal uAction As Long, ByVal uParam As Long, ByRef lpvParam As Any, ByVal fuWinIni As Long) As Long

'方法3
Public Declare Function GetDesktopWindow Lib "user32.dll" () As Long
Public Declare Function GetWindowRect Lib "user32.dll" (ByVal hwnd As Long, ByRef lpRect As Rect) As Long

'方法4 和 3 都要用到这个结构
'记得在 SUB中 dim uArea as Rect
Public Type Rect
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type