Processing 字体变形

在Processing中做字体变形通常需要有以下基础知识：

1、PGraphics对象

2、图片像素化

制作过程也不复杂，代码如下：

 color ELLIPSE_COLOR = color(0);
 color LINE_COLOR = color(0, 125);
 color PGRAPHICS_COLOR = color(0);
 int LINE_LENGTH = 25;
 boolean reverseDrawing = false;
 PGraphics pg;
 PFont f = createFont("宋体", 42);
 void setup() {
   size(1280, 720,P2D);
   pg = createGraphics(width, height, JAVA2D);
   pg.beginDraw();
   pg.textFont(f);
   pg.textSize(300);
   pg.textAlign(CENTER, CENTER);
   pg.fill(PGRAPHICS_COLOR);
   pg.text("麥塔威", pg.width/2, pg.height/2);
   pg.endDraw();
 }
 void draw() {
   int gridH = (int) map(mouseX, 0, width, 30, 100);
   int gridV = (int) map(mouseY, 0, height, 15, 100);
   float w = width/gridH;
   float h = height/gridV;
   float r = min(w, h);

   background(255);
   strokeWeight(1);
   for (int y=0; y<gridV; y++) {
     for (int x=0; x<gridH; x++) {
       float _x = x*w;
       float _y = y*h;
       color c = pg.get(int(_x), int(_y));
       boolean textDraw = (c == PGRAPHICS_COLOR);
       if (textDraw) {
         noStroke();
         fill(ELLIPSE_COLOR);
         ellipse(_x, _y, r, r);
       } else {
         stroke(LINE_COLOR);
         line(_x, _y, _x+LINE_LENGTH, _y+LINE_LENGTH);
       }
     }
   }
 }

其中，setup部分的pg操作都是在PGraphics对象上的操作，这个对象就类似于画布上的画布，而draw里面两个for循环则是实现字体变形的关键，将图片像素化以后比对字体颜色和背景颜色就可以将字体从背景中“抠”出来，然后想捏扁还是捏圆就看各人的喜好了~