[ActionScript 3.0] 通过BitmapData将对象保存成jpg图片

此方法需要用到JPGEncoder.as和BitString.as这两个类，是将BitmapData对象转换成ByteArray，然后通过FileStream把此ByteArray写入到文件保存成jpg图片,因为用到File相关类，故需要用air播放器发布flash，在此提供两个下载JPGEncoder.as和BitString.as类的地址，

CSDN：http://download.csdn.net/source/3205224

Adobe官方的CoreLib下载: http://code.google.com/p/as3corelib/ 使用其中的:com.adobe.images.JPEGEncoder

以下是一个简单例子，SaveToJPEG .as 类 可直接作为文档类

 package
 {
     import JPEGEncoder.JPGEncoder;
     import flash.display.Bitmap;
     import flash.display.BitmapData;
     import flash.display.Loader;
     import flash.display.MovieClip;
     import flash.display.Sprite;
     import flash.events.Event;
     import flash.events.MouseEvent;
     import flash.filesystem.File;
     import flash.filesystem.FileMode;
     import flash.filesystem.FileStream;
     import flash.geom.Rectangle;
     import flash.net.URLRequest;
     import flash.text.TextField;
     import flash.text.TextFieldAutoSize;
     import flash.utils.ByteArray;

     /**
       * ...
       * @author Frost.Yen
       */
     public class SaveToJPEG extends Sprite
     {
         var ldr:Loader = new Loader();
         var rect:Rectangle;
         var bytearr:ByteArray;
         public function SaveToJPEG():void
         {
             init();
         }

         private function init():void
         {
             var btnMC:MovieClip = new MovieClip();
             btnMC.graphics.beginFill(0xcccccc);
             btnMC.graphics.drawRoundRect(0, 0, 100, 40, 10, 10);
             btnMC.graphics.endFill();
             btnMC.x = 630;
             btnMC.y = 50;
             btnMC.buttonMode = true;
             btnMC.addEventListener(MouseEvent.CLICK, onClick);
             this.addChild(btnMC);

             var txt:TextField = new TextField();
             txt.autoSize = TextFieldAutoSize.LEFT;
             txt.selectable = false;
             txt.mouseEnabled = false;
             txt.text = "点击保存此图片";
             txt.x = (btnMC.width - txt.width) / 2;
             txt.y = (btnMC.height - txt.height) / 2;
             btnMC.addChild(txt);

             ldr.load(new URLRequest("http://hiphotos.baidu.com/frostyen/pic/item/7e49d8b53f6b48ffd9335aa2.jpg"));
             ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);
         }

         private function onClick(e:MouseEvent):void
         {
             if (bytearr != null)
             {
                 var file:File = new File();
                 file.browseForDirectory("保存");
                 file.addEventListener(Event.SELECT, onSelectPath);
             }
         }

         private function onSelectPath(e:Event):void
         {
             var file:File = (e.target as File).resolvePath("松竹梅副本.jpg");
             var filestream:FileStream = new FileStream();
             filestream.open(file, FileMode.WRITE);
             filestream.writeBytes(bytearr);
         }

         private function onComplete(e:Event):void
         {
             this.addChild(ldr);
             rect = ldr.getRect(ldr);

             var bmpd:BitmapData = new BitmapData(rect.width,rect.height);
             bmpd.draw(ldr);
             var jpg:JPGEncoder = new JPGEncoder();
             bytearr = jpg.encode(bmpd) as ByteArray;
         }
     }
 }