linux中部署自己的系统内核

1、计算机是如何将系统起起来的？-- PC机的引导流程

PC机BIOS固件是固化在PC机主板上的ROM芯片中，断电也能保存，PC机上电后的第一条指令就是在BIOS固件中，它负责检测和初始化CPU、内存和主板平台，然后加载引导设备（大概率是硬盘）中的第一个扇区数据，到0x7c00地址开始的内存空间，再跳转到0x7c00处执行指令。这里是GRUB引导程序。

GRUB:GNU GRUB（GRand Unified Bootloader简称“GRUB”）是一个来自GNU项目的多操作系统启动程序。GRUB是多启动规范的实现，它允许用户可以在计算机内同时拥有多个操作系统，并在计算机启动时选择希望运行的操作系统。GRUB可用于选择操作系统分区上的不同内核，也可用于向这些内核传递启动参数。参考：百度百科

2、Hello OS引导汇编代码

为什么不能直接用C？

C 作为通用的高级语言，不能直接操作特定的硬件，而且 C 语言的函数调用、函数传参，都需要用栈。

栈，数据满足后进先出的特性，它由CPU特定的寄存器指向，所以需要先用汇编代码处理好C语言的工作环境

;彭东 @ 2021.01.09
MBT_HDR_FLAGS EQU 0x00010003
MBT_HDR_MAGIC EQU 0x1BADB002 ;多引导协议头魔数
MBT_HDR2_MAGIC EQU 0xe85250d6 ;第二版多引导协议头魔数
global _start ;导出_start符号
extern main ;导入外部的main函数符号
[section .start.text] ;定义.start.text代码节
[bits 32] ;汇编成32位代码
_start:
jmp _entry
ALIGN 8
mbt_hdr:
dd MBT_HDR_MAGIC
dd MBT_HDR_FLAGS
dd -(MBT_HDR_MAGIC+MBT_HDR_FLAGS)
dd mbt_hdr
dd _start
dd 0
dd 0
dd _entry
;以上是GRUB所需要的头
ALIGN 8
mbt2_hdr:
DD MBT_HDR2_MAGIC
DD 0
DD mbt2_hdr_end - mbt2_hdr
DD -(MBT_HDR2_MAGIC + 0 + (mbt2_hdr_end - mbt2_hdr))
DW 2, 0
DD 24
DD mbt2_hdr
DD _start
DD 0
DD 0
DW 3, 0
DD 12
DD _entry
DD 0
DW 0, 0
DD 8
mbt2_hdr_end:
;以上是GRUB2所需要的头
;包含两个头是为了同时兼容GRUB、GRUB2
ALIGN 8
_entry:
;关中断
cli
;关不可屏蔽中断
in al, 0x70
or al, 0x80
out 0x70,al
;重新加载GDT
lgdt [GDT_PTR]
jmp dword 0x8 :_32bits_mode
_32bits_mode:
;下面初始化C语言可能会用到的寄存器
mov ax, 0x10
mov ds, ax
mov ss, ax
mov es, ax
mov fs, ax
mov gs, ax
xor eax,eax
xor ebx,ebx
xor ecx,ecx
xor edx,edx
xor edi,edi
xor esi,esi
xor ebp,ebp
xor esp,esp
;初始化栈，C语言需要栈才能工作
mov esp,0x9000
;调用C语言函数main
call main
;让CPU停止执行指令
halt_step:
halt
jmp halt_step
GDT_START:
knull_dsc: dq 0
kcode_dsc: dq 0x00cf9e000000ffff
kdata_dsc: dq 0x00cf92000000ffff
k16cd_dsc: dq 0x00009e000000ffff
k16da_dsc: dq 0x000092000000ffff
GDT_END:
GDT_PTR:
GDTLEN dw GDT_END-GDT_START-1
GDTBASE dd GDT_START

1. 代码 1~40 行，用汇编定义的 GRUB 的多引导协议头，其实就是一定格式的数据，我们的 Hello OS 是用 GRUB 引导的，当然要遵循 GRUB 的多引导协议标准，让 GRUB 能识别我们的 Hello OS。之所以有两个引导头，是为了兼容 GRUB1 和 GRUB2。
2. 代码 44~52 行，关掉中断，设定 CPU 的工作模式
3. 代码 54~73 行，初始化 CPU 的寄存器和 C 语言的运行环境。
4. 代码 78~87 行，GDT_START 开始的，是 CPU 工作模式所需要的数据

Hello OS 的主函数

#include "vgastr.h"
void main()
{
    printf("Hello OS!");
    return;
}

注意：这里的printf不是应用程序库中的printf，是需要自己实现的

具体实现如下：

void _strwrite(char* string)
{
    char* p_strdst = (char*)(0xb8000);//指向显存的开始位置
    while (*string)
    {

        *p_strdst = *string++;
        p_strdst += 2;
    }
    return;
}

void printf(char* fmt, ...)
{
    _strwrite(fmt);
    return;
}

显卡的字符模式的工作细节：

它把屏幕分成 24 行，每行 80 个字符，把这（24*80）个位置映射到以 0xb8000 地址开始的内存中，每两个字节对应一个字符，其中一个字节是字符的 ASCII 码，另一个字节为字符的颜色值。如下图所示：



因此在上述显示printf的代码中要从0xb8000 开始写，p_strdst 每次+2跳过字符的颜色空间的原因

编译

• 链接器-map选项

LDFLAGS		= -s -static -T hello.lds -n **-Map** HelloOS.map
OJCYFLAGS	= -S -O binary

该选项将使得在链接过程中，生成链接布局文件，通过该文件可知HelloOS的内存映射布局

编译HelloOS时生成的map文件如下图所示：

安装HelloOS

将HelloOS作为一个操作系统启动项供grub启动，因此需要能够在PC启动时进入grub引导菜单，并选择启动HelloOS

为了能够每次启动时进入grub引导菜单，需要进行如下设置

• 修改/etc/default/grub
  
  

a. 注释掉HIDDEN所在的2行

b. 将GRUB_TIMEOUT设置为30（使用默认值10其实也可以）

c. 将GRUB_CMDLINE_LINUX_DEFAUL设置为text

参考

执行如下命令，更新grub配置

sudo update-grub

• 增加HelloOS启动选项
  
  修改/boot/grub/grub.cfg，增加HelloOS启动项

menuentry 'HelloOS' {
    insmod part_msdos
    insmod ext2
    set root='hd0,msdos5' #注意boot目录挂载的分区，这是我机器上的情况
    multiboot2 /boot/HelloOS.bin
    boot
}

PS:

使用df /boot 查看/boot分区情况

• 把HelloOS.bin文件复制到/boot/目录下

重启虚拟机，便可看到HelloOS启动项

选择该启动项，即可启动HelloOS