oracle package pragma SERIALLY_REUSABLE(编译指示 告诉PL/SQL 的运行时引擎，在数据引用之时不要保持包级数据。)

当包第一次被动调用时，将进行初始化；比如将包从硬盘上调到内存中来，放到系统全局工作区的共享缓冲池中，包的运行状态则被放到用户全局区的会话中存储区中，因此可以保证每个调用包的会话都拥有包的运行副本，当会话结束时，包的运行状态才会被释放。
也就是说，包从第一次调用被初始化一直到会话结束才释放其运行状态，因此包中的变量具有会话级的作用域，因而可以跨多个事物存储数据。
如果再定义包规范时，指定了pragma serially_reusable ，则可以将包的运行状态保存在系统全局区，而不是用户全局区，这样每次调用包以后，包的运行状态就会被释放，这样再次调用包时，将重新开始包的状态； 

注意：这种每次调用便释放的连续进行会占用大量的内存，内存的占用量与包的并发调用用户数成正比，而且当前登陆的用户数无关，因此需要谨慎使用

CREATE OR REPLACE PACKAGE pragma_serially_reusable_no AS
--  PRAGMA SERIALLY_REUSABLE;  --包体的编译指示；
    -- countnum测试调用FUN_TEST的次数，如果不加 pragma serially_reusable v_num 的值是会话级变量 是不会改变的
    countnum NUMBER := 0 ;
  V_NUM NUMBER;
  FUNCTION FUN_TEST RETURN NUMBER;
END;

CREATE OR REPLACE PACKAGE BODY pragma_serially_reusable_no AS
--  PRAGMA SERIALLY_REUSABLE;  --包体的编译指示；
  FUNCTION FUN_TEST RETURN NUMBER AS
  BEGIN
    countnum :=countnum+1;
    DBMS_OUTPUT.PUT_LINE('第 '||countnum||' 次调用fun_test，v_num的值是：' || V_NUM || '  ;');
    RETURN V_NUM;
  END FUN_TEST;
BEGIN
--包体的初始化 ！
  SELECT TO_NUMBER(TO_CHAR(SYSDATE, 'ss')) INTO V_NUM FROM DUAL;
END pragma_serially_reusable_no;

CREATE OR REPLACE PACKAGE pragma_serially_reusable_yes AS
  PRAGMA SERIALLY_REUSABLE;  --包体的编译指示；
    -- countnum测试调用FUN_TEST的次数，如果不加 pragma serially_reusable v_num 的值是会话级变量 是不会改变的
    countnum NUMBER :=0 ;
  V_NUM NUMBER;
  FUNCTION FUN_TEST RETURN NUMBER;
END;

CREATE OR REPLACE PACKAGE BODY pragma_serially_reusable_yes AS
  PRAGMA SERIALLY_REUSABLE;  --包体的编译指示；
  FUNCTION FUN_TEST RETURN NUMBER AS
  BEGIN
        countnum :=countnum+1;
    DBMS_OUTPUT.PUT_LINE('第 '||countnum||' 次调用fun_test，v_num的值是：' || V_NUM || '  ;');
    RETURN V_NUM;
  END FUN_TEST;
BEGIN
--包体的初始化 ！
  SELECT TO_NUMBER(TO_CHAR(SYSDATE, 'ss')) INTO V_NUM FROM DUAL;
END pragma_serially_reusable_yes;

--测试代码；

--测试代码 ；
DECLARE
a NUMBER ;
b NUMBER ;
BEGIN
  a:=pragma_serially_reusable_yes.FUN_TEST ;
   b:=pragma_serially_reusable_no.FUN_TEST;
END;  

测试结果：
第 1 次调用fun_test，v_num的值是：36  ;  --counnum 不变  v_num 改变；

第 274 次调用fun_test，v_num的值是：31  ; --countnum 改变，v_num 不变；