• 8.1 触发器类型
  • 8.1.1 DML触发器
  • 8.1.2 替代触发器
  • 8.1.3 系统触发器
  • 8.2 创建触发器
  • 8.2.1 触发器触发次序
  • 8.2.2 创建DML触发器
  • 8.2.3 创建替代(INSTEAD OF)触发器
  • 8.2.3 创建系统事件触发器
  • 8.2.4 系统触发器事件属性
  • 8.2.5 使用触发器谓词
  • 8.2.6 又一次编译触发器
  • 8.3 删除和使能触发器
  • 8.4 触发器和数据字典
  • 8.5 数据库触发器的应用举例

触发器是很多关系数据库系统都提供的一项技术。在ORACLE系统里,触发器类似过程和函数,都有声明,运行和异常处理过程的PL/SQL块。



8.1 触发器类型



    触发器在数据库里以独立的对象存储,它与存储过程和函数不同的是,存储过程与函数须要用户显示调用才执行,而触发器是由一个事件来启动执行。即触发器是当某个事件发生时自己主动地隐式执行。而且,触发器不能接收參数。所以执行触发器就叫触发或点火(firing)。ORACLE事件指的是对数据库的表进行的INSERT、UPDATE及DELETE操作或对视图进行类似的操作。ORACLE将触发器的功能扩展到了触发ORACLE,如数据库的启动与关闭等。所以触发器经常使用来完毕由数据库的完整性约束难以完毕的复杂业务规则的约束,或用来监视对数据库的各种操作,实现审计的功能。




8.1.1 DML触发器



    ORACLE能够在DML语句进行触发,能够在DML操作前或操作后进行触发,而且能够对每一个行或语句操作上进行触发。



8.1.2 替代触发器



    因为在ORACLE里,不能直接对由两个以上的表建立的视图进行操作。所以给出了替代触发器。它就是ORACLE 8专门为进行视图操作的一种处理方法。



8.1.3 系统触发器



ORACLE 8i 提供了第三种类型的触发器叫系统触发器。它能够在ORACLE数据库系统的事件中进行触发,如ORACLE系统的启动与关闭等。



触发器组成:



触发事件:引起触发器被触发的事件。 比如:DML语句(INSERT, UPDATE, DELETE语句对表或视图运行数据处理操作)、DDL语句(如CREATE、ALTER、DROP语句在数据库中创建、改动、删除模式对象)、数据库系统事件(如系统启动或退出、异常错误)、用户事件(如登录或退出数据库)。

  • 触发时间:即该TRIGGER 是在触发事件发生之前(BEFORE)还是之后(AFTER)触发,也就是触发事件和该TRIGGER 的操作顺序。
  • 触发操作:即该TRIGGER 被触发之后的目的和意图,正是触发器本身要做的事情。 比如:PL/SQL 块。
  • 触发对象:包含表、视图、模式、数据库。仅仅有在这些对象上发生了符合触发条件的触发事件,才会运行触发操作。
  • 触发条件:由WHEN子句指定一个逻辑表达式。仅仅有当该表达式的值为TRUE时,遇到触发事件才会自己主动运行触发器,使其运行触发操作。
  • 触发频率:说明触发器内定义的动作被运行的次数。即语句级(STATEMENT)触发器和行级(ROW)触发器。
  • 语句级(STATEMENT)触发器:是指当某触发事件发生时,该触发器仅仅运行一次;
  • 行级(ROW)触发器:是指当某触发事件发生时,对受到该操作影响的每一行数据,触发器都单独运行一次。

编写触发器时,须要注意下面几点:

  • 触发器不接受參数
  • 一个表上最多可有12个触发器,但同一时间、同一事件、同一类型的触发器仅仅能有一个。并各触发器之间不能有矛盾。
  • 在一个表上的触发器越多,对在该表上的DML操作的性能影响就越大。
  • 触发器最大为32KB。若确实须要,能够先建立过程,然后在触发器中用CALL语句进行调用。
  • 在触发器的运行部分仅仅能用DML语句(SELECT、INSERT、UPDATE、DELETE),不能使用DDL语句(CREATE、ALTER、DROP)。
  • 触发器中不能包括事务控制语句(COMMIT,ROLLBACK,SAVEPOINT)。由于触发器是触发语句的一部分,触发语句被提交、回退时,触发器也被提交、回退了。
  • 在触发器主体中调用的不论什么过程、函数,都不能使用事务控制语句。
  • 在触发器主体中不能申明不论什么Long和blob变量。新值new和旧值old也不能向表中的不论什么long和blob列。
  • 不同类型的触发器(如DML触发器、INSTEAD OF触发器、系统触发器)的语法格式和作用有较大差别。

8.2 创建触发器



创建触发器的一般语法是:

引用


CREATE [OR REPLACE] TRIGGER trigger_name

{BEFORE | AFTER }

{INSERT | DELETE | UPDATE [OF column [, column …]]}

[OR {INSERT | DELETE | UPDATE [OF column [, column …]]}...]

ON [schema.]table_name | [schema.]view_name

[REFERENCING {OLD [AS] old | NEW [AS] new| PARENT as parent}]

[FOR EACH ROW ]

[WHEN condition]

PL/SQL_BLOCK | CALL procedure_name;

当中:



BEFORE 和AFTER指出触发器的触发时序分别为前触发和后触发方式,前触发是在运行触发事件之前触发当前所创建的触发器,后触发是在运行触发事件之后触发当前所创建的触发器。




       FOR EACH ROW选项说明触发器为行触发器。行触发器和语句触发器的差别表如今:行触发器要求当一个DML语句操走影响数据库中的多行数据时,对于当中的每一个数据行,仅仅要它们符合触发约束条件,均激活一次触发器;而语句触发器将整个语句操作作为触发事件,当它符合约束条件时,激活一次触发器。当省略FOR EACH ROW 选项时,BEFORE 和AFTER 触发器为语句触发器,而INSTEAD OF 触发器则仅仅能为行触发器。




            REFERENCING 子句说明相关名称,在行触发器的PL/SQL块和WHEN 子句中能够使用相关名称參照当前的新、旧列值,默认的相关名称分别为OLD和NEW。触发器的PL/SQL块中应用相关名称时,必须在它们之前加冒号(:),但在WHEN子句中则不能加冒号。




WHEN 子句说明触发约束条件。Condition 为一个逻辑表达时,当中必须包括相关名称,而不能包括查询语句,也不能调用PL/SQL 函数。WHEN 子句指定的触发约束条件仅仅能用在BEFORE 和AFTER 行触发器中,不能用在INSTEAD OF 行触发器和其他类型的触发器中。




    当一个基表被修改( INSERT, UPDATE, DELETE)时要运行的存储过程,运行时依据其所依附的基表修改而自己主动触发,因此与应用程序无关,用数据库触发器能够保证数据的一致性和完整性。






每张表最多可建立12 种类型的触发器,它们是:



BEFORE INSERT



BEFORE INSERT FOR EACH ROW



AFTER INSERT



AFTER INSERT FOR EACH ROW





BEFORE UPDATE



BEFORE UPDATE FOR EACH ROW



AFTER UPDATE



AFTER UPDATE FOR EACH ROW





BEFORE DELETE



BEFORE DELETE FOR EACH ROW



AFTER DELETE



AFTER DELETE FOR EACH ROW



8.2.1 触发器触发次序



1. 运行 BEFORE语句级触发器;



2. 对与受语句影响的每一行:

  • 运行 BEFORE行级触发器
  • 运行 DML语句
  • 运行 AFTER行级触发器

3. 运行 AFTER语句级触发器



8.2.2 创建DML触发器



    触发器名与过程名和包的名字不一样,它是单独的名字空间,因而触发器名能够和表或过程有同样的名字,但在一个模式中触发器名不能同样。



DML触发器的限制

  • CREATE TRIGGER语句文本的字符长度不能超过32KB;
  • 触发器体内的SELECT 语句仅仅能为SELECT … INTO …结构,或者为定义游标所使用的SELECT 语句。
  • 触发器中不能使用数据库事务控制语句 COMMIT; ROLLBACK, SVAEPOINT 语句;
  • 由触发器所调用的过程或函数也不能使用数据库事务控制语句;
  • 触发器中不能使用LONG, LONG RAW 类型;
  • 触发器内能够參照LOB 类型列的列值,但不能通过 :NEW 改动LOB列中的数据;

DML触发器基本要点



l         触发时机:指定触发器的触发时间。假设指定为BEFORE,则表示在运行DML操作之前触发,以便防止某些错误操作发生或实现某些业务规则;假设指定为AFTER,则表示在运行DML操作之后触发,以便记录该操作或做某些事后处理。

  • 触发事件:引起触发器被触发的事件,即DML操作(INSERT、UPDATE、DELETE)。既能够是单个触发事件,也能够是多个触发事件的组合(仅仅能使用OR逻辑组合,不能使用AND逻辑组合)。
  • 条件谓词:当在触发器中包括多个触发事件(INSERT、UPDATE、DELETE)的组合时,为了分别针对不同的事件进行不同的处理,须要使用ORACLE提供的例如以下条件谓词。


      1)INSERTING:当触发事件是INSERT时,取值为TRUE,否则为FALSE。



      2)UPDATING [(column_1,column_2,…,column_x)]:当触发事件是UPDATE      时,假设改动了column_x列,则取值为TRUE,否则为FALSE。当中column_x是可选的。




      3)DELETING:当触发事件是DELETE时,则取值为TRUE,否则为FALSE。
  • 解发对象:指定触发器是创建在哪个表、视图上。
  • 触发类型:是语句级还是行级触发器。
  • 触发条件:由WHEN子句指定一个逻辑表达式,仅仅同意在行级触发器上指定触发条件,指定UPDATING后面的列的列表。

问题:当触发器被触发时,要使用被插入、更新或删除的记录中的列值,有时要使用操作前、        后列的值.



实现:  :NEW 修饰符訪问操作完毕后列的值



        :OLD 修饰符訪问操作完毕前列的值

特性

INSERT UPDATE DELETEOLD null 实际值 实际值NEW 实际值 实际值 null

例1: 建立一个触发器, 当职工表 emp 表被删除一条记录时,把被删除记录写到职工表删除日志表中去。

引用


CREATE TABLE emp_his AS SELECT * FROM EMP WHERE 1=2;

CREATE OR REPLACE TRIGGER tr_del_emp

   BEFORE DELETE --指定触发时机为删除操作前触发

   ON scott.emp

   FOR EACH ROW   --说明创建的是行级触发器

BEGIN

   --将改动前数据插入到日志记录表 del_emp ,以供监督使用。

   INSERT INTO emp_his(deptno , empno, ename , job ,mgr , sal , comm , hiredate )


       VALUES(ld.deptno,ld.empno,ld.ename
,ld.job,:old.mgr,ld.sal,ld.comm,ld.hiredate
);

END;

DELETE emp WHERE empno=7788;

DROP TABLE emp_his;

DROP TRIGGER del_emp;

例2:限制对Departments表改动(包含INSERT,DELETE,UPDATE)的时间范围,即不同意在非工作时间改动departments表。

引用


CREATE OR REPLACE TRIGGER tr_dept_time

BEFORE INSERT OR DELETE OR UPDATE

ON departments

BEGIN

IF (TO_CHAR(sysdate,'DAY') IN ('星期六', '星期日')) OR (TO_CHAR(sysdate, 'HH24:MI') NOT BETWEEN '08:30' AND '18:00') THEN


     RAISE_APPLICATION_ERROR(-20001, '不是上班时间,不能改动departments表');

END IF;

END;

例3:限定仅仅对部门号为80的记录进行行触发器操作。

引用


CREATE OR REPLACE TRIGGER tr_emp_sal_comm

BEFORE UPDATE OF salary, commission_pct

       OR DELETE

ON HR.employees

FOR EACH ROW

WHEN (old.department_id = 80)

BEGIN

CASE

     WHEN UPDATING ('salary') THEN

        IF :NEW.salary <ld.salary THEN




           RAISE_APPLICATION_ERROR(-20001, '部门80的人员的工资不能降');

        END IF;

     WHEN UPDATING ('commission_pct') THEN



        IF :NEW.commission_pct <ld.commission_pct THEN


           RAISE_APPLICATION_ERROR(-20002, '部门80的人员的奖金不能降');

        END IF;

     WHEN DELETING THEN

          RAISE_APPLICATION_ERROR(-20003, '不能删除部门80的人员记录');

     END CASE;

END;



/*

实例:

UPDATE employees SET salary = 8000 WHERE employee_id = 177;

DELETE FROM employees WHERE employee_id in (177,170);

*/

例4:利用行触发器实现级联更新。在改动了主表regions中的region_id之后(AFTER),级联的、自己主动的更新子表countries表中原来在该地区的国家的region_id。

引用


CREATE OR REPLACE TRIGGER tr_reg_cou

AFTER update OF region_id

ON regions

FOR EACH ROW

BEGIN

DBMS_OUTPUT.PUT_LINE('旧的region_id值是'||:old.region_id

                  ||'、新的region_id值是'||:new.region_id);

UPDATE countries SET region_id = :new.region_id

WHERE region_id =ld.region_id;

例5:在触发器中调用过程。

引用


CREATE OR REPLACE PROCEDURE add_job_history

( p_emp_id          job_history.employee_id%type

   , p_start_date      job_history.start_date%type

  , p_end_date        job_history.end_date%type

   , p_job_id          job_history.job_id%type

   , p_department_id   job_history.department_id%type

   )

IS

BEGIN

INSERT INTO job_history (employee_id, start_date, end_date,

                           job_id, department_id)

  VALUES(p_emp_id, p_start_date, p_end_date, p_job_id, p_department_id);

END add_job_history;



--创建触发器调用存储过程...

CREATE OR REPLACE TRIGGER update_job_history

AFTER UPDATE OF job_id, department_id ON employees

FOR EACH ROW

BEGIN

add_job_history(:old.employee_id,ld.hire_date, sysdate,


                 ld.job_id,ld.department_id);


END;

8.2.3 创建替代(INSTEAD OF)触发器





创建触发器的一般语法是:

引用


CREATE [OR REPLACE] TRIGGER trigger_name

INSTEAD OF

{INSERT | DELETE | UPDATE [OF column [, column …]]}

[OR {INSERT | DELETE | UPDATE [OF column [, column …]]}...]

ON [schema.] view_name --仅仅能定义在视图上

[REFERENCING {OLD [AS] old | NEW [AS] new| PARENT as parent}]

[FOR EACH ROW ] --由于INSTEAD OF触发器仅仅能在行级上触发,所以没有必要指定

[WHEN condition]

PL/SQL_block | CALL procedure_name;

当中:



            INSTEAD OF 选项使ORACLE激活触发器,而不运行触发事件。仅仅能对视图和对象视图建立INSTEAD OF触发器,而不能对表、模式和数据库建立INSTEAD OF 触发器。




            FOR EACH ROW选项说明触发器为行触发器。行触发器和语句触发器的差别表如今:行触发器要求当一个DML语句操走影响数据库中的多行数据时,对于当中的每一个数据行,仅仅要它们符合触发约束条件,均激活一次触发器;而语句触发器将整个语句操作作为触发事件,当它符合约束条件时,激活一次触发器。当省略FOR EACH ROW 选项时,BEFORE 和AFTER 触发器为语句触发器,而INSTEAD OF 触发器则为行触发器。




            REFERENCING 子句说明相关名称,在行触发器的PL/SQL块和WHEN 子句中能够使用相关名称參照当前的新、旧列值,默认的相关名称分别为OLD和NEW。触发器的PL/SQL块中应用相关名称时,必须在它们之前加冒号(:),但在WHEN子句中则不能加冒号。




WHEN 子句说明触发约束条件。Condition 为一个逻辑表达时,当中必须包括相关名称,而不能包括查询语句,也不能调用PL/SQL 函数。WHEN 子句指定的触发约束条件仅仅能用在BEFORE 和AFTER 行触发器中,不能用在INSTEAD OF 行触发器和其他类型的触发器中。








    INSTEAD_OF 用于对视图的DML触发,因为视图有可能是由多个表进行联结(join)而成,因而并不是是全部的联结都是可更新的。但能够依照所需的方式运行更新,比如以下情况:




例1:

引用


CREATE OR REPLACE VIEW emp_view AS

SELECT deptno, count(*) total_employeer, sum(sal) total_salary

FROM emp GROUP BY deptno;

在此视图中直接删除是非法:

引用


SQL>DELETE FROM emp_view WHERE deptno=10;

DELETE FROM emp_view WHERE deptno=10

ERROR 位于第 1 行:



ORA-01732: 此视图的数据操纵操作非法



可是我们能够创建INSTEAD_OF触发器来为 DELETE 操作运行所需的处理,即删除EMP表中全部基准行:

引用


CREATE OR REPLACE TRIGGER emp_view_delete

   INSTEAD OF DELETE ON emp_view FOR EACH ROW

BEGIN

   DELETE FROM emp WHERE deptno=ld.deptno;


END emp_view_delete;



DELETE FROM emp_view WHERE deptno=10;



DROP TRIGGER emp_view_delete;



DROP VIEW emp_view;

例2:创建复杂视图,针对INSERT操作创建INSTEAD OF触发器,向复杂视图插入数据。

  • 创建视图:
引用


CREATE OR REPLACE FORCE VIEW "HR"."V_REG_COU" ("R_ID", "R_NAME", "C_ID", "C_NAME")


AS

SELECT r.region_id,

    r.region_name,

    c.country_id,

    c.country_name

FROM regions r,

    countries c

WHERE r.region_id = c.region_id;
  • 创建触发器:
引用


CREATE OR REPLACE TRIGGER "HR"."TR_I_O_REG_COU" INSTEAD OF

INSERT ON v_reg_cou FOR EACH ROW DECLARE v_count NUMBER;

BEGIN

SELECT COUNT(*) INTO v_count FROM regions WHERE region_id = :new.r_id;

IF v_count = 0 THEN

    INSERT INTO regions

      (region_id, region_name

      ) VALUES

      (:new.r_id, :new.r_name

      );

END IF;



SELECT COUNT(*) INTO v_count FROM countries WHERE country_id = :new.c_id;

IF v_count = 0 THEN

    INSERT

    INTO countries

      (

        country_id,

        country_name,

        region_id

      )

      VALUES

      (

        :new.c_id,

        :new.c_name,

        :new.r_id

      );

END IF;

END;

创建INSTEAD OF触发器须要注意下面几点:

  • 仅仅能被创建在视图上,而且该视图没有指定WITH CHECK OPTION选项。
  • 不能指定BEFORE 或 AFTER选项。
  • FOR EACH ROW子但是可选的,即INSTEAD OF触发器仅仅能在行级上触发、或仅仅能是行级触发器,没有必要指定。
  • 没有必要在针对一个表的视图上创建INSTEAD OF触发器,仅仅要创建DML触发器就能够了。

8.2.3 创建系统事件触发器



    ORACLE10G提供的系统事件触发器能够在DDL或数据库系统上被触发。DDL指的是数据定义语言,如CREATE 、ALTER及DROP 等。而数据库系统事件包含数据库server的启动或关闭,用户的登录与退出、数据库服务错误等。创建系统触发器的语法例如以下:




创建触发器的一般语法是:

引用


CREATE OR REPLACE TRIGGER [sachema.]trigger_name

{BEFORE|AFTER}

{ddl_event_list | database_event_list}

ON { DATABASE | [schema.]SCHEMA }

[WHEN condition]

PL/SQL_block | CALL procedure_name;

当中: ddl_event_list:一个或多个DDL 事件,事件间用 OR 分开;



         database_event_list:一个或多个数据库事件,事件间用 OR 分开;



            系统事件触发器既能够建立在一个模式上,又能够建立在整个数据库上。当建立在模式(SCHEMA)之上时,仅仅有模式所指定用户的DDL操作和它们所导致的错误才激活触发器, 默认时为当前用户模式。当建立在数据库(DATABASE)之上时,该数据库全部用户的DDL操作和他们所导致的错误,以及数据库的启动和关闭均可激活触发器。要在数据库之上建立触发器时,要求用户具有ADMINISTER DATABASE TRIGGER权限。






以下给出系统触发器的种类和事件出现的时机(前或后):


















例1:创建触发器,存放有关事件信息。

引用


DESC ora_sysevent

DESC ora_login_user



--创建用于记录事件用的表



CREATE TABLE ddl_event

(crt_date timestamp PRIMARY KEY,

event_name VARCHAR2(20),

user_name VARCHAR2(10),

obj_type VARCHAR2(20),

obj_name VARCHAR2(20));



--创建触犯发器

CREATE OR REPLACE TRIGGER tr_ddl

AFTER DDL ON SCHEMA

BEGIN

   INSERT INTO ddl_event VALUES

   (systimestamp,ora_sysevent, ora_login_user,

    ora_dict_obj_type, ora_dict_obj_name);

END tr_ddl;

例2:创建登录、退出触发器。

引用


CREATE TABLE log_event

(user_name VARCHAR2(10),

address VARCHAR2(20),

logon_date timestamp,

logoff_date timestamp);



--创建登录触发器

CREATE OR REPLACE TRIGGER tr_logon

AFTER LOGON ON DATABASE

BEGIN

   INSERT INTO log_event (user_name, address, logon_date)

   VALUES (ora_login_user, ora_client_ip_address, systimestamp);

END tr_logon;

--创建退出触发器

CREATE OR REPLACE TRIGGER tr_logoff

BEFORE LOGOFF ON DATABASE

BEGIN

   INSERT INTO log_event (user_name, address, logoff_date)

   VALUES (ora_login_user, ora_client_ip_address, systimestamp);

END tr_logoff;

8.2.5 使用触发器谓词



    ORACLE 提供三个參数INSERTING, UPDATING, DELETING 用于推断触发了哪些操作。






8.2.6 又一次编译触发器



假设在触发器内调用其他函数或过程,当这些函数或过程被删除或改动后,触发器的状态将被标识为无效。当DML语句激活一个无效触发器时,ORACLE将又一次编译触发器代码,假设编译时发现错误,这将导致DML语句运行失败。




在PL/SQL程序中能够调用ALTER TRIGGER语句又一次编译已经创建的触发器,格式为:

引用
ALTER TRIGGER [schema.] trigger_name COMPILE [ DEBUG]

当中:DEBUG 选项要器编译器生成PL/SQL 程序条使其所使用的调试代码。



8.3 删除和使能触发器



删除触发器:

引用
DROP TRIGGER trigger_name;

当删除其它用户模式中的触发器名称,须要具有DROP ANY TRIGGER系统权限,当删除建立在数据库上的触发器时,用户须要具有ADMINISTER DATABASE TRIGGER系统权限。




此外,当删除表或视图时,建立在这些对象上的触发器也随之删除。



l         禁用或启用触发器



数据库TRIGGER 的状态:



有效状态(ENABLE):当触发事件发生时,处于有效状态的数据库触发器TRIGGER 将被触发。



无效状态(DISABLE):当触发事件发生时,处于无效状态的数据库触发器TRIGGER 将不会被触发,此时就跟没有这个数据库触发器(TRIGGER) 一样。



数据库TRIGGER的这两种状态能够互相转换。格式为:

引用


ALTER TIGGER trigger_name [DISABLE | ENABLE ];



--例:ALTER TRIGGER emp_view_delete DISABLE;

ALTER TRIGGER语句一次仅仅能改变一个触发器的状态,而ALTER TABLE语句则一次可以改变与指定表相关的全部触发器的使用状态。格式为:

引用
ALTER TABLE [schema.]table_name {ENABLE|DISABLE} ALL TRIGGERS;




--例:使表EMP 上的全部TRIGGER 失效:

ALTER TABLE emp DISABLE ALL TRIGGERS;

8.4 触发器和数据字典



相关数据字典:USER_TRIGGERS、ALL_TRIGGERS、DBA_TRIGGERS

引用
SELECT TRIGGER_NAME, TRIGGER_TYPE, TRIGGERING_EVENT,

TABLE_OWNER, BASE_OBJECT_TYPE, REFERENCING_NAMES,

STATUS, ACTION_TYPE

FROM user_triggers;

8.5   数据库触发器的应用举例



例1:创建一个DML语句级触发器,当对emp表运行INSERT, UPDATE, DELETE 操作时,它自己主动更新dept_summary 表中的数据。因为在PL/SQL块中不能直接调用DDL语句,所以,利用ORACLE内置包DBMS_UTILITY中的EXEC_DDL_STATEMENT过程,由它运行DDL语句创建触发器。

引用


CREATE TABLE dept_summary(

Deptno NUMBER(2),

Sal_sum NUMBER(9, 2),

Emp_count NUMBER);



INSERT INTO dept_summary(deptno, sal_sum, emp_count)

SELECT deptno, SUM(sal), COUNT(*)

FROM emp

GROUP BY deptno;



--创建一个PL/SQL过程disp_dept_summary

--在触发器中调用该过程显示dept_summary标中的数据。

CREATE OR REPLACE PROCEDURE disp_dept_summary

IS

Rec dept_summary%ROWTYPE;

CURSOR c1 IS SELECT * FROM dept_summary;

BEGIN

OPEN c1;

FETCH c1 INTO REC;

DBMS_OUTPUT.PUT_LINE('deptno    sal_sum    emp_count');

DBMS_OUTPUT.PUT_LINE('-------------------------------------');

WHILE c1%FOUND LOOP

    DBMS_OUTPUT.PUT_LINE(RPAD(rec.deptno, 6)||

      To_char(rec.sal_sum, '$999,999.99')||

      LPAD(rec.emp_count, 13));

    FETCH c1 INTO rec;

END LOOP;

CLOSE c1;

END;

BEGIN

DBMS_OUTPUT.PUT_LINE('插入前');

Disp_dept_summary();

DBMS_UTILITY.EXEC_DDL_STATEMENT('

    CREATE OR REPLACE TRIGGER trig1

      AFTER INSERT OR DELETE OR UPDATE OF sal ON emp

    BEGIN

      DBMS_OUTPUT.PUT_LINE(''正在运行trig1 触发器…'');

      DELETE FROM dept_summary;

      INSERT INTO dept_summary(deptno, sal_sum, emp_count)

      SELECT deptno, SUM(sal), COUNT(*)

      FROM emp GROUP BY deptno;

    END;

');





INSERT INTO dept(deptno, dname, loc)

VALUES(90, ‘demo_dept’, ‘none_loc’);

INSERT INTO emp(ename, deptno, empno, sal)

VALUES(USER, 90, 9999, 3000);



DBMS_OUTPUT.PUT_LINE('插入后');

Disp_dept_summary();



UPDATE emp SET sal=1000 WHERE empno=9999;

DBMS_OUTPUT.PUT_LINE('改动后');

Disp_dept_summary();



DELETE FROM emp WHERE empno=9999;

DELETE FROM dept WHERE deptno=90;



DBMS_OUTPUT.PUT_LINE('删除后');

Disp_dept_summary();

DBMS_UTILITY.EXEC_DDL_STATEMENT(‘DROP TRIGGER trig1’);

EXCEPTION

   WHEN OTHERS THEN

      DBMS_OUTPUT.PUT_LINE(SQLCODE||'---'||SQLERRM);



END;

例2:创建DML语句行级触发器。当对emp表运行INSERT, UPDATE, DELETE 操作时,它自己主动更新dept_summary 表中的数据。因为在PL/SQL块中不能直接调用DDL语句,所以,利用ORACLE内置包DBMS_UTILITY中的EXEC_DDL_STATEMENT过程,由它运行DDL语句创建触发器。

引用


BEGIN

  DBMS_OUTPUT.PUT_LINE('插入前');

  Disp_dept_summary();

  DBMS_UTILITY.EXEC_DDL_STATEMENT(

    'CREATE OR REPLACE TRIGGER trig2_update

      AFTER UPDATE OF sal ON emp

      REFERENCING OLD AS old_emp NEW AS new_emp

      FOR EACH ROW

      WHEN (old_emp.sal != new_emp.sal)

    BEGIN

      DBMS_OUTPUT.PUT_LINE(''正在运行trig2_update 触发器…'');

      DBMS_OUTPUT.PUT_LINE(''sal 旧值:''||ld_emp.sal);


      DBMS_OUTPUT.PUT_LINE(''sal 新值:''|| :new_emp.sal);

      UPDATE dept_summary

        SET sal_sum=sal_sum + :new_emp.sal -ld_emp.sal


        WHERE deptno = :new_emp.deptno;

    END;'

  );

 

  DBMS_UTILITY.EXEC_DDL_STATEMENT(

    'CREATE OR REPLACE TRIGGER trig2_insert

      AFTER INSERT ON emp

      REFERENCING NEW AS new_emp

      FOR EACH ROW

    DECLARE

      I NUMBER;

    BEGIN

      DBMS_OUTPUT.PUT_LINE(''正在运行trig2_insert 触发器…'');

      SELECT COUNT(*) INTO I

      FROM dept_summary WHERE deptno = :new_emp.deptno;

      IF I > 0 THEN

        UPDATE dept_summary

        SET sal_sum=sal_sum+:new_emp.sal,

        Emp_count=emp_count+1

        WHERE deptno = :new_emp.deptno;

      ELSE

        INSERT INTO dept_summary

        VALUES (:new_emp.deptno, :new_emp.sal, 1);

      END IF;

    END;'

  );



  DBMS_UTILITY.EXEC_DDL_STATEMENT(

    'CREATE OR REPLACE TRIGGER trig2_delete

      AFTER DELETE ON emp

      REFERENCING OLD AS old_emp

      FOR EACH ROW

    DECLARE

      I NUMBER;

    BEGIN

      DBMS_OUTPUT.PUT_LINE(''正在运行trig2_delete 触发器…'');

      SELECT emp_count INTO I

      FROM dept_summary WHERE deptno =ld_emp.deptno;


      IF I >1 THEN

        UPDATE dept_summary

        SET sal_sum=sal_sum -ld_emp.sal,


        Emp_count=emp_count - 1

        WHERE deptno =ld_emp.deptno;


      ELSE

        DELETE FROM dept_summary WHERE deptno =ld_emp.deptno;


      END IF;

    END;'

  );



  INSERT INTO dept(deptno, dname, loc)

    VALUES(90, 'demo_dept', 'none_loc');

  INSERT INTO emp(ename, deptno, empno, sal)

    VALUES(USER, 90, 9999, 3000);

  INSERT INTO emp(ename, deptno, empno, sal)

    VALUES(USER, 90, 9998, 2000);

  DBMS_OUTPUT.PUT_LINE('插入后');

  Disp_dept_summary();



  UPDATE emp SET sal = sal*1.1 WHERE deptno=90;

  DBMS_OUTPUT.PUT_LINE('改动后');

  Disp_dept_summary();



  DELETE FROM emp WHERE deptno=90;

  DELETE FROM dept WHERE deptno=90;

  DBMS_OUTPUT.PUT_LINE('删除后');

  Disp_dept_summary();



  DBMS_UTILITY.EXEC_DDL_STATEMENT('DROP TRIGGER trig2_update');

  DBMS_UTILITY.EXEC_DDL_STATEMENT('DROP TRIGGER trig2_insert');

  DBMS_UTILITY.EXEC_DDL_STATEMENT('DROP TRIGGER trig2_delete');

EXCEPTION

   WHEN OTHERS THEN

      DBMS_OUTPUT.PUT_LINE(SQLCODE||'---'||SQLERRM);

END;

例3:利用ORACLE提供的条件谓词INSERTING、UPDATING和DELETING创建与例2具有同样功能的触发器。

引用


BEGIN

    DBMS_OUTPUT.PUT_LINE('插入前');

    Disp_dept_summary();

    DBMS_UTILITY.EXEC_DDL_STATEMENT(

        'CREATE OR REPLACE TRIGGER trig2

            AFTER INSERT OR DELETE OR UPDATE OF sal

ON emp

            REFERENCING OLD AS old_emp NEW AS new_emp

            FOR EACH ROW

        DECLARE

            I NUMBER;

        BEGIN

            IF UPDATING ANDld_emp.sal != :new_emp.sal THEN


            DBMS_OUTPUT.PUT_LINE(''正在运行trig2 触发器…'');

                DBMS_OUTPUT.PUT_LINE(''sal 旧值:''||ld_emp.sal);


                DBMS_OUTPUT.PUT_LINE(''sal 新值:''|| :new_emp.sal);

                UPDATE dept_summary

                    SET sal_sum=sal_sum + :new_emp.sal -ld_emp.sal


                WHERE deptno = :new_emp.deptno;

            ELSIF INSERTING THEN

                DBMS_OUTPUT.PUT_LINE(''正在运行trig2触发器…'');

                SELECT COUNT(*) INTO I

        FROM dept_summary

        WHERE deptno = :new_emp.deptno;

                IF I > 0 THEN

                    UPDATE dept_summary

          SET sal_sum=sal_sum+:new_emp.sal,

              Emp_count=emp_count+1

          WHERE deptno = :new_emp.deptno;

            ELSE

          INSERT INTO dept_summary

            VALUES (:new_emp.deptno, :new_emp.sal, 1);

        END IF;

      ELSE

        DBMS_OUTPUT.PUT_LINE(''正在运行trig2触发器…'');

        SELECT emp_count INTO I

        FROM dept_summary WHERE deptno =ld_emp.deptno;


      IF I > 1 THEN

        UPDATE dept_summary

        SET sal_sum=sal_sum -ld_emp.sal,


        Emp_count=emp_count - 1

        WHERE deptno =ld_emp.deptno;


      ELSE

          DELETE FROM dept_summary

          WHERE deptno =ld_emp.deptno;


      END IF;

    END IF;

    END;'

  );



  INSERT INTO dept(deptno, dname, loc)

    VALUES(90, 'demo_dept', 'none_loc');

  INSERT INTO emp(ename, deptno, empno, sal)

    VALUES(USER, 90, 9999, 3000);

  INSERT INTO emp(ename, deptno, empno, sal)

    VALUES(USER, 90, 9998, 2000);

  DBMS_OUTPUT.PUT_LINE('插入后');

  Disp_dept_summary();



  UPDATE emp SET sal = sal*1.1 WHERE deptno=90;

  DBMS_OUTPUT.PUT_LINE('改动后');

  Disp_dept_summary();



  DELETE FROM emp WHERE deptno=90;

  DELETE FROM dept WHERE deptno=90;

  DBMS_OUTPUT.PUT_LINE('删除后');

  Disp_dept_summary();



  DBMS_UTILITY.EXEC_DDL_STATEMENT('DROP TRIGGER trig2');

EXCEPTION

   WHEN OTHERS THEN

      DBMS_OUTPUT.PUT_LINE(SQLCODE||'---'||SQLERRM);

END;

例4:创建INSTEAD OF 触发器。首先创建一个视图myview, 因为该视图是复合查询所产生的视图,所以不能运行DML语句。依据用户对视图所插入的数据推断须要将数据插入到哪个视图基表中,然后对该基表运行插入操作。

引用


DECLARE

    No NUMBER;

    Name VARCHAR2(20);

BEGIN

    DBMS_UTILITY.EXEC_DDL_STATEMENT('

        CREATE OR REPLACE VIEW myview AS

            SELECT empno, ename, ''E'' type FROM emp

            UNION

            SELECT dept.deptno, dname, ''D'' FROM dept

    ');

    -- 创建INSTEAD OF 触发器trigger3;

    DBMS_UTILITY.EXEC_DDL_STATEMENT('

        CREATE OR REPLACE TRIGGER trig3

            INSTEAD OF INSERT ON myview

            REFERENCING NEW n

            FOR EACH ROW

        DECLARE

            Rows INTEGER;

        BEGIN

            DBMS_OUTPUT.PUT_LINE(''正在运行trig3触发器…'');

            IF :n.type = ''D'' THEN

                SELECT COUNT(*) INTO rows

                    FROM dept WHERE deptno = :n.empno;

                IF rows = 0 THEN

                    DBMS_OUTPUT.PUT_LINE(''向dept表中插入数据…'');

                    INSERT INTO dept(deptno, dname, loc)

                        VALUES (:n.empno, :n.ename, ''none’’);

                ELSE

                    DBMS_OUTPUT.PUT_LINE(''编号为''|| :n.empno||

                     ''的部门已存在,插入操作失败!'');

                 END IF;

            ELSE

                SELECT COUNT(*) INTO rows

                    FROM emp WHERE empno = :n.empno;

                IF rows = 0 THEN

                    DBMS_OUTPUT.PUT_LINE('’向emp表中插入数据…’’);

                    INSERT INTO emp(empno, ename)

                        VALUES(:n.empno, :n.ename);

                ELSE

                    DBMS_OUTPUT.PUT_LINE(''编号为''|| :n.empno||

                      ''的人员已存在,插入操作失败!'');

                END IF;

            END IF;

        END;

    ');



    INSERT INTO myview VALUES (70, 'demo', 'D');

    INSERT INTO myview VALUES (9999, USER, 'E');

    SELECT deptno, dname INTO no, name FROM dept WHERE deptno=70;

    DBMS_OUTPUT.PUT_LINE('员工编号:'||TO_CHAR(no)||'姓名:'||name);

    SELECT empno, ename INTO no, name FROM emp WHERE empno=9999;

    DBMS_OUTPUT.PUT_LINE('部门编号:'||TO_CHAR(no)||'姓名:'||name);

  DELETE FROM emp WHERE empno=9999;

  DELETE FROM dept WHERE deptno=70;

    DBMS_UTILITY.EXEC_DDL_STATEMENT('DROP TRIGGER trig3');

END;

例5:利用ORACLE事件属性函数,创建一个系统事件触发器。首先创建一个事件日志表eventlog,由它存储用户在当前数据库中所创建的数据库对象,以及用户的登陆和注销、数据库的启动和关闭等事件,之后创建trig4_ddl、trig4_before和trig4_after触发器,它们调用事件属性函数将各个事件记录到eventlog数据表中。

引用


BEGIN

    -- 创建用于记录事件日志的数据表

    DBMS_UTILITY.EXEC_DDL_STATEMENT('

        CREATE TABLE eventlog(

            Eventname VARCHAR2(20) NOT NULL,

            Eventdate date default sysdate,

            Inst_num NUMBER NULL,

            Db_name VARCHAR2(50) NULL,

            Srv_error NUMBER NULL,

            Username VARCHAR2(30) NULL,

            Obj_type VARCHAR2(20) NULL,

            Obj_name VARCHAR2(30) NULL,

            Obj_owner VARCHAR2(30) NULL

        )

    ');



    -- 创建DDL触发器trig4_ddl

    DBMS_UTILITY.EXEC_DDL_STATEMENT('

        CREATE OR REPLACE TRIGGER trig4_ddl

            AFTER CREATE OR ALTER OR DROP

ON DATABASE

        DECLARE

            Event VARCHAR2(20);

            Typ VARCHAR2(20);

            Name VARCHAR2(30);

            Owner VARCHAR2(30);

        BEGIN

            -- 读取DDL事件属性

            Event := SYSEVENT;

            Typ := DICTIONARY_OBJ_TYPE;

            Name := DICTIONARY_OBJ_NAME;

            Owner := DICTIONARY_OBJ_OWNER;

            --将事件属性插入到事件日志表中

            INSERT INTO scott.eventlog(eventname, obj_type, obj_name, obj_owner)

                VALUES(event, typ, name, owner);

        END;

    ');



    -- 创建LOGON、STARTUP和SERVERERROR 事件触发器

    DBMS_UTILITY.EXEC_DDL_STATEMENT('

        CREATE OR REPLACE TRIGGER trig4_after

            AFTER LOGON OR STARTUP OR SERVERERROR

      ON DATABASE

        DECLARE

            Event VARCHAR2(20);

            Instance NUMBER;

            Err_num NUMBER;

            Dbname VARCHAR2(50);

            User VARCHAR2(30);

        BEGIN

            Event := SYSEVENT;

            IF event = ''LOGON'' THEN

                User := LOGIN_USER;

                INSERT INTO eventlog(eventname, username)

                    VALUES(event, user);

            ELSIF event = ''SERVERERROR'' THEN

                Err_num := SERVER_ERROR(1);

                INSERT INTO eventlog(eventname, srv_error)

                    VALUES(event, err_num);

            ELSE

                Instance := INSTANCE_NUM;

                Dbname := DATABASE_NAME;

                INSERT INTO eventlog(eventname, inst_num, db_name)

                    VALUES(event, instance, dbname);

      END IF;

    END;

  ');



  -- 创建LOGOFF和SHUTDOWN 事件触发器

  DBMS_UTILITY.EXEC_DDL_STATEMENT('

    CREATE OR REPLACE TRIGGER trig4_before

      BEFORE LOGOFF OR SHUTDOWN

      ON DATABASE

    DECLARE

      Event VARCHAR2(20);

      Instance NUMBER;

      Dbname VARCHAR2(50);

      User VARCHAR2(30);

    BEGIN

      Event := SYSEVENT;

      IF event = ''LOGOFF'' THEN

        User := LOGIN_USER;

        INSERT INTO eventlog(eventname, username)

          VALUES(event, user);

      ELSE

        Instance := INSTANCE_NUM;

        Dbname := DATABASE_NAME;

        INSERT INTO eventlog(eventname, inst_num, db_name)

          VALUES(event, instance, dbname);

      END IF;

    END;

  ');

END;



CREATE TABLE mydata(mydate NUMBER);

CONNECT SCOTT/TIGER



COL eventname FORMAT A10

COL eventdate FORMAT A12

COL username FORMAT A10

COL obj_type FORMAT A15

COL obj_name FORMAT A15

COL obj_owner FORMAT A10

SELECT eventname, eventdate, obj_type, obj_name, obj_owner, username, Srv_error

  FROM eventlog;



DROP TRIGGER trig4_ddl;

DROP TRIGGER trig4_before;

DROP TRIGGER trig4_after;

DROP TABLE eventlog;

DROP TABLE mydata;

8.6   数据库触发器的应用实例



用户能够使用数据库触发器实现各种功能:



复杂的审计功能;



例:将EMP 表的变化情况记录到AUDIT_TABLE和AUDIT_TABLE_VALUES中。

引用
CREATE TABLE audit_table(

    Audit_id     NUMBER,

    User_name VARCHAR2(20),

    Now_time DATE,

    Terminal_name VARCHAR2(10),

    Table_name VARCHAR2(10),

    Action_name VARCHAR2(10),

    Emp_id NUMBER(4));



CREATE TABLE audit_table_val(

    Audit_id NUMBER,

    Column_name VARCHAR2(10),

    Old_val NUMBER(7,2),

    New_val NUMBER(7,2));



CREATE SEQUENCE audit_seq

    START WITH 1000

    INCREMENT BY 1

    NOMAXVALUE

    NOCYCLE NOCACHE;



CREATE OR REPLACE TRIGGER audit_emp

    AFTER INSERT OR UPDATE OR DELETE ON emp

    FOR EACH ROW

DECLARE

    Time_now DATE;

    Terminal CHAR(10);

BEGIN

    Time_now:=sysdate;

    Terminal:=USERENV('TERMINAL');

    IF INSERTING THEN

        INSERT INTO audit_table

    VALUES(audit_seq.NEXTVAL, user, time_now,

           terminal, 'EMP', 'INSERT', :new.empno);

    ELSIF DELETING THEN

        INSERT INTO audit_table

    VALUES(audit_seq.NEXTVAL, user, time_now,

           terminal, 'EMP', 'DELETE',ld.empno);


    ELSE

        INSERT INTO audit_table

    VALUES(audit_seq.NEXTVAL, user, time_now,

           terminal, 'EMP', 'UPDATE',ld.empno);


        IF UPDATING('SAL') THEN

            INSERT INTO audit_table_val

                VALUES(audit_seq.CURRVAL, 'SAL',ld.sal, :new.sal);


        ELSE UPDATING('DEPTNO')

            INSERT INTO audit_table_val

                VALUES(audit_seq.CURRVAL, 'DEPTNO',ld.deptno, :new.deptno);


        END IF;

    END IF;

END;

增强数据的完整性管理;



例:改动DEPT表的DEPTNO列时,同一时候把EMP表中对应的DEPTNO也作对应的改动;

引用


CREATE SEQUENCE update_sequence

    INCREMENT BY 1

    START WITH 1000

    MAXVALUE 5000 CYCLE;



ALTER TABLE emp

    ADD update_id NUMBER;



CREATE OR REPLACE PACKAGE integritypackage AS

    Updateseq NUMBER;

END integritypackage;



CREATE OR REPLACE PACKAGE BODY integritypackage AS

END integritypackage;



CREATE OR REPLACE TRIGGER dept_cascade1

    BEFORE UPDATE OF deptno ON dept

DECLARE

    Dummy NUMBER;

BEGIN

    SELECT update_sequence.NEXTVAL INTO dummy FROM dual;

    Integritypackage.updateseq:=dummy;

END;



CREATE OR REPLACE TRIGGER dept_cascade2

    AFTER DELETE OR UPDATE OF deptno ON dept

    FOR EACH ROW

BEGIN

    IF UPDATING THEN

        UPDATE emp SET deptno=:new.deptno,

     update_id=integritypackage.updateseq

        WHERE emp.deptno=:old.deptno AND update_id IS NULL;

    END IF;

    IF DELETING THEN

        DELETE FROM emp

            WHERE emp.deptno=:old.deptno;

    END IF;

END;



CREATE OR REPLACE TRIGGER dept_cascade3

    AFTER UPDATE OF deptno ON dept

BEGIN

    UPDATE emp SET update_id=NULL

        WHERE update_id=integritypackage.updateseq;

END;



SELECT * FROM EMP ORDER BY DEPTNO;

UPDATE dept SET deptno=25 WHERE deptno=20;

帮助实现安全控制;



例:保证对EMP表的改动仅在工作日的工作时间;

引用
CREATE TABLE company_holidays(day DATE);



INSERT INTO company_holidays

    VALUES(sysdate);

INSERT INTO company_holidays

VALUES(TO_DATE('21-10月-01', 'DD-MON-YY'));



CREATE OR REPLACE TRIGGER emp_permit_change

    BEFORE INSERT OR DELETE OR UPDATE ON emp

DECLARE

    Dummy NUMBER;

    Not_on_weekends EXCEPTION;

    Not_on_holidays EXCEPTION;

    Not_working_hours EXCEPTION;

BEGIN

    /* check for weekends */

IF TO_CHAR(SYSDATE, 'DAY') IN ('星期六', '星期日') THEN

    RAISE not_on_weekends;

END IF;

    /* check for company holidays */

SELECT COUNT(*) INTO dummy FROM company_holidays

    WHERE TRUNC(day)=TRUNC(SYSDATE);

IF dummy >0 THEN

    RAISE not_on_holidays;

END IF;

    /* check for work hours(8:00 AM to 18:00 PM */

IF (TO_CHAR(SYSDATE,'HH24')<8 OR TO_CHAR(SYSDATE, 'HH24')>18) THEN

  RAISE not_working_hours;

END IF;

EXCEPTION

  WHEN not_on_weekends THEN

    RAISE_APPLICATION_ERROR(-20324,

'May not change employee table during the weekends');

  WHEN not_on_holidays THEN

    RAISE_APPLICATION_ERROR(-20325,

'May not change employee table during a holiday');

  WHEN not_working_hours THEN

    RAISE_APPLICATION_ERROR(-20326,

'May not change employee table during no_working hours');

END;

管理复杂的表复制;

  • 防止非法的事务发生;
  • 自己主动生成派生的列值;

帮助式显复杂的商业管理。

转:http://zhuguo.iteye.com/blog/1153835

oracle触发器实例的更多相关文章

  1. Oracle触发器实例(网搜)

    触发器使用教程和命名规范 目  录触发器使用教程和命名规范 11,触发器简介 12,触发器示例 23,触发器语法和功能 34,例一:行级触发器之一 45,例二:行级触发器之二 46,例三:INSTEA ...

  2. PL/SQL之存储过程和触发器实例

    1.Oracle存储过程实例 /*不带任何参数存储过程(输出系统日期)*/ CREATE OR REPLACE PROCEDURE output_date IS BEGIN DBMS_OUTPUT.P ...

  3. Oracle触发器用法实例详解

    转自:https://www.jb51.net/article/80804.htm. 本文实例讲述了Oracle触发器用法.分享给大家供大家参考,具体如下: 一.触发器简介 触发器的定义就是说某个条件 ...

  4. [转载]Oracle触发器用法实例详解

    本文实例讲述了Oracle触发器用法.分享给大家供大家参考,具体如下: 一.触发器简介 触发器的定义就是说某个条件成立的时候,触发器里面所定义的语句就会被自动的执行. 因此触发器不需要人为的去调用,也 ...

  5. Oracle 触发器在日志管理开发中的应用

    摘要: 本文讨论了利用数据库中的触发器对日志管理进行设计与实现的方法, 是对原来在客户端软件中编写日志管理方法的一种改进, 并给出了 Oracle9i 中的实例演示.关键词: Oracle; 触发器; ...

  6. oracle触发器应用

    首先给大家推荐两篇我看后的博文,我已经内容转载过来: 1.对触发器的讲解 本篇主要内容如下: 8.1 触发器类型 8.1.1 DML触发器 8.1.2 替代触发器 8.1.3 系统触发器 8.2 创建 ...

  7. ORACLE触发器的管理与实际应用【weber出品】

    一.INSTEAD OF触发器 对于简单的视图可以执行INSERT,UPDATE和DELETE操作,但是对于复杂视图,不允许直接执行INSERT,UPDATE,DELETE操作,当视图出现以下任何一种 ...

  8. Oracle 数据库实例

    Oracle- 数据库的实例,表空间,用户,表之间的关系 一.完整的Oracle数据库通常由两部分组成:Oracle数据库和数据库实例 1.数据库是一些列物理文件的集合(数据文件,控制文件,联机文件, ...

  9. Oracle 触发器(二)

    Oracle触发器详解   触发器是许多关系数据库系统都提供的一项技术.在oracle系统里,触发器类似过程和函数,都有声明,执行和异常处理过程的PL/SQL块. 8.1 触发器类型 触发器在数据库里 ...

随机推荐

  1. Monkey 使用aapt查看apk包名

    使用aapt    //aapt是sdk自带的一个工具,在sdk\builds-tools\目录下1.以ES文件浏览器为例,命令行中切换到aapt.exe目录执行:aapt dump badging ...

  2. Linux makefile教程之书写命令四[转]

    书写命令———— 每 条规则中的命令和操作系统Shell的命令行是一致的.make会一按顺序一条一条的执行命令,每条命令的开头必须以[Tab]键开头,除非,命令是紧跟 在依赖规则后面的分号后的.在命令 ...

  3. java类的访问控制符与其他几个特殊修饰符的总结

    1  访问控制符 1.1 字段或者方法的访问控制符   同一个类中 同一个包中 不同包中的子类 不同包中的非子类 private YES       默认(包可访问) YES YES     prot ...

  4. iOS开发——swift精讲&amp;MVC应用实战

    MVC应用实战 iOS开发中设计模式是很重要的,其中,使用最多的就是MVC模式,今天就简单介绍一下在Swift中这么使用MVC模式来实现我们想要的功能: 模型-视图-控制器(Model-View-Co ...

  5. Codevs 1191 数轴染色

    1191 数轴染色 时间限制: 1 s 空间限制: 128000 KB 题目等级 : 黄金 Gold 题目描述 Description 在一条数轴上有N个点,分别是1-N.一开始所有的点都被染成黑色. ...

  6. 使用read(),write(),seekg(),seekp()实现二进制方式文件随机存取

    // binary.cpp -- binary file I/O #include <iostream> #include <fstream> #include <iom ...

  7. Div+Css(一)必备知识

    我只积累我不知道的 参考链接 http://www.kwstu.com/ArticleView/divcss_201442291125960 http://www.kwstu.com/ArticleV ...

  8. 剑指Offer——记中国银行体检之旅

    剑指Offer--记中国银行体检之旅   11.23完成中国银行面试,当日回到学校.当天晚上8:39收到体检通知,自己真是又气又高兴啊.气的是自己刚从北京回来,接着又要去一次.高兴的是自己通过了面试. ...

  9. (已解决) eclipse提示报错&quot;serializing cdt project settings&quot;解决方案

    最近在使用eclipse作为cocos2dx的交叉编译工具.但是某天突然相关工程打不开,打开eclipse直接提示 “serializing cdt project settings” has enc ...

  10. (十九)ArcGIS JS 加载WMS服务(超图示例)

    前言 在工作中,需要在ArcGIS API for JavaScript中加载超图服务,因为超图的rest服务只可以用于Leaflet .openlayers3 (with MVT) .MapboxG ...