uboot启动流程

uboot 的启动过程及工作原理
2.1 启动模式介绍
    大多数 Boot Loader 都包含两种不同的操作模式:"启动加载"模式和"下载"模式,这种区别仅对于开发人
员才有意义。但从最终用户的角度看,Boot Loader 的作用就是用来加载操作系统,而并不存在所谓的启动加
载模式与下载工作模式的区别。
    启动加载(Boot loading)模式:这种模式也称为"自主"(Autonomous)模式。也即 Boot Loader 从目标机
上的某个固态存储设备上将操作系统加载到 RAM 中运行,整个过程并没有用户的介入。这种模式是 Boot 
Loader 的正常工作模式,因此在嵌入式产品发布的时侯,Boot Loader 显然必须工作在这种模式下。
    下载(Downloading)模式:在这种模式下,目标机上的 Boot Loader 将通过串口连接或网络连接等通信手
段从主机(Host)下载文件,比如:下载内核映像和根文件系统映像等。从主机下载的文件通常首先被 Boot 
Loader 保存到目标机的 RAM 中,然后再被 BootLoader 写到目标机上的 FLASH 类固态存储设备中。Boot 
Loader 的这种模式通常在第一次安装内核与根文件系统时被使用;此外,以后的系统更新也会使用 Boot 
Loader 的这种工作模式。工作于这种模式下的 Boot Loader 通常都会向它的终端用户提供一个简单的命令
行接口。
   U­Boot 这样功能强大的 Boot Loader 同时支持这两种工作模式,而且允许用户在这两种工作模式之间进行
切换。
    大多数 bootloader 都分为阶段 1(stage1)和阶段 2(stage2)两大部分,u­boot 也不例外。依赖于 CPU 体系结构
的代码(如 CPU 初始化代码等)通常都放在阶段 1 中且通常用汇编语言实现,而阶段 2 则通常用 C 语言来实
现,这样可以实现复杂的功能,而且有更好的可读性和移植性。
2.2 阶段 1 介绍
u­boot 的 stage1 代码通常放在 start.s 文件中,它用汇编语言写成,其主要代码部分如下:
2.2.1 定义入口
由于一个可执行的 Image 必须有一个入口点,并且只能有一个全局入口,通常这个入口放在 ROM(Flash)的 0x0
地址,因此,必须通知编译器以使其知道这个入口,该工作可通过修改连接器脚本来完成。
     1. board/crane2410/u­boot.lds:  ENTRY(_start)   ==> cpu/arm920t/start.S: .globl _start
     2. uboot 代码区(TEXT_BASE = 0x33F80000)定义在 board/crane2410/config.mk

2.2.2 设置异常向量
_start: b   reset                      @ 0x00000000
        ldr pc, _undefined_instruction @ 0x00000004
        ldr pc, _software_interrupt    @ 0x00000008
        ldr pc, _prefetch_abort        @ 0x0000000c
        ldr pc, _data_abort            @ 0x00000010
        ldr pc, _not_used              @ 0x00000014
        ldr pc, _irq                    @ 0x 0000018
                                           0
        ldr pc, _fiq                    @ 0x 000001c
                                           0
      当发生异常时,执行 cpu/arm920t/interrupts.c 中定义的中断处理函数。
2.2.3 设置 CPU 的模式为 SVC 模式
        mrs     r0,cpsr
        bic     r0,r0,#0x1f
        orr     r0,r0,#0xd3
        msr     cpsr,r0
2.2.4 关闭看门狗
#if defined(CONFIG_S3C2400) || defined(CONFIG_S3C2410)
        ldr     r0, =pWTCON
        mov     r1, #0x0     @ 根据三星手册进行调置。
        str     r1, [r0]
2.2.5 禁掉所有中断
        mov     r1, #0xffffffff
        ldr     r0, =INTMSK
        str     r1, [r0]
# if defined(CONFIG_S3C2410)
        ldr     r1, =0x3ff
        ldr     r0, =INTSUBMSK
        str     r1, [r0]
2.2.6 设置以 CPU 的频率-系统时钟
    默认频率为      FCLK:HCLK:PCLK = 1:2:4,默认 FCLK 的值为 120 MHz,该值为 S3C2410 手册的推荐值。
        ldr     r0, =CLKDIVN
        mov     r1, #3
        str     r1, [r0]
2.2.7 设置 CP15
   设置 CP15, 失效指令(I)Cache 和数据(D)Cache 后, 禁止 MMU 与 Cache。
cpu_init_crit:
        mov     r0, #0
        mcr     p15, 0, r0, c7, c7, 0   /* 失效 I/D cache, 见 S3C2410 手册附录的 2-16 */
        mcr     p15, 0, r0, c8, c7, 0   /* 失效 TLB, 见 S3C2410 手册附录的 2-18 */
        /*
         * 禁止 MMU 和 caches, 详见 S3C2410 手册附录 2-11
         */
        mrc     p15, 0, r0, c1, c0, 0
        bic     r0, r0, #0x00002300     /* 清除 bits 13, 9:8 (--V- --RS)
                                 * Bit 8: Disable System Protection
                                 * Bit 7: Disable ROM Protection
                                 * Bit 13: 异常向量表基地址: 0x0000 0000
                                 */
        bic     r0, r0, #0x00000087     /* 清除 bits 7, 2:0 (B--- -CAM)
                                 * Bit 0: MMU disabled
                                 * Bit 1: Alignment Fault checking disabled
                                 * Bit 2: Data cache disabled
                                 * Bit 7: 0 = Little-endian operation
                                  */
         orr     r0, r0, #0x00000002      /* set bit 2 (A) Align, 1 = Fault checking enabled */
         orr     r0, r0, #0x00001000     /* set bit 12 (I) I-Cache, 1 = Instruction cache enabled
*/
         mcr     p15, 0, r0, c1, c0, 0
2.2.8 配置内存区控制寄存器
    配置内存区控制寄存器,寄存器的具体值通常由开发板厂商或硬件工程师提供. 如果您对总线周期及外围
芯片非常熟悉, 也可以自己确定, 在 U­BOOT 中的设置文件是 board/crane2410/lowlevel_init.S, 该文件包含
lowleve_init 程序段. 
         mov     ip, lr
         bl      lowlevel_init
         mov     lr, ip
2.2.9 安装 U-BOOT 使的栈空间
    下面这段代码只对不是从 Nand Flash 启动的代码段有意义,对从 Nand Flash 启动的代码,没有意义。因为
从 Nand Flash 中把 UBOOT 执行代码搬移到 RAM,
#ifndef CONFIG_SKIP_RELOCATE_UBOOT
...
#endif
stack_setup:
        ldr    r0, _TEXT_BASE               /* 代码段的起始地址            */
        sub    r0, r0, #CFG_MALLOC_LEN      /* 分配的动态内存区             */
        sub    r0, r0, #CFG_GBL_DATA_SIZE /* UBOOT开发板全局数据存放 */
#ifdef CONFIG_USE_IRQ
        /* 分配 IRQ 和 FIQ 栈空间 */
        sub    r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
#endif
        sub    sp, r0, #12                  /* 留下 3 个字为 Abort       */

　　***为C语言的运行设置堆栈

2.2.10 BSS 段清 0
clear_bss:
        ldr    r0, _bss_start        /* BSS 段的起始地址         */
        ldr    r1, _bss_end          /* BSS 段的结束地址         */
        mov    r2, #0x00000000              /* BSS 段置 0                     */
clbss_l:str    r2, [r0]              /* 循环清除 BSS 段 */
        add    r0, r0, #4
        cmp    r0, r1
        ble    clbss_l
2.2.11 搬移 Nand Flash 代码
从 Nand Flash 中, 把数据拷贝到 RAM, 是由 copy_myself 程序段完成, 
#ifdef CONFIG_S3C2410_NAND_BOOT
        bl    copy_myself
        @ jump to ram
        ldr   r1, =on_the_ram
        add pc, r1, #0
        nop
        nop
       1:    b     1b          @ infinite loop
       on_the_ram:
#endif
2.2.12 进入 C 代码部分
        ldr     pc, _start_armboot
        _start_armboot: .word start_armboot

2.3 阶段 2 的 C 语言代码部分 
lib_arm/board.c 中的 start armboot 是 C 语言开始的函数,也是整个启动代码中 C 语言的主函数,同时还是整个
u­boot(armboot)的主函数,该函数主要完成如下操作:
2.3.1 调用一系列的初始化函数
1. 指定初始函数表:
init_fnc_t *init_sequence[] = {
         cpu_init,              /* cpu 的基本设置             */
         board_init,            /* 开发板的基本初始化             */
         interrupt_init,        /* 初始化中断                 */
         env_init,              /* 初始化环境变量               */
         init_baudrate,         /* 初始化波特率                */
         serial_init,           /* 串口通讯初始化               */
         console_init_f,        /* 控制台初始化第一阶段 */
         display_banner,        /* 通知代码已经运行到该处 */
         dram_init,             /* 配制可用的内存区              */
         display_dram_config,
#if defined(CONFIG_VCMA9) || defined (CONFIG_CMC_PU2)
         checkboard,
#endif
         NULL,
};
执行初始化函数的代码如下:
         for (init_fnc_ptr = init_sequence; *init_fnc_ptr; ++init_fnc_ptr) {
                 if ((*init_fnc_ptr)() != 0) {
                        hang ();
                 }
         }
2.  配置可用的 Flash 区
    flash_init ()
3. 初始化内存分配函数
    mem_malloc_init()
4. nand flash 初始化
  #if (CONFIG_COMMANDS & CFG_CMD_NAND)
             puts ("NAND:");
             nand_init();              /* 初始化 NAND */
见第七部分 3.2.3 节中的第 3 点 nand_init()函数.
5. 初始化环境变量
   env_relocate (); 
6.  外围设备初始化
    devices_init()
7. I2C 总线初始化
   i2c_init();
8. LCD 初始化
   drv_lcd_init();
9. VIDEO 初始化
   drv_video_init();
10. 键盘初始化
   drv_keyboard_init();
11. 系统初始化
   drv_system_init();
2.3.2 初始化网络设备
初始化相关网络设备,填写 IP、MAC 地址等。
1. 设置 IP 地址
         /* IP Address */
         gd->bd->bi_ip_addr = getenv_IPaddr ("ipaddr");
           /* MAC Address */
           {
                     int i;
                     ulong reg;
                     char *s, *e;
                     uchar tmp[64];
                     i = getenv_r ("ethaddr", tmp, sizeof (tmp));
                     s = (i > 0) ? tmp : NULL;
                     for (reg = 0; reg < 6; ++reg) {
                             gd->bd->bi_enetaddr[reg] = s ? simple_strtoul (s, &e, 16) : 0;
                             if (s)
                                     s = (*e) ? e + 1 : e;
                     }
           }
2.3.3 进入主 UBOOT 命令行
进入命令循环(即整个 boot 的工作循环),接受用户从串口输入的命令,然后进行相应的工作。
           for (;;) {
                     main_loop (); /* 在 common/main.c */
           }
2.4 代码搬运
  为了支持 NAND flash 起动,S3C2410 内建了内部的 4k 的 SRAM 缓存“Steppingstone”。当起动时,NAND 
flash 最初的 4k 字节将被读入”Steppingstone”然后开始执行起动代码。通常起动代码会把 NAND flash 中的内容
拷到 SDRAM 中以便执行主代码。
  使用硬件的 ECC, NAND flash 中的数据的有效性将会得到检测。
功能
     1. NAND flash 模式:支持读/删除/编程 NAND Flash
     2. 自动起动模式:在复位时起动代码将被读入”Steppingstone”中,然后开始执行起动代码。
     3. 硬件 ECC 检测模块(硬件检测,软件纠正)
     4. “Steppingstone” 4­KB 内部 SRAM 在起动后可以另外使用。