调用GOOGLE的TTS实现文字转语音(XE7+小米2)(XE10.1+小米5)

相关资料：

注意：在手机上必须选安装文字转语音引擎“google Text To Speech”
地址：http://www.shouji56.com/soft/GoogleWenZiZhuanYuYinYinQingGoogleTexttoSpeech_3864/

结果总结：

XE10.1 + 小米手机5 = 通过测试
首先手机上必须安装语音包：
1.“google Text To Speech” (不知为什么我的只发英文)
2.“度秘语音引擎3.0” (中英都可以发音)
3.“科大讯飞语音引擎3.0”(中英都可以发音)
4.APK发音使用的是当前语音包
5.小米手机5-设置-更多设置-语言和输入法-文字转语音（TTS）输出

1. 新建一个单元Androidapi.JNI.TTS

{*******************************************************}

{                                                       }

{           CodeGear Delphi Runtime Library             }

{ Copyright(c) 2013 Jeff Overcash                       }

{                                                       }

{*******************************************************}

{ Delphi trnslation for TTS Android Java classes from                            }

{ http://developer.android.com/reference/android/speech/tts/package-summary.html }

unit Androidapi.JNI.TTS;

interface

uses Androidapi.JNIBridge,

  Androidapi.JNI.JavaTypes,

  Androidapi.JNI.Os,

  Androidapi.JNI.App,

  Androidapi.JNI.GraphicsContentViewText;

type

  {Forward declarations}

  JSynthesisCallback = interface; // android.speech.tts.SynthesisCallback

  JSynthesisRequest = interface; // android.speech.tts.SynthesisRequest

  JTextToSpeech = interface; // android.speech.tts.TextToSpeech

  JTextToSpeech_Engine = interface; // android.speech.tts.TextToSpeech$Engine

  JTextToSpeech_EngineInfo = interface; //android.speech.tts.TextToSpeech$EngineInfo

  JTextToSpeech_OnInitListener = interface; // android.speech.tts.TextToSpeech$OnInitListener

  JTextToSpeech_OnUtteranceCompletedListener = interface; // android.speech.tts.TextToSpeech$OnUtteranceCompletedListener

  JTextToSpeechService = interface; // android.speech.tts.TextToSpeechService

  JUtteranceProgressListener = interface; // android.speech.tts.UtteranceProgressListener

  JSynthesisCallbackClass = interface(IJavaClass)

    ['{3B30766E-A43B-4005-BE92-472CD075F325}']

  end;

  [JavaSignature('android/speech/tts/SynthesisCallback')]

  JSynthesisCallback = interface(IJavaInstance)

    ['{190C13DE-BC7E-44CE-94F6-4AF1A84A4612}']

    function audioAvailable(buffer: TJavaArray<byte>; offset: Integer; length: Integer): Integer; cdecl;

    function done: Integer; cdecl;

    procedure error; cdecl;

    function getMaxBufferSize: Integer; cdecl;

    function start(sampleRateInHz: Integer; audioFormat: Integer;  channelCount: Integer): Integer; cdecl;

  end;

  TJSynthesisCallback = class(TJavaGenericImport<JSynthesisCallbackClass, JSynthesisCallback>) end;

  JSynthesisRequestClass = interface(JObjectClass)

    ['{AE41459D-42C6-4E66-B174-F6FA5216A1DA}']

    { Method }

    function init(text: JString; params: JBundle): JSynthesisRequest;

  end;

  [JavaSignature('android/speech/tts/SynthesisRequest')]

  JSynthesisRequest = interface(JObject)

    ['{1963DAD8-C58F-4868-BF8A-B43AE7A14145}']

    function getCountry: JString; cdecl;

    function getLanguage: JString; cdecl;

    function getParams: JBundle; cdecl;

    function getPitch: Integer; cdecl;

    function getSpeechRate: Integer; cdecl;

    function getText: JString; cdecl;

    function getVariant: JString; cdecl;

  end;

  TJSynthesisRequest = class(TJavaGenericImport<JSynthesisRequestClass, JSynthesisRequest>) end;

  JTextToSpeechClass = interface(JObjectClass)

    ['{0E2C5E49-95BE-4F19-BCCD-21960D03E957}']

    { Property Methods }

    function _GetACTION_TTS_QUEUE_PROCESSING_COMPLETED: JString;

    function _GetERROR: Integer;

    function _GetLANG_AVAILABLE: Integer;

    function _GetLANG_COUNTRY_AVAILABLE: Integer;

    function _GetLANG_COUNTRY_VAR_AVAILABLE: Integer;

    function _GetLANG_MISSING_DATA: Integer;

    function _GetLANG_NOT_SUPPORTED: Integer;

    function _GetQUEUE_ADD: Integer;

    function _GetQUEUE_FLUSH: Integer;

    function _GetSUCCESS: Integer;

    { Methods }

    function init(contect: JContext; listener: JTextToSpeech_OnInitListener) : JTextToSpeech; cdecl; overload;

    function init(context: JContext; listener: JTextToSpeech_OnInitListener; engine: JString): JTextToSpeech; overload;

    { Properties }

    property ACTION_TTS_QUEUE_PROCESSING_COMPLETED: JString read _GetACTION_TTS_QUEUE_PROCESSING_COMPLETED;

    property ERROR: Integer read _GetERROR;

    property LANG_AVAILABLE: Integer read _GetLANG_AVAILABLE;

    property LANG_COUNTRY_AVAILABLE: Integer read _GetLANG_COUNTRY_AVAILABLE;

    property LANG_COUNTRY_VAR_AVAILABLE: Integer read _GetLANG_COUNTRY_VAR_AVAILABLE;

    property LANG_MISSING_DATA: Integer read _GetLANG_MISSING_DATA;

    property LANG_NOT_SUPPORTED: Integer read _GetLANG_NOT_SUPPORTED;

    property QUEUE_ADD: Integer read _GetQUEUE_ADD;

    property QUEUE_FLUSH: Integer read _GetQUEUE_FLUSH;

    property SUCCESS: Integer read _GetSUCCESS;

  end;

  [JavaSignature('android/speech/tts/TextToSpeech')]

  JTextToSpeech = interface(JObject)

    ['{E1D06364-F967-4381-B178-EEDD42C203C7}']

    function addEarcon(earcon: JString; filename: JString): Integer; cdecl; overload;

    function addEarcon(earcon: JString; packagename: JString; resourceID: Integer): Integer; cdecl; overload;

    function addSpeech(text: JString; filename: JString): Integer; cdecl; overload;

    function addSpeech(text: JString; packagename: JString; resourceID: Integer) : Integer; cdecl; overload;

    function areDefaultsEnforced: Boolean; cdecl;

    function getDefaultEngine: JString; cdecl;

    function getEngines: JList; cdecl;

    function getFeatures(locale: JLocale): JSet; cdecl;

    function getLanguage: JLocale; cdecl;

    function isLanguageAvailable(loc: JLocale): Integer; cdecl;

    function isSpeaking: Boolean; cdecl;

    function playEarcon(earcon: JString; queueMode: Integer; params: JHashMap) : Integer; cdecl;

    function playSilence(durationInMs: Int64; queueMode: Integer; params: JHashMap): Integer; cdecl;

    function setEngineByPackageName(enginePackageName: JString): Integer; cdecl;

    function setLanguage(loc: JLocale): Integer; cdecl;

    function setOnUtteranceCompletedListener(listener: JTextToSpeech_OnUtteranceCompletedListener): Integer; cdecl;

    function setOnUtteranceProgressListener(listener: JUtteranceProgressListener): Integer; cdecl;

    function setPitch(pitch: Single): Integer; cdecl;

    function setSpeechRate(speechRate: Single): Integer; cdecl;

    procedure shutdown; cdecl;

    function speak(text: JString; queueMode: Integer; params: JHashMap) : Integer; cdecl;

    function stop: Integer; cdecl;

    function synthesizeToFile(text: JString; params: JHashMap; filename: String) : Integer; cdecl;

  end;

  TJTextToSpeech = class(TJavaGenericImport<JTextToSpeechClass, JTextToSpeech>) end;

  JTextToSpeech_EngineClass = interface(JObjectClass)

    ['{8516EA75-A410-4EEE-8281-9ABCE1577F46}']

    { Property Methods }

    function _GeCHECK_VOICE_DATA_PASS: Integer;

    function _GetACTION_CHECK_TTS_DATA: JString;

    function _GetACTION_INSTALL_TTS_DATA: JString;

    function _GetACTION_TTS_DATA_INSTALLED: JString;

    function _GetCHECK_VOICE_DATA_BAD_DATA: Integer;

    function _GetCHECK_VOICE_DATA_FAIL: Integer;

    function _GetCHECK_VOICE_DATA_MISSING_DATA: Integer;

    function _GetCHECK_VOICE_DATA_MISSING_VOLUME: Integer;

    function _GetDEFAULT_STREAM: Integer;

    function _GetEXTRA_AVAILABLE_VOICES: JString;

    function _GetEXTRA_CHECK_VOICE_DATA_FOR: JString;

    function _GetEXTRA_TTS_DATA_INSTALLED: JString;

    function _GetEXTRA_UNAVAILABLE_VOICES: JString;

    function _GetEXTRA_VOICE_DATA_FILES: JString;

    function _GetEXTRA_VOICE_DATA_FILES_INFO: JString;

    function _GetEXTRA_VOICE_DATA_ROOT_DIRECTORY: JString;

    function _GetINTENT_ACTION_TTS_SERVICE: JString;

    function _GetKEY_FEATURE_EMBEDDED_SYNTHESIS: JString;

    function _GetKEY_FEATURE_NETWORK_SYNTHESIS: JString;

    function _GetKEY_PARAM_PAN: JString;

    function _GetKEY_PARAM_STREAM: JString;

    function _GetKEY_PARAM_UTTERANCE_ID: JString;

    function _GetKEY_PARAM_VOLUME: JString;

    function _GetSERVICE_META_DATA: JString;

    { Methods }

    function init: JTextToSpeech_Engine;

    { Properties }

    property ACTION_CHECK_TTS_DATA: JString read _GetACTION_CHECK_TTS_DATA;

    property ACTION_INSTALL_TTS_DATA: JString read _GetACTION_INSTALL_TTS_DATA;

    property ACTION_TTS_DATA_INSTALLED: JString read _GetACTION_TTS_DATA_INSTALLED;

    property CHECK_VOICE_DATA_BAD_DATA: Integer read _GetCHECK_VOICE_DATA_BAD_DATA;

    property CHECK_VOICE_DATA_FAIL: Integer read _GetCHECK_VOICE_DATA_FAIL;

    property CHECK_VOICE_DATA_MISSING_DATA: Integer read _GetCHECK_VOICE_DATA_MISSING_DATA;

    property CHECK_VOICE_DATA_MISSING_VOLUME: Integer read _GetCHECK_VOICE_DATA_MISSING_VOLUME;

    property CHECK_VOICE_DATA_PASS: Integer read _GeCHECK_VOICE_DATA_PASS;

    property DEFAULT_STREAM: Integer read _GetDEFAULT_STREAM;

    property EXTRA_AVAILABLE_VOICES: JString read _GetEXTRA_AVAILABLE_VOICES;

    property EXTRA_CHECK_VOICE_DATA_FOR: JString read _GetEXTRA_CHECK_VOICE_DATA_FOR;

    property EXTRA_TTS_DATA_INSTALLED: JString read _GetEXTRA_TTS_DATA_INSTALLED;

    property EXTRA_UNAVAILABLE_VOICES: JString read _GetEXTRA_UNAVAILABLE_VOICES;

    property EXTRA_VOICE_DATA_FILES: JString read _GetEXTRA_VOICE_DATA_FILES;

    property EXTRA_VOICE_DATA_FILES_INFO: JString read _GetEXTRA_VOICE_DATA_FILES_INFO;

    property EXTRA_VOICE_DATA_ROOT_DIRECTORY: JString read _GetEXTRA_VOICE_DATA_ROOT_DIRECTORY;

    property INTENT_ACTION_TTS_SERVICE: JString read _GetINTENT_ACTION_TTS_SERVICE;

    property KEY_FEATURE_EMBEDDED_SYNTHESIS: JString read _GetKEY_FEATURE_EMBEDDED_SYNTHESIS;

    property KEY_FEATURE_NETWORK_SYNTHESIS: JString read _GetKEY_FEATURE_NETWORK_SYNTHESIS;

    property KEY_PARAM_PAN: JString read _GetKEY_PARAM_PAN;

    property KEY_PARAM_STREAM: JString read _GetKEY_PARAM_STREAM;

    property KEY_PARAM_UTTERANCE_ID: JString read _GetKEY_PARAM_UTTERANCE_ID;

    property KEY_PARAM_VOLUME: JString read _GetKEY_PARAM_VOLUME;

    property SERVICE_META_DATA: JString read _GetSERVICE_META_DATA;

  end;

  JTextToSpeech_Engine = interface(JObject)

    ['{5BAC3048-CB0C-4DC4-AF62-D0D9AE4394CF}']

  end;

  TJTextToSpeech_Engine = class(TJavaGenericImport<JTextToSpeech_EngineClass, JTextToSpeech_Engine>) end;

  JTextToSpeech_EngineInfoClass = interface(JObjectClass)

  ['{8297AD59-5A6F-4867-A185-CA09BAD90159}']

  {Methods}

    function init : JTextToSpeech_EngineInfo;

  end;

  JTextToSpeech_EngineInfo = interface(JObject)

  ['{204B30D8-6E25-4531-847D-18588D48D9BF}']

  {property Methods}

    function _Geticon: integer;

    function _Getlabel: JString;

    function _Getname: JString;

    procedure _Seticon(const Value: integer);

    procedure _Setlabel(const Value: JString);

    procedure _Setname(const Value: JString);

  {Properties}

    property icon : integer read _Geticon write _Seticon;

    property _label : JString read _Getlabel write _Setlabel;

    property name : JString read _Getname write _Setname;

  end;

  TJTextToSpeech_EngineInfo = class(TJavaGenericImport<JTextToSpeech_EngineInfoClass, JTextToSpeech_EngineInfo>) end;

  JTextToSpeech_OnInitListenerClass = interface(IJavaClass)

    ['{58D32EFB-6528-4EC6-BA4F-28B22FE8E573}']

  end;

  [JavaSignature('android/speech/tts/TextToSpeech$OnInitListener')]

  JTextToSpeech_OnInitListener = interface(IJavaInstance)

    ['{027DA109-680A-4A69-905D-F62E2BD1282F}']

    procedure onInit(status: Integer); cdecl;

  end;

  TJTextToSpeech_OnInitListener = class(TJavaGenericImport<JTextToSpeech_OnInitListenerClass,JTextToSpeech_OnInitListener>) end;

  JTextToSpeech_OnUtteranceCompletedListenerClass = interface(IJavaClass)

    ['{0A608BB9-A6BF-4746-8419-9317AD625DFA}']

  end;

  [JavaSignature('android/speech/tts/TextToSpeech$OnUtteranceCompletedListener')]

  JTextToSpeech_OnUtteranceCompletedListener = interface(IJavaInstance)

    ['{00439F2B-E73C-4B93-A9E3-832AE3CC1D5F}']

    procedure onUtteranceCompleted(utteranceID: JString); cdecl;

  end;

  TJTextToSpeech_OnUtteranceCompletedListener = class(TJavaGenericImport<JTextToSpeech_OnUtteranceCompletedListenerClass, JTextToSpeech_OnUtteranceCompletedListener>) end;

  JTextToSpeechServiceClass = interface(JServiceClass)

  ['{6BCC6ADC-CBCB-4515-A5C3-E33F9787EEC2}']

    function init : JTextToSpeechService;

  end;

  [JavaSignature('android/speech/tts/TextToSpeechService')]

  JTextToSpeechService = interface(JService)

  ['{EE3943B6-88DC-488B-9E10-E0FA9914708D}']

    function onGetFeaturesForLanguage(lang : JString; country : JString; variant : JString) : JSet; cdecl;

    function onGetLanguage : TJavaArray<JString>; cdecl;

    function onIsLanguageAvailable(lang : JString; country : JString; variant : JString) : Integer; cdecl;

    function onLoadLanguage(lang : JString; country : JString; variant : JString) : Integer; cdecl;

    procedure onStop; cdecl;

    procedure onSynthesizeText(request : JSynthesisRequest; callback : JSynthesisCallback); cdecl;

  end;

  TJTextToSpeechService = class(TJavaGenericImport<JTextToSpeechServiceClass, JTextToSpeechService>) end;

  JUtteranceProgressListenerClass = interface(JObjectClass)

    ['{0870532F-6FD7-4B1F-9DEF-B53F0095C98A}']

    { Method }

    function init: JUtteranceProgressListener;

  end;

  [JavaSignature('android/speech/tts/UtteranceProgressListener')]

  JUtteranceProgressListener = interface(JObject)

    ['{8B03499D-0B26-4F36-90E8-F724BD78DB0C}']

    procedure onDone(utteranceID: JString); cdecl;

    procedure onError(utteranceID: JString); cdecl;

    procedure onStart(utteranceID: JString); cdecl;

  end;

  TJUtteranceProgressListener = class(TJavaGenericImport<JUtteranceProgressListenerClass, JUtteranceProgressListener>) end;

implementation

end.

2.实例代码

{********************************************************}

{    XE10.1 + 小米手机5 = 通过测试                                                    }

{    首先手机上必须安装语音包                            }

{    语音包有                                            }

{    1.“google Text To Speech” (不知为什么我的只发英文)  }

{    2.“度秘语音引擎3.0” (中英都可以发音)                }

{    3.“科大讯飞语音引擎3.0”(中英都可以发音)             }

{    4.APK发音使用的是当前语音包                         }

{    5.设置-更多设置-语言和输入法-文字转语音（TTS）输出  }

{********************************************************}

unit Unit1;

interface

uses

  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,

  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.ScrollBox,

  FMX.Memo, FMX.Controls.Presentation, FMX.StdCtrls,

  //需要引入的单元

  FMX.Helpers.Android,//引

  Androidapi.Helpers,//引入

  Androidapi.JNIBridge,//引入

  Androidapi.Jni.JavaTypes,//引入

  Androidapi.JNI.TTS;//引入

type

  TForm1 = class(TForm)

    Button1: TButton;//发音

    Button2: TButton;//初始化

    Memo1: TMemo;//内容，可以是英语，可以是中文

    procedure Button1Click(Sender: TObject);

    procedure Button2Click(Sender: TObject);

  private

    type

      //倾听者

      TttsOnInitListener = class(TJavaLocal, JTextToSpeech_OnInitListener)

      private

        FParent: TForm1;

      public

        constructor Create(AParent: TForm1);

        procedure onInit(status: Integer); cdecl;

      end;

  private

    { Private declarations }

    ttsListener: TttsOnInitListener;//倾听者私有对象

    TTS: JTextToSpeech;//文字TO言语

    procedure SpeakOut;//说话

  public

    { Public declarations }

    constructor Create(AOwner: TComponent); override;

    destructor Destroy; override;

  end;

var

  Form1: TForm1;

implementation

{$R *.fmx}

{$R *.LgXhdpiPh.fmx ANDROID}

//发音

procedure TForm1.Button1Click(Sender: TObject);

begin

  SpeakOut;

end;

//初始化

procedure TForm1.Button2Click(Sender: TObject);

begin

  TTS := TJTextToSpeech.JavaClass.init(SharedActivityContext, ttsListener);

end;

//建立私有对象

constructor TForm1.Create(AOwner: TComponent);

begin

  inherited;

  ttsListener := TttsOnInitListener.Create(self);

end;

//释放对象

destructor TForm1.Destroy;

begin

  if Assigned(TTS) then

  begin

    TTS.stop;

    TTS.shutdown;

    TTS := nil;

  end;

  ttsListener := nil;

  inherited;

end;

//把要朗读的文字指定给 TTS 引擎

procedure TForm1.SpeakOut;

var

  text: JString;

begin

  text := StringToJString(Memo1.Lines.text);

  TTS.speak(text, TJTextToSpeech.JavaClass.QUEUE_FLUSH, nil);

end;

{ TForm1.TttsOnInitListener }

constructor TForm1.TttsOnInitListener.Create(AParent: TForm1);

begin

  inherited Create;

  FParent := AParent;

end;

procedure TForm1.TttsOnInitListener.onInit(status: Integer);

var

  Result: Integer;

begin

  if (status = TJTextToSpeech.JavaClass.SUCCESS) then

  begin

    Result := FParent.TTS.setLanguage(TJLocale.JavaClass.US); // 这是指定这美语

    if (Result = TJTextToSpeech.JavaClass.LANG_MISSING_DATA) or

      (Result = TJTextToSpeech.JavaClass.LANG_NOT_SUPPORTED) then

      //这里在XE10.1中提示“只能在主线程中使用此提示”

      //ShowMessage('不支持这种语言！')

    else

    begin

      FParent.Button1.Enabled := True;

      FParent.Button2.Enabled := False;

    end;

  end

  else

  begin

    //ShowMessage('初始化失败！');

  end;

end;

end.

调用GOOGLE的TTS实现文字转语音(XE7+小米2)(XE10.1+小米5)的更多相关文章

Android实例-调用GOOGLE的TTS实现文字转语音(XE7+小米2)(无图)
注意:在手机上必须选安装文字转语音引擎“google Text To Speech”地址:http://www.shouji56.com/soft/GoogleWenZiZhuanYuYinYinQi ...
Android实例-调用GOOGLE的TTS实现文字转语音(XE7+小米2)(XE10.1+小米5)
相关资料: 注意:在手机上必须选安装文字转语音引擎“google Text To Speech”地址:http://www.shouji56.com/soft/GoogleWenZiZhuanYuYi ...
Android文字转语音引擎（TTS）使用
百度网盘下载地址密码:3si0资源来源:https://blog.csdn.net/Sqq_yj/article/details/82460580?utm_source=blogxgwz4 简单比较 ...
Android技术分享-文字转语音并朗读
Android技术分享-文字转语音并朗读最近在做一个项目,其中有一个功能是需要将文本转换成语音并播放出来.下面我将我的做法分享一下. 非常令人开心的是,Android系统目前已经集成了TTS,提供了 ...
speech sdk 文字转语音
1.下载SDK包 https://www.microsoft.com/en-us/download/details.aspx?id=10121 2.直接上代码 // SpeechRecognition ...
Delphi文字转语音TTS【支持选择语音库，播放，暂停，开始，停止，生成语音文件，设置音量，设置语速】
作者QQ:(648437169) 点击下载➨文字转语音TTS [Delphi 文字转语音TTS]调用系统自带的TTS组件,支持XP,vista,win7,win8,win10系统,支持选择语音库,播放 ...
160617、使用espeak将文字转语音（TTS）
http://www.eguidedog.net/cn/WebSpeech_cn.php 简单使用例子: <html> <head> <meta http-equiv=& ...
【转】调用百度API，HTML在线文字转语音播报
<!DOCTYPE html> <html lang="en"> <head> <meta charset="UTF-8&quo ...
TTS 文字转语音 ekho
1.源码下载使用svn客户端,执行如下命令下载 svn co https://svn.code.sf.net/p/e-guidedog/code/ 2.官方网站查看说明 http://www.egu ...

随机推荐

Ubuntu12.04软件安装指南
更新升级源首先编辑软件源,在终端输入下面命令: sudo gedit /etc/apt/sources.list 较快速的升级源有163,台湾源,科大源,搜狐源等,大家将新的升级源全部覆盖原文件so ...
C++/CLI学习入门
aaarticlea/png;base64,iVBORw0KGgoAAAANSUhEUgAAAxIAAAFlCAYAAAB/fN6bAAAAAXNSR0IArs4c6QAAAARnQU1BAACxjw
UI设计师经常去的五个网站
1.站酷站酷(ZCOOL),中国人气设计师互动平台.深耕设计领域十年,站酷聚集了470万优秀设计师.摄影师.插画师.艺术家.创意人,设计创意群体中具有较高的影响力与号召力. 2.花瓣花瓣网, ...
[JAVA]多线程下如何确定执行顺序性
最近在讨论一个下载任务:要求文件下载后进行打包,再提供给用户下载: 如何确保打包的线程在所有下载文件的线程执行完成后进行呢? 看看下面三个兄弟的本事: CountDownLatch.CyclicBar ...
oralce的lag和lead函数
https://www.cnblogs.com/always-online/p/5010185.html
java通过IP地址获取物理位置
import java.io.*; import java.util.*; import java.util.regex.Matcher; import java.util.regex.Pattern ...
ubuntu14简介/安装/菜鸟使用手册
Linux拥有众多的发行版,可以分为两大类商业版和开源社区免费版.商业版以Radhat为代表,开源社区版以debian为代表. 简单的比较ubuntu与centos. Ubuntu 优点:丰富的 ...
UGUI控制UI的显示层级
1.调用transform.SetAsLastSibling();将该UI的显示层级调到最上面. 调用transform.SetAsFirstSibling();将该UI的显示层级调到最下面. 2. ...
2018.11.07 NOIP模拟异或（数位dp）
传送门对于每个二进制位单独考虑贡献. 然后对于两种情况分别统计. 对于第二种要用类似数位dpdpdp的方法来计算贡献. 代码
2018.11.01 NOIP训练图论（线段树+倍增+dfs序）
传送门一道挺妙的题. 对于询问点(u,v),如右图所示,我们可以发现存在一个点m在u->v的路径中,m子树的点到u是最近的,m子树外到v是最近的.其中dis(u,m)=(dis(u,v)-1) ...

调用GOOGLE的TTS实现文字转语音(XE7+小米2)(XE10.1+小米5)

调用GOOGLE的TTS实现文字转语音(XE7+小米2)(XE10.1+小米5)的更多相关文章

随机推荐

热门专题