研究windows下SVN备份及还原恢复方案

windows下SVN备份方案

备份策略

svn备份一般采用三种方式：

    1）svnadmin dump 
    2）svnadmin hotcopy 
    3）svnsync. 

注意，svn备份不宜采用普通的文件拷贝方式（除非你备份的时候将库暂停），如copy命令、rsync命令。

优缺点分析：

第一种svnadmin dump是官方推荐的备份方式，优点是比较灵活，可以全量备份也可以增量备份，并提供了版本恢复机制。

缺点是：如果版本比较大，如版本数增长到数万、数十万，那么dump的过程将非常慢；备份耗时，恢复更耗时；不利于快速进行灾难恢复。

个人建议在版本数比较小的情况下使用这种备份方式。

第二种svnadmin hotcopy原设计目的估计不是用来备份的，只能进行全量拷贝，不能进行增量备份；

优点是：备份过程较快，灾难恢复也很快；如果备份机上已经搭建了svn服务，甚至不需要恢复，只需要进行简单配置即可切换到备份库上工作。

缺点是：比较耗费硬盘，需要有较大的硬盘支持（俺的备份机有1TB空间，呵呵）。

第三种svnsync实际上是制作2个镜像库，当一个坏了的时候，可以迅速切换到另一个。不过，必须svn1.4版本以上才支持这个功能。

优点是：当制作成2个镜像库的时候起到双机实时备份的作用；

缺点是：当作为2个镜像库使用时，没办法做到“想完全抛弃今天的修改恢复到昨晚的样子”；而当作为普通备份机制每日备份时，操作又较前2种方法麻烦。

svnadmin dump全量备份实现

新建一个bat文件，内容如下：

echo on
rem Subversion的安装目录
 rem 所有版本库的父目录
set SVN_ROOT=F:/Repositories
rem 备份的目录
set BACKUP_SVN_ROOT=G:\SVN_BAK
set BACKUP_DIRECTORY=%BACKUP_SVN_ROOT%\%date:~0,4%%date:~5,2%%date:~8,2%
if exist %BACKUP_DIRECTORY% goto checkBack
echo 建立备份目录%BACKUP_DIRECTORY%>>%SVN_ROOT%/backup.log
mkdir %BACKUP_DIRECTORY%
rem 验证目录是否为版本库，如果是则取出名称备份
for /r %SVN_ROOT% %%I in (.) do @if exist "%%I/conf/svnserve.conf"   svnadmin dump %%~fI > %BACKUP_DIRECTORY%/%%~nI
goto end
:checkBack
echo 备份目录%BACKUP_DIRECTORY%已经存在，请清空。
goto end
:end

自动将svn资源目录下的所有版本库被分到“BACKUP_SVN_ROOT年月日”目录下。

结果发现：如果版本库文件较大，则备份时间太长。原本25G的资源目录，备份之后231G，且时间为1个多小时。

考虑svnadmin hotcopy方式

svnadmin hotcopy备份实现

svnadmin hotcopy /path/to/repository /path/to/backup

echo on
rem Subversion的安装目录
 rem 所有版本库的父目录
set SVN_ROOT=F:/Repositories
rem 备份的目录
set BACKUP_SVN_ROOT=G:\SVN_BAK
set BACKUP_DIRECTORY=%BACKUP_SVN_ROOT%\%date:~0,4%%date:~5,2%%date:~8,2%%time:~0,2%%time:~3,2%
if exist %BACKUP_DIRECTORY% goto checkBack
echo 建立备份目录%BACKUP_DIRECTORY%>>%SVN_ROOT%/backup.log
mkdir %BACKUP_DIRECTORY%
rem 验证目录是否为版本库，如果是则取出名称备份
rem for /r %SVN_ROOT% %%I in (.) do @if exist "%%I/conf/svnserve.conf"   svnadmin dump %%~fI > %BACKUP_DIRECTORY%/%%~nI
for /r %SVN_ROOT% %%I in (.) do @if exist "%%I/conf/svnserve.conf" svnadmin hotcopy %%~fI %BACKUP_DIRECTORY%/%%~nI

goto end
:checkBack
echo 备份目录%BACKUP_DIRECTORY%已经存在，请清空。
goto end
:end

备份之后的文件大小和资源库大小一样。

hotcopy备份恢复测试

换个测试机下载svn server，安装完成之后，拷贝某个项目版本库到测试机。【其实也可以进行本机恢复】

hotcopy恢复命令

svnadmin hotcopy /path/to/backup /path/to/repository

创建用户，授权，用小乌龟连接一下，正常能用

dump 备份恢复测试

恢复命令

svnadmin load 要恢复的版本库路径及名称 < 备份文件

•  mkdir newrepos
  

•  svnadmin create newrepos
  

•  svnadmin load newrepos < backfile
  

一定要先创建项目资源库，然后再恢复。

授权，测试，可用。

添加定时任务

修改脚本，备份文件自动循环覆盖

set BACKUP_DIRECTORY=%BACKUP_SVN_ROOT%\%date:~0,4%%date:~5,2%%date:~8,2%%time:~0,2%%time:~3,2%

修改为以下脚本【每十天会覆盖一次】

rem 设置为循环覆盖（每十天）
set BACKUP_DIRECTORY=%BACKUP_SVN_ROOT%\%date:~9,1%

最终脚本

echo off
rem Subversion的安装目录
 rem 所有版本库的父目录
set SVN_ROOT=F:/Repositories
rem 备份的目录
set BACKUP_SVN_ROOT=G:\SVN_BAK
rem set BACKUP_DIRECTORY=%BACKUP_SVN_ROOT%\%date:~0,4%%date:~5,2%%date:~8,2%%time:~0,2%%time:~3,2%
rem 设置为循环覆盖（每十天）
set BACKUP_DIRECTORY=%BACKUP_SVN_ROOT%\%date:~9,1%

if exist %BACKUP_DIRECTORY% rmdir /s/q %BACKUP_DIRECTORY%
echo 建立备份目录%BACKUP_DIRECTORY%>>%SVN_ROOT%/backup.log
mkdir %BACKUP_DIRECTORY%
rem 验证目录是否为版本库，如果是则取出名称备份
rem for /r %SVN_ROOT% %%I in (.) do @if exist "%%I/conf/svnserve.conf"   svnadmin dump %%~fI > %BACKUP_DIRECTORY%/%%~nI
for /r %SVN_ROOT% %%I in (.) do @if exist "%%I/conf/svnserve.conf" svnadmin hotcopy %%~fI %BACKUP_DIRECTORY%/%%~nI