windows_Bat_Scripts查看系统IP-更改regedit-更新系统补丁

1.1    脚本名称

Update_patch.bat

1.2    脚本代码

@echo off

:menu

cls

mode con cols=48 lines=27 & color 02

echo.

echo================================================

echo         请选择要进行的操作，然后按回车

echo================================================

echo.

echo         1.查看主机IP配置信息

echo.

echo         2.添加注册表UNC路径检查

echo.

echo         3.更新防病毒补丁

echo.

echo         4.重启系统

echo.

echo         Q.退出

echo.

:cho

set choice=

set /p choice="Please enter your choice:"

echo.

IF NOT "%choice%"=="" SET choice=%choice:~0,1%

if /i "%choice%"=="1" goto ip

if /i "%choice%"=="2" goto reg

if /i "%choice%"=="3" goto patch

if /i "%choice%"=="4" goto reboot

if /i "%choice%"=="Q" goto exit

echo 选择无效，请重新输入

echo.

goto cho

:ip

ver|findstr "5.1" >nul && (set "IP=ipconfig^|findstr /i "ip address"")|| (set "IP=ipconfig^|findstr /i "ipv4"")

for /f "tokens=14* delims=: " %%1 in ('%IP%')do echo          %%2

echo.

echo==================================

echo     按任意键返回主菜单继续

echo==================================

echo.

pause > nul

goto menu

:reg

reg add "HKEY_CURRENT_USER\Software\Microsoft\Command Processor" /v "DisableUNCCheck" /t "REG_DWORD" /d "1" /f  > nul 2>&1

echo       更新注册表操作成功

echo.

echo==================================

echo     按任意键返回主菜单继续

echo==================================

echo.

pause > nul

goto menu

:patch

if "%PROCESSOR_ARCHITECTURE%"=="x86" goto x86

if "%PROCESSOR_ARCHITECTURE%"=="AMD64" goto x64

:x86

echo Start installing 32_system patches.

wusa %cd%\windows6.1-kb4012212-x86.msu /quiet /norestart

pause > nul

echo.

echo Patch update successful, please restart the system.

echo.

echo==================================

echo     按任意键返回主菜单继续

echo==================================

echo.

goto menu

:x64

echo Start installing 64_system patches.

wusa %cd%\windows6.1-kb4012212-x64.msu /quiet /norestart

echo.

echo Patch update successful, please restart the system.

echo.

echo==================================

echo     按任意键返回主菜单继续

echo==================================

echo.

pause > nul

goto menu

:reboot

shutdown /r /t 0 /f

exit

:exit

exit

1.3    脚本运行方法

复制上面脚本代码到记事本中，将记事本文件重命名为Update_patch.bat，找到保存好的Update_patch.bat脚本文件双击直接运行，输入你的选择即可运行相应的功能，运行效果如下：