在Vcl和FireMonkey应用程序中启用TXMLDocument 的XPath（selectNode，selectNodes）方法

该TXMLDocument的类让你来操作VCL和FireMonkey应用程序的XML文件，但这个类没有实现直接的方式来调用XPath的相关方法（selectNode，的selectNodes），所以你必须编写一组辅助函数来调用这些方法。

通常你可以写这样的东西

function selectSingleNode(ADOMDocument: IDOMDocument; const nodePath: WideString): IDOMNode;
var
  LDomNodeSelect : IDomNodeSelect;
begin
  if not Assigned(ADOMDocument) or not Supports(ADOMDocument.documentElement, IDomNodeSelect, LDomNodeSelect) then
   Exit;
  //or just LDomNodeSelect:= (ADOMDocument.documentElement as IDOMNodeSelect);
  Result:=LDomNodeSelect.selectNode(nodePath);
end;
function SelectNodes(ADOMDocument: IDOMDocument; const nodePath: WideString): IDOMNodeList;
var
  LDomNodeSelect : IDomNodeSelect;
begin
  if not Assigned(ADOMDocument) or not Supports(ADOMDocument.documentElement, IDomNodeSelect, LDomNodeSelect) then
   Exit;
  //or just LDomNodeSelect:= (ADOMDocument.documentElement as IDOMNodeSelect);
  Result:=LDomNodeSelect.selectNodes(nodePath);
end;

并这样使用：

var
  XmlDoc: IXMLDocument;
  LNode : IDOMNode;
  i : Integer;
begin
  XmlDoc := TXMLDocument.Create(nil);
  XmlDoc.Active := True;
  XmlDoc.Options := XmlDoc.Options + [doNodeAutoIndent];
  XmlDoc.Version := '1.0';
  ...
  ...
  LNode:=selectSingleNode(XmlDoc.DOMDocument,XPathExpr);

上面的代码在Windows下使用MSXML提供程序作为默认DOM供应商可以正常工作，但在必须在OSX和Windows中运行的FireMonkey应用程序中，必须将默认DOM供应商设置为ADOM（OpenXML）。

DefaultDOMVendor := OpenXML4Factory.Description;

现在，如果您尝试在ADOM供应商下使用上述功能（selectSingleNode，SelectNodes），您将获得一个非常好的例外

EOleException Catastrophic failure 8000FFFF

这个问题的根目录是Tox4DOMNode.selectNode和Tox4DOMNode.selectNodes这些方法的实现，请检查下一个代码。

function Tox4DOMNode.selectNode(const nodePath: WideString): IDOMNode;
var
  xpath: TXpathExpression;
  xdomText: TDomText;
begin
  Result := nil;
  if not Assigned(WrapperDocument) or not Assigned(WrapperDocument.WrapperDOMImpl) then
    Exit;

  xpath := WrapperDocument.WrapperDOMImpl.FXpath; //here the xpath is set with a nil value because the FXpath was no initialized
  xpath.ContextNode := NativeNode; //Here the App crash because xpath is nil

FXpath字段在Tox4DOMImplementation.InitParserAgent方法中初始化，该方法永远不会调用您使用Tox4DOMImplementation.loadFromStream或Tox4DOMImplementation.loadxml方法的方法。因此，要解决此问题，必须在调用selectNode和selectNodes方法之前调用Tox4DOMImplementation.InitParserAgent函数。

function selectSingleNode(ADOMDocument: IDOMDocument; const nodePath: WideString): IDOMNode;
var
  LDomNodeSelect : IDomNodeSelect;
begin
  if not Assigned(ADOMDocument) or not Supports(ADOMDocument.documentElement, IDomNodeSelect, LDomNodeSelect) then
   Exit;
  //or just LDomNodeSelect:= (ADOMDocument.documentElement as IDOMNodeSelect);
  if (DefaultDOMVendor = OpenXML4Factory.Description) then
    Tox4DOMNode(LDomNodeSelect).WrapperDocument.WrapperDOMImpl.InitParserAgent;
  Result:=LDomNodeSelect.selectNode(nodePath);
end;
function SelectNodes(ADOMDocument: IDOMDocument; const nodePath: WideString): IDOMNodeList;
var
  LDomNodeSelect : IDomNodeSelect;
begin
  if not Assigned(ADOMDocument) or not Supports(ADOMDocument.documentElement, IDomNodeSelect, LDomNodeSelect) then
   Exit;
  //or just LDomNodeSelect:= (ADOMDocument.documentElement as IDOMNodeSelect);
  if (DefaultDOMVendor = OpenXML4Factory.Description) then
    Tox4DOMNode(LDomNodeSelect).WrapperDocument.WrapperDOMImpl.InitParserAgent;
  Result:=LDomNodeSelect.selectNodes(nodePath);
end;

现在通过这些更改，您将能够使用ADOM供应商评估VCL和FireMonkey应用程序中的XPath表达式。

这是在Windows和OSX （Delphi 10.3.2 Rio）中测试的演示控制台应用程序：

 // reference  https://theroadtodelphi.wordpress.com/2013/05/29/enabling-xpath-selectnode-selectnodes-methods-in-vcl-and-firemonkey-apps/

 {$APPTYPE CONSOLE}
 uses
 {$IFDEF MSWINDOWS}
   System.Win.ComObj,
   Winapi.ActiveX,
 {$ENDIF}
   System.SysUtils,
   Xml.XMLIntf,
   Xml.adomxmldom,
   Xml.XMLDom,
   Xml.XMLDoc;

 function selectSingleNode(ADOMDocument: IDOMDocument; const nodePath: WideString): IDOMNode;
 var
   LDomNodeSelect: IDomNodeSelect;
 begin
   if not Assigned(ADOMDocument) or not Supports(ADOMDocument.documentElement, IDomNodeSelect, LDomNodeSelect) then
     Exit;
   // or just LDomNodeSelect:= (ADOMDocument.documentElement as IDOMNodeSelect);
   if (DefaultDOMVendor = OpenXML4Factory.Description) then
     Tox4DOMNode(LDomNodeSelect).WrapperDocument.WrapperDOMImpl.InitParserAgent;
   Result := LDomNodeSelect.selectNode(nodePath);
 end;

 function SelectNodes(ADOMDocument: IDOMDocument; const nodePath: WideString): IDOMNodeList;
 var
   LDomNodeSelect: IDomNodeSelect;
 begin
   if not Assigned(ADOMDocument) or not Supports(ADOMDocument.documentElement, IDomNodeSelect, LDomNodeSelect) then
     Exit;
   // or just LDomNodeSelect:= (ADOMDocument.documentElement as IDOMNodeSelect);
   if (DefaultDOMVendor = OpenXML4Factory.Description) then
     Tox4DOMNode(LDomNodeSelect).WrapperDocument.WrapperDOMImpl.InitParserAgent;
   Result := LDomNodeSelect.SelectNodes(nodePath);
 end;

 procedure TestXPath;
 var
   XMLDoc: IXMLDocument;
   Root, Book, Author, Publisher: IXMLNode;
   LNodeList: IDOMNodeList;
   LNode: IDOMNode;
   i: Integer;
 begin
   XMLDoc := TXMLDocument.Create(nil);
   XMLDoc.Active := True;
   XMLDoc.Options := XMLDoc.Options + [doNodeAutoIndent];
   XMLDoc.Version := '1.0';

   Root := XMLDoc.CreateNode('BookStore');
   Root.Attributes['url'] := 'http://www.amazon.com';
   XMLDoc.documentElement := Root;

   Book := XMLDoc.CreateNode('Book');
   Book.Attributes['Name'] := 'Steve Jobs';
   Author := XMLDoc.CreateNode('Author');
   Author.Text := 'Walter Isaacson';
   Publisher := XMLDoc.CreateNode('Publisher');
   Publisher.Text := 'Simon Schuster (October 24, 2011)';
   Root.ChildNodes.Add(Book);
   Book.ChildNodes.Add(Author);
   Book.ChildNodes.Add(Publisher);

   Book := XMLDoc.CreateNode('Book');
   Book.Attributes['Name'] := 'Clean Code: A Handbook of Agile Software Craftsmanship';
   Author := XMLDoc.CreateNode('Author');
   Author.Text := 'Robert C. Martin';
   Publisher := XMLDoc.CreateNode('Publisher');
   Publisher.Text := 'Prentice Hall; 1 edition (August 11, 2008)';
   Root.ChildNodes.Add(Book);
   Book.ChildNodes.Add(Author);
   Book.ChildNodes.Add(Publisher);

   Book := XMLDoc.CreateNode('Book');
   Book.Attributes['Name'] := 'Paradox Lost';
   Author := XMLDoc.CreateNode('Author');
   Author.Text := 'Kress, Peter';
   Publisher := XMLDoc.CreateNode('Publisher');
   Publisher.Text := 'Prentice Hall; 1 edition (February 2, 2000)';
   Root.ChildNodes.Add(Book);
   Book.ChildNodes.Add(Author);
   Book.ChildNodes.Add(Publisher);

   Writeln(XMLDoc.Xml.Text);

   Writeln('selectSingleNode');
   LNode := selectSingleNode(XMLDoc.DOMDocument, '/BookStore/Book[2]/Author["Robert C. Martin"]');
   if LNode <> nil then
     Writeln(LNode.firstChild.nodeValue);

   Writeln;

   Writeln('SelectNodes');
   LNodeList := SelectNodes(XMLDoc.DOMDocument, '//BookStore/Book/Author');
   if LNodeList <> nil then
     for i :=  to LNodeList.length -  do
       Writeln(LNodeList[i].firstChild.nodeValue);
 end;

 begin
   try
     ReportMemoryLeaksOnShutdown := True;
     DefaultDOMVendor := OpenXML4Factory.Description;
 {$IFDEF MSWINDOWS}CoInitialize(nil); {$ENDIF}
     try
       TestXPath;
     finally
 {$IFDEF MSWINDOWS}CoUninitialize; {$ENDIF}
     end;
   except
 {$IFDEF MSWINDOWS}
     on E: EOleException do
       Writeln(Format('EOleException %s %x', [E.Message, E.ErrorCode]));
 {$ENDIF}
     on E: Exception do
       Writeln(E.Classname, ':', E.Message);
   end;
   Writeln;
   Writeln('Press Enter to exit');
   Readln;

 end.