ANSYS - 修改节点荷载的规则

问题：

分别在不同的荷载步对同一节点施加集中荷载，则节点最终所受荷载为各步荷载值叠加还是最后一步荷载值？

如，在第一个荷载步对节点n施加集中荷载F1，在第二个荷载步对该节点施加集中荷载F2，则第二个荷载步分析结果的荷载条件是Fn = F1+F2 还是Fn=F2 ?

解答：

分别对静力分析和瞬态分析进行试验，结论一致：节点所受荷载为最后一步荷载值。

1.  建立模型

建立平面模型如图1所示。单元类型为梁单元，节点1固定。

图1

2.  试验（以静力分析为例）

试验条件1（初始状态）：自由端荷载FY=0

查看节点1支反力 FY=0

试验条件2（第一次加载）：在试验条件1的基础上，重启动分析，自由端加载FY=-2

查看节点1支反力 FY=2

试验条件3（第二次加载）：在试验条件2的基础上，重启动分析，自由端加载FY=-4

查看节点1支反力 FY=4

3.  命令流

!建立模型

FINISH

/CLEAR

/FILNAME, TEMP

/PREP7

L = 4

H = 0.4

B = 0.2

A0 = B * H

I0 = B * H**3 / 12

ET,1,BEAM3

MP,EX,1,2.1E11

MP,PRXY,1,0.3

MP,ALPX,1,1E-5

MP, DENS, 1, 7800

R,1,A0,I0,H

K,1

K,2,,L

K,3,L,L

L,1,2

L,2,3

DK,1,ALL

LESIZE,ALL,,,10

LMESH,ALL

FINISH

!静力分析初始条件

/SOLU

ANTYPE, STATIC

SOLVE

SAVE

/POST1

PRRSOL

!静力分析第一次加载 FY=-2

FINISH$/CLEAR$/FILNAME,TEMP

/SOLU$RESUME$ANTYPE,,REST

F, 12, FY, -2

SOLVE

SAVE

/POST1

PRRSOL

!静力分析第二次加载 FY=-4

FINISH$/CLEAR$/FILNAME,TEMP

/SOLU$RESUME$ANTYPE,,REST

F, 12, FY, -4

SOLVE

SAVE

/POST1

PRRSOL

!瞬态分析求解命令流

/SOLU

ANTYPE, TRANS

TIME, 1

NSUBST, 10

KBC, 0

SOLVE

SAVE

FINISH$/CLEAR$/FILNAME,TEMP

/SOLU$RESUME$ANTYPE,,REST

TIME, 2

NSUBST, 10

KBC, 0

F, 12, FY, -2

SOLVE

SAVE

FINISH$/CLEAR$/FILNAME,TEMP

/SOLU$RESUME$ANTYPE,,REST

TIME, 3

NSUBST, 10

KBC, 0

F, 12, FY, -4

SOLVE

SAVE