bat脚本-set(setlocal enabledelayedexpansion) 学习

设置本地为延迟扩展。其实也就是：延迟变量，全称延迟环境变量扩展。

事件一：

@echo off
set a=4
set a=5&echo %a%
pause

解说：为什么是4而不是5呢？在echo之前明明已经把变量a的值改成5了。

批处理运行命令的机制：批处理读取命令时是按行读取的（另外例如for命令等，其后用一对圆括号闭合的所有语句也当作一行），在处理之前要完成必要的预处理工作，这其中就包括对该行命令中的变量赋值。我们现在分析一下例1，批处理在运行到这句“set a=5&echo %a%”之前，先把这一句整句读取并做了预处理——对变量a赋了值，那么%a%当然就是4了！（没有为什么，批处理就是这样做的。）而为了能够感知环境变量的动态变化，批处理设计了变量延迟。简单来说，在读取了一条完整的语句之后，不立即对该行的变量赋值，而会在某个单条语句执行之前再进行赋值，也就是说“延迟”了对变量的赋值。如何开启变量延迟呢？变量延迟又需要注意什么呢？

事件二：开启 变量延迟机制！

@echo off
setlocal enabledelayedexpansion
set a=4
set a=5&echo !a!
pause

结果：5
解说：由于启动了变量延迟，得到了正确答案。变量延迟的启动语句是“setlocal enabledelayedexpansion”，并且变量要用一对叹号“!!”括起来（注意要用英文的叹号），否则就没有变量延迟的效果。分析一下例2，首先“setlocal
enabledelayedexpansion”开启变量延迟，然后“set a=4”先给变量a赋值为4，“set a=5&echo
!a!”这句是给变量a赋值为5并输出（由于启动了变量延迟，所以批处理能够感知到动态变化，即不是先给该行变量赋值，而是在运行过程中给变量赋值，因此此时a的值就是5了）。

事件三： (一般通过全局变量保存返回值的比较常见),当前这个示例通过变量传递来保存函数的返回值：

 @echo off
 ::通过给调用者传递一个变量（var），来保存函数的返回值
 call :myFunc var
 echo.var:%var%
 goto :eof

 :myFunc
     set "%1=haha"
 goto :eof

结果：var:haha
解说：通过给 myFunc 函数传递 var 一个变量，然后 函数中 通过 set "%1=haha" 给第一个参数设置值，也就是给变量设置;

事件四： 通过 设置局部的可延迟的扩展变量 来实现循环，如下循环5次；

 @echo off
 ::设置局部的可延迟的扩展变量a
 setlocal enabledelayedexpansion
 for /l %%i in ( 1,1,5 ) do (
     set a=%%i  echo !a!
 )
 pause

解释： for /l %%i in(start,step,end) do  ;这个循环的语法；每次将循环变量赋值给a，并打印出来；必须要加 setlocal enabledelayedexpansion 这一句，否则 a变量 预处理时没有这个东西，会不打印或者打印 echo是关闭状态；

事件五：处理局部变量和全局变量不冲突；SETLOCAL命令能让处理器当做是局部变量，用ENDLOCAL解除局部变量。

 @echo off
 :: 怎么保证局部变量和全局变量不冲突，SETLOCAL命令能让处理器当做是局部变量，
 :: 用ENDLOCAL解除局部变量。
 :: ENDLOCAL 会被自动调用，当批处理执行到文件末尾的时候，即GOTO:EOF。
 :: SETLOCAL可以很好的保护函数内与外面的变量不会冲突。

 set "var1=i'm goloable var1!"
 set "var2=i'm goloable var2!"

 echo.var1 before:"%var1%"
 echo.var2 before:"%var2%"
 call :myFunc var2
 echo.var1 after:"%var1%"
 echo.var2 after:"%var2%"
 pause && goto :eof
 ::传一个参数应用进去
 :myFunc
 SETLOCAL
     set "var1=呵呵呵！"
     set "%1=%var1%"
     echo.var1 :"local Val1 %var1%"
 ENDLOCAL
 goto :eof

执行结果：

解释： 可以看到 ，代码中 将 var2 引用通过参数传进去，同时在函数中将var1的变量设置为呵呵呵！,但是函数执行完后， var1,和var2都没有变动(尽管var2是以变量的形式传进去的)，他们只有在属于的局部区域，赋值才有效，endlocal 执行后，他们又恢复 全局变量的值了；

事件六：怎么跳过ENDLOCAL的屏障，返回局部变量值？采用”变量扩充“，在SETLOCAL与ENDLOCAL之间的全局变量的值会备份，当退出ENDLOCAL，该值将恢复。让命令处理器来执行ENDLOCAL 和SET命令。

 @echo off
 :: 返回局部变量
 :: 怎么跳过ENDLOCAL的屏障，返回局部变量值？
 :: 采用”变量扩充“，在SETLOCAL与ENDLOCAL之间的全局变量的值会备份，当退出ENDLOCAL，该值将恢复。
 :: 让命令处理器来执行ENDLOCAL 和SET命令。

 set "aStr=Expect no changed,Even if used in function~"
 set "var1=Expect changed"
 echo.aStr before:%aStr%
 echo.var1 before:"%var1%"
 call :myFunc var1
 echo.aStr after:%aStr%
 echo.var1 after:"%var1%"
 pause && goto :eof

 :myFunc
 setLocal
 set "aStr=Try To Change!"
 (ENDLOCAL
     set "%1=%aStr%"
 )
 goto :eof

执行结果：

解释：aStr 变量通过全局变量的形式，在 setlocal 和 endlocal 之间赋值，这个赋值肯定是不会影响外部的aStr的值的，怎样将 这个局部设置的值保存下来？如上代码： 在 setlocal 和 endlocal 之外 ，通过 将这个值设置给 传进来的参数变量、或者另一个全局变量，即可将 该局部变量的赋值保存下来并返回；如上图，var1的值变为了 局部赋值：Try To Change!;

事件七：编写递归函数，Fibonacci函数；让函数局部变量的变换对调用者是可见的，循环调用函数，让变量可重用：

　　

 @echo off
 :: 编写斐波拉里 函数，用来计算多少以内的斐波拉里数！ 递归！
 set "fst=0"
 set "fib=1"
 set "limit=10000"

 :: fib 传的是引用， 另两个传的是值； fib最后用来返回值
 call :feberlalie fib,%fst%,%limit%
 echo. The next Fibonacci number greater or equal %limit% is %fib%.
 pause && goto :eof

 :feberlalie
 SETLOCAL

 ::可以利用set /a 进行连续赋值,只要用逗号分开每个变量名就可以了。是下面三行代码的缩写
 set /a "Num1=%1,Num2=%2,limit=%3"
 :: set /a "Num1=%1"
 :: set /a "Num2=%2"
 :: set /a "limit=%3"

 :: 在set /a 计算时，可以省略变量的%号或!号，极为方便。 是带百分号的 加法的缩写
 :: set /a "Sum=Num1 + Num2"
 set /a "Sum=%Num1% + %Num2%"

 echo.Num1 :%Num1%
 if /i %Sum% LSS %limit% call:feberlalie Sum,%Num1%,%limit%
 (ENDLOCAL
     IF "%1" NEQ "" SET "%1=%Sum%"
 )
 goto :eof

执行结果：

总结：定义一个标准的dos batch script function（ps:人家总结的不错，直接拿来用了）：

      :myFunctionName    -- function description here  函数名
     ::           参数描述      -- %~1: argument description here  下面都是函数体
     SETLOCAL
     REM.--function body here
     set LocalVar1=...
     set LocalVar2=...
     (ENDLOCAL & REM -- RETURN VALUES  待返回的值
         IF "%~1" NEQ "" SET %~1=%LocalVar1%
         IF "%~2" NEQ "" SET %~2=%LocalVar2%
     )
     GOTO:EOF  

学习参考链接：

http://blog.csdn.net/xiaoding133/article/details/39252357

http://www.jb51.net/article/29323.htm