动态修改PE文件图标（使用UpdateResource API函数）

PE文件的图标存储在资源文件中，而操作资源要用到的API函数就是UpdateResource
首先我们需要先了解一下ICO格式，参考资料：http://www.moon-soft.com/program/FORMAT/windows/icons.htm
ICO格式不复杂，就是由数据头、数据目录、数据三个部分组成

一个.ico文件中可能含有若干个图标，我们需要将数据目录和数据解析出来。简单地写了个单元

1. unit Icons;
2. interface
3. uses
4. Winapi.Windows, System.SysUtils, System.Classes;
5. type
6. { 用于ICO图标文件 }
7. TIconDirEntry = packed record
8. bWidth: Byte;
9. bHeight: Byte;
10. bColorCount: Byte;
11. bReserved: Byte;
12. wPlanes: Word;
13. wBitCount: Word;
14. dwBytesInRes: DWORD;
15. dwImageOffset: DWORD;
16. end;
17. PIconDirEntry = ^TIconDirEntry;
18. TIconDir = packed record
19. idReserved: Word;
20. idType: Word;
21. idCount: Word;
22. idEntries: array [0..0] of TIconDirEntry;
23. end;
24. PIconDir = ^TIconDir;
25. { 用于PE文件中的图标 }
26. TGroupIconDirEntry = packed record
27. bWidth: Byte;
28. bHeight: Byte;
29. bColorCount: Byte;
30. bReserved: Byte;
31. wPlanes: Word;
32. wBitCount: Word;
33. dwBytesInRes: DWORD;
34. nID: Word;
35. end;
36. TGroupIconDir = packed record
37. idReserved: Word;
38. idType: Word;
39. idCount: Word;
40. idEntries: array [0 .. 0] of TGroupIconDirEntry;
41. end;
42. PGroupIconDir = ^TGroupIconDir;
43. { ICO图标文件 }
44. TIcoFile = class
45. public
46. IconStream: TMemoryStream;
47. IconDir: PIconDir;
48. IconDirSize: DWORD;
49. constructor Create; overload;
50. constructor Create(const FileName: string); overload;
51. destructor Destroy; override;
52. // 加载ICO数据
53. procedure LoadFromFile(const FileName: string);
54. procedure LoadFromStream(Stream: TStream);
55. end;
56. implementation
57. { TIcoFile }
58. constructor TIcoFile.Create;
59. begin
60. IconStream := TMemoryStream.Create;
61. IconDir := nil;
62. IconDirSize := 0;
63. end;
64. constructor TIcoFile.Create(const FileName: string);
65. begin
66. Create;
67. LoadFromFile(FileName);
68. end;
69. destructor TIcoFile.Destroy;
70. begin
71. FreeMem(IconDir);
72. FreeAndNil(IconStream);
73. inherited;
74. end;
75. procedure TIcoFile.LoadFromFile(const FileName: string);
76. var
77. MS: TMemoryStream;
78. begin
79. MS := TMemoryStream.Create;
80. try
81. MS.LoadFromFile(FileName);
82. LoadFromStream(MS);
83. finally
84. FreeAndNil(MS);
85. end;
86. end;
87. procedure TIcoFile.LoadFromStream(Stream: TStream);
88. var
89. Dir: TIconDir;
90. begin
91. Stream.Position := 0;
92. IconStream.Clear;
93. IconStream.CopyFrom(Stream, Stream.Size);
94. IconStream.Position := 0;
95. IconStream.ReadBuffer(Dir, SizeOf(Dir));
96. FreeMem(IconDir);
97. IconDirSize := SizeOf(TIconDirEntry) * (Dir.idCount - 1) + SizeOf(TIconDir);
98. IconDir := AllocMem(IconDirSize);
99. IconStream.Position := 0;
100. IconStream.ReadBuffer(IconDir^, IconDirSize);
101. end;
102. end.

这里要注意一个问题，ICO文件中的TIconDirEntry结构和PE文件中的TGroupIconDirEntry结构是不同的
不同处在最后一个参数，ICO文件中表示的是图像数据偏移地址，是DWORD类型。而PE文件中表示的是图像数据的索引，是WORD类型，少了2个字节
替换图标需要写入2个部分：RT_GROUP_ICON 和 RT_ICON
RT_GROUP_ICON也就是ICO的数据头部分，RT_ICON就是图像数据部分了
数据部分直接写入即可，不用转换什么的。但是数据头需要稍微处理一下，因为前面说了，这个替换过程是把ICO文件写到PE文件中
而他们数据头部分结构略有不同（PE文件中每个数据头比起ICO数据头要少2字节），只用把这里处理下就行了
最后写个函数就可以替换PE文件图标了

1. function TMainForm.UpdatePeIcon(IcoFile, PeFile: string): Boolean;
2. var
3. Ico: TIcoFile;
4. I: Integer;
5. hRes: THandle;
6. GroupIconDir: PGroupIconDir;
7. GroupIconDirSize: DWORD;
8. Data: TBytes;
9. begin
10. Result := False;
11. hRes := BeginUpdateResource(PChar(PeFile), False);
12. if hRes <> 0 then
13. begin
14. Ico := TIcoFile.Create(IcoFile);
15. // TGroupIconDirEntry结构要比TIconDirEntry结构少2字节
16. GroupIconDirSize := Ico.IconDirSize - Ico.IconDir^.idCount * 2;
17. GroupIconDir := AllocMem(GroupIconDirSize);
18. GroupIconDir^.idReserved := 0;
19. GroupIconDir^.idType := 1;
20. GroupIconDir^.idCount := Ico.IconDir.idCount;
21. for I := 0 to Ico.IconDir.idCount - 1 do
22. begin
23. CopyMemory(@GroupIconDir^.idEntries[I], @Ico.IconDir^.idEntries[I],
24. SizeOf(TGroupIconDirEntry));
25. // 索引从1开始
26. GroupIconDir^.idEntries[I].nID := I + 1;
27. // 写入图标数据
28. SetLength(Data, Ico.IconDir^.idEntries[I].dwBytesInRes);
29. Ico.IconStream.Position := Ico.IconDir^.idEntries[I].dwImageOffset;
30. Ico.IconStream.ReadBuffer(Data[0], Length(Data));
31. UpdateResource(hRes, RT_ICON, MakeIntResource(I + 1), 0, @Data[0], Length(Data));
32. end;
33. // 写入 RT_GROUP_ICON
34. UpdateResource(hRes, RT_GROUP_ICON, MakeIntResource('MAINICON'), 0, GroupIconDir, GroupIconDirSize);
35. FreeMem(GroupIconDir);
36. FreeAndNil(Ico);
37. EndUpdateResource(hRes, False);
38. Result := True;
39. end;
40. end;

http://blog.csdn.net/aqtata/article/details/7710720