【Oracle学习笔记】游标

1. 分类

常见的游标可分为显示游标、隐式游标、静态游标和动态游标四大类：

1.1 显示游标

显式是相对与隐式cursor而言的，就是有一个明确的声明的cursor。显式游标的声明类似如下：

delcare 游标关键字cursor 游标名 is 数据集;

游标从declare、open、fetch、close是一个完整的生命旅程。当然了一个这样的游标是可以被多次open进行使用的，显式cursor是静态cursor，她的作用域是全局的，但也必须明白，静态cursor也只有pl/sql代码才可以使用她。下面看一个简单的静态显式cursor的示例：

 declare
   cursor get_subid(pid a_test.parentid%type) is
     select subid from a_test where parentid = pid;
   v_subid a_test.subid%type;
 begin
   open get_subid(1);
   loop
     fetch get_subid
       into v_subid;
     exit when get_subid%notfound;
     dbms_output.put_line(v_subid);
   end loop;
   close get_subid;
   dbms_output.put_line('--------这是分割线----------');
   open get_subid(4);
   loop
     fetch get_subid
       into v_subid;
     exit when get_subid%notfound;
     dbms_output.put_line(v_subid);
   end loop;
   close get_subid;
 end;

1.2 隐式游标

隐式cursor当然是相对于显式而言的，就是没有明确的cursor的declare。在Oracle的PL/SQL中，所有的DML操作都被Oracle内部解析为一个cursor名为SQL的隐式游标，只是对我们透明罢了。

begin
  for rec in (select user, sysdate from dual) loop
    dbms_output.put_line(rec.user || '：' ||
                         to_char(rec.sysdate, 'yyyy-mm-dd hh24:mi:ss'));
  end loop;
end;

1.3 静态游标

静态游标是相对于动态游标而言的，普通显示定义的游标都是静态游标。

1.4 动态游标

动态游标是相对于静态游标而言的，要等到运行时才知道结果集查询语句是什么样的。

 declare
   type atest_rec is record(
     pid   a_test.parentid%type,
     subid a_test.subid%type);

   type app_ref_cur_type is ref cursor return atest_rec;
   my_cur app_ref_cur_type;
   my_rec atest_rec;
 begin

   if (to_char(sysdate, 'dd') = 30) then
     open my_cur for
       select parentid, subid from a_test where parentid = 1;
   else
     open my_cur for
       select parentid, subid from a_test where parentid = 2;
   end if;

   fetch my_cur
     into my_rec;
   while my_cur%found loop
     --当前不是30号 执行else 结果：
     --2#4
     --2#5
     dbms_output.put_line(my_rec.pid || '#' || my_rec.subid);
     fetch my_cur
       into my_rec;
   end loop;
   close my_cur;

 end;

　　【注】Record为记录数据类型。它类似于C语言中的结构数据类型(STRUCTURE)，PL/SQL提供了将几个相关的、分离的、基本数据类型的变量组成一个整体的方法，即RECORD复合数据类型。在使用记录数据类型变量时，需要在声明部分先定义记录的组成、记录的变量，然后在执行部分引用该记录变量本身或其中的成员。

　　定义记录数据类型的语法如下：

 TYPE RECORD_NAME IS RECORD(
 V1  DATA_TYPE1 [NOT NULL][:=DEFAULT_VALUE],
 V2  DATA_TYPE2 [NOT NULL][:=DEFAULT_VALUE],
 VN  DATA_TYPEN [NOT NULL][:=DEFAULT_VALUE]);

由上面的例子，可知cursor与REF cursor大致有以下几点区别：

1）PL/SQL静态游标不能返回到客户端，只有PL/SQL才能利用它。动态游标能够被返回到客户端，这就是从Oracle的存储过程返回结果集的方式。

2）PL/SQL静态游标可以是全局的，而动态游标则不是，不能在包说明或包体中的过程或函数之外定义动态游标。

3）动态游标可以从子例程传递到子例程，而普通游标则不能。如果要共享静态光标，必须在包说明或包体中把它定义为全局光标。 因为使用全局变量通常不是一种很好的编码习惯，因此可以用动态游标来共享PL/SQL中的游标，无需混合使用全局变量。

4）静态光标比动态游标标效率要高，所以在使用游标时首先考虑使用静态游标，也有人建议尽量使用隐式游标，避免编写附加的游标控制代码（声明，打开，获取，关闭），也不需要声明变量来保存从游标中获取的数据。这个就因人因事而定吧。

另外，在oracle9i以后系统定义的一个refcursor， 这是一个弱类型的游标，相当于.Net中用户var声明的变量，主要用在过程中返回结果集。

 --创建存储过程
 create or replace procedure sp_get_subid(pid       ina_test.parentid%type,
  out_subid out SYS_REFCURSOR) as
 begin
   open out_subid for
     SELECT * FROM a_test WHERE parentid = pid;
 EXCEPTION
   WHEN OTHERS THEN
     RAISE_APPLICATION_ERROR(-20101, 'Error in sp_get_subid' || SQLCODE);
 end sp_get_subid;

 --调用存储过程
 declare
   v_rent_rows SYS_REFCURSOR;
   v_rent_row  a_test%rowType;
 begin
   sp_get_subid(1, v_rent_rows);
   Dbms_output.put_line('parentid subid');
   loop
     fetch v _rows
       into v _row;
     exit when v _rows%NOTFOUND;
     Dbms_output.put_line(v _row.parentid || ' ' || v _row.subid);
   end loop;
   close v_rows;
 end;

2. 属性

2.1 说明

 %FOUND： bool - TRUE if >1 row returned
 %NOTFOUND：bool - TRUE if 0 rows returned
 %ISOPEN： bool - TRUE if cursor still open
 %ROWCOUNT：int - number of rows affected by last SQL statement

【注】NO_DATA_FOUND和%NOTFOUND的用法是有区别的，小结如下：

1）SELECT . . . INTO 语句触发 NO_DATA_FOUND；

2）当一个显式游标的 where 子句未找到时触发 %NOTFOUND；

3）当UPDATE或DELETE 语句的where 子句未找到时触发 SQL%NOTFOUND；

4）在游标的提取(Fetch)循环中要用 %NOTFOUND 或%FOUND 来确定循环的退出条件，不要用NO_DATA_FOUND

2.2 示例

2.2.1 示例一：

 begin

   update A_TEST set SUBID = '' WHERE PARENTID = 4;

   --SQL%ISOPEN是一个布尔值，如果游标打开，则为TRUE，如果游标关闭，则为FALSE.

   if sql%isopen then

     dbms_output.put_line('Openging');

   else

     dbms_output.put_line('closing'); --对于隐式游标而言SQL%ISOPEN总是FALSE，这是因为隐式游标在DML语句执行时打开，结束时就立即关闭。

   end if;

   if sql%found then

     dbms_output.put_line('游标指向了有效行'); --判断游标是否指向有效行

   else

     dbms_output.put_line('Sorry');

   end if;

   if sql%notfound then

     dbms_output.put_line('Also Sorry');

   else

     dbms_output.put_line('Haha');

   end if;

   dbms_output.put_line(sql%rowcount);

 exception

   when no_data_found then

     dbms_output.put_line('Sorry No data');

   when too_many_rows then

     dbms_output.put_line('Too Many rows');

 end;

【注】SQL语言分为DDL（Data Definition Language，数据定义语言，用来维护数据对象）和DML（Data Manipulation Language，数据操作语言，用于增删改表中数据，DML是伴随TCL事务控制的）。

2.2.2 示例二：

 declare

   empNumber a_test.parentid%TYPE;

   empName   a_test.subid%TYPE;

 begin

   if sql%isopen then

     dbms_output.put_line('Cursor is opinging');

   else

     dbms_output.put_line('Cursor is Close');

   end if;

   if sql%notfound then

     dbms_output.put_line('No Value');

   else

     dbms_output.put_line(empNumber); --没有赋值，输出为空白

   end if;

   dbms_output.put_line(sql%rowcount); --没有记录，输出为空白

   dbms_output.put_line('-------------');

   select parentid, subid into empNumber, empName from a_test where parentid = 4;

   dbms_output.put_line(sql%rowcount);

   if sql%isopen then

     dbms_output.put_line('Cursor is opinging');

   else

     dbms_output.put_line('Cursor is Closing');

   end if;

   if sql%notfound then

     dbms_output.put_line('No Value');

   else

     dbms_output.put_line(empNumber);

   end if;

 exception

   when no_data_found then

     dbms_output.put_line('No Value');

   when too_many_rows then

     dbms_output.put_line('too many rows');

 end;

【注】%Type是Oracle提供的一种数据定义方法，为的是使一个新定义的变量与另一个已经定义了的变量(通常是表的某一列)的数据类型保持一致，当被参照的那个变量的数据类型发生改变时,那么这个新定义的变量的数据类型也会随之发生改变。当不能确切的知道那个变量的类型是,就采用这种方法来定义变量的数据类型。

3. 操作

3.1 For循环游标

  --声明游标：delcare 游标关键字cursor 游标名 is 数据集;

 declare

 cursorc_list is

 selectp.fid, max(t.exp) exp

 from view_pilot p

 left join IO_FMS_BILLOFHEALTH t

 ont.phr = p.fjobnumber

 group by p.fid;

 --For循环，类似.Net中的foreach方法：

 --begin

 --for 元素名 in 游标名 循环关键字loop

 --执行语句;

 --endloop;

 begin

   for c_row in c_list loop

     update alarm_pilotintelligence

        set C = GetAlarmStateByExp(c_row.exp)

      where isprimary = 0

        and pid = c_row.fid;

 end loop;

3.2 Fetch游标

 --定义游标

 declare

   cursor c_job is

     select * from a_test order by parentid;

   --定义一个游标变量

   c_row c_job%rowtype;

 begin

   --使用的时候必须要明确的打开游标

   Open c_job;

   --开始循环标记

   loop

     --提取一行数据到c_row，相当ADO.Net中的SqlDataReader.Read()方法

     fetch c_job into c_row;

     --判读是否提取到值，没取到值就退出

     --取到值c_job%notfound 是false

     --取不到值c_job%notfound 是true

     exit when c_job%notfound;

     dbms_output.put_line(c_row.parentid || '-' || c_row.subid); --用于输出，这是oracle中最基础的方法之一

     --结束循环，并关闭游标

   end loop;

   close c_job;

 end;

【注】如果一个表有较多的列，使用%ROWTYPE来定义一个表示表中一行记录的变量，比分别使用%TYPE来定义表示表中各个列的变量要简洁得多，并且不容易遗漏、出错。这样会增加程序的可维护性。当不能确切地知道被参照的那个表的结构及其数据类型时，可以采用这种方法定义变量的数据类型。

3.3 While循环游标

　　上面【示例二】中的结果还可以通过While循环与Fetch相结合来实现：

 --定义游标

 declare

   cursor c_job is

     select * from a_test order by parentid;

   --定义一个游标变量

   c_row c_job%rowtype;

 begin

   --使用的时候必须要明确的打开游标

   Open c_job;

   --开始循环标记

   --提取一行数据到c_row，相当ADO.Net中的SqlDataReader.Read()方法

   fetch c_job

     into c_row;

   --while循环

   while c_job%found loop

     dbms_output.put_line(c_row.parentid || '-' || c_row.subid);

     fetch c_job

       into c_row;

     --结束循环，并关闭游标

   end loop;

   close c_job;

 end;

参考资料：

1．Oracle 游标使用全解

2．游标属性SQL%FOUND, SQL%NOTFOUND, SQL%ROWCOUNT, SQL%ISOPEN

3．ORACLE中%TYPE和%ROWTYPE的使用

4. cursor 与refcursor及sys_refcursor的区别 (转载)