Windows10如何卸载OneDrive

Windows10如何卸载OneDrive

来源 https://zhuanlan.zhihu.com/p/23985905

1） 禁止onedrive自启动简单的就是在任务管理器的启动中禁用onedrive的启动项目就可以。

如果是准备彻底删除onedrive，组策略的这三项其实是不用理会的，因为onedrive都没有了，这个策略设置就毫无意义。这个策略可能适用于同步行为的设置。

2）组策略管理
运行gpedit.msc，进入【计算机配置】-【管理模板】-【windows组件】-【onedrive】，右侧的三个选项：

默认情况下，将文档保存到 OneDrive，选择禁用；
禁止使用 OneDrive 进行文件存储，选择启用
禁止OneDrive 文件通过按流量的连接同步，选择启用。

3）删除onedrive的程序文件
卸载方法一：
运行输入 %localappdata%\Microsoft\OneDrive\ ,查看版本号，一般是一串数值的形式。运行CMD命令，输入%localappdata%\Microsoft\OneDrive\XXXXXXXXXXXXXXX(刚才查看到的那个版本号)\OneDriveSetup /uninstall，这个命令可以卸载掉大多的onedrive程序，剩余的可以自行删除（可能须要权限设置或者以管理员模式运行cmd）

卸载方法二：
强制删除。直接通过取得权限的方式来删除%localappdata%\Microsoft \onedrive文件夹（取得权限以后，可能需要先在进程中关闭掉相应的onedrive进程，才能把文件夹删除干净）

4）删除导航栏中的onedrive
卸载onedrive是不能清除导航栏里面的onedrive，进入注册表：
HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder

把 Attributes属性的值 f080004d 改为 f090004d；

或是更直接的方法——

5） 直接删除以下注册表项

HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}

HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}

重启资源管理器。

 

编辑于 2016-11-27

-----------------------------------

RemoveOneDrive.bat

@echo off
title 一键删除OneDrive
::获取管理员权限
%Windir%\System32\FLTMC.exe >nul 2>&1 || (
    IF EXIST "%TEMP%\AdminRun.vbs" DEL /f /q "%TEMP%\AdminRun.vbs" 2>nul
    ECHO CreateObject^("Shell.Application"^).ShellExecute "%~f0", "%1", "", "runas", 1 >> "%TEMP%\AdminRun.vbs"
    ECHO CreateObject^("Scripting.filesystemobject"^).DeleteFile ^(WScript.ScriptFullName^) >> "%TEMP%\AdminRun.vbs"
    %Windir%\System32\CSCRIPT.exe //Nologo "%TEMP%\AdminRun.vbs"
    Exit /b
)
echo.
echo 即将删除OneDrive，是否继续？
echo.
echo 是：请按任意键继续。
echo 否：点击右上角，关闭本窗口。
echo.
echo 如有安全软件弹出拦截提示，放行即可。
pause
echo 正在调用OneDrive自带卸载功能，请稍后。
for /d %%f in (%localappdata%\Microsoft\OneDrive\*) do (if exist "%%f\OneDriveSetup.exe" %%f\OneDriveSetup.exe /uninstall)
echo OneDrive卸载完成！
del /f /s /q %localappdata%\Microsoft\OneDrive\*.*
rd /s /q %localappdata%\Microsoft\OneDrive\
echo OneDrive残留文件删除完成！
reg add "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /v Attributes /t REG_DWORD /d "0xf090004d" /f
reg add "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /v Attributes /t REG_DWORD /d "0xf090004d" /f
echo OneDrive导航栏选项删除完成！
echo 删除导航栏OneDrive图标将会在重启Windows资源管理器后生效。
echo.
echo.
echo 已将OneDrive彻底卸载。如有残留文件无法删除，重启后手工删除即可。
echo 请按任意键退出本程序。
pause

============== End