[ActionScript 3.0] 翻牌效果，运用语法rotationY，PerspectiveProjection

 package
 {
     import com.tweener.transitions.Tweener;

     import flash.display.Bitmap;
     import flash.display.BitmapData;
     import flash.display.Sprite;
     import flash.events.MouseEvent;
     import flash.geom.PerspectiveProjection;
     import flash.geom.Point;
     import flash.utils.getDefinitionByName;
     import flash.utils.setTimeout;

     /**
      * @author Frost.Yen
      * @E-mail 871979853@qq.com
      * @create 2015-7-29 下午4:53:03
      *
      */
     [SWF(width="1024",height="768",backgroundColor = "0x000000")]
     public class FlipCard extends Sprite
     {
         [Embed(source="card.png")]
         private var _card:Class;
         [Embed(source="back.jpg")]
         private var _back:Class;
         public function FlipCard()
         {
             initViews();
         }
         private function initViews():void
         {
             var cardClass:Class = getDefinitionByName("FlipCard__card") as  Class;
             var backClass:Class = getDefinitionByName("FlipCard__back") as  Class;
             var cardBitmap:Bitmap = new cardClass();
             var backBitmap:Bitmap = new backClass();

             for(var i:int = 0;i<18;i++){
                 var card:Card = new Card();
                 var backBmp:Bitmap = new Bitmap();
                 var cardBmp:Bitmap = new Bitmap();
                 var backBmpd:BitmapData = new BitmapData(backBitmap.width,backBitmap.height);
                 var cardBmpd:BitmapData = new BitmapData(cardBitmap.width,cardBitmap.height);
                 backBmpd.draw(backBitmap);
                 cardBmpd.draw(cardBitmap);
                 backBmp.bitmapData = backBmpd;
                 cardBmp.bitmapData = cardBmpd;
                 cardBmp.width = backBmp.width = 79;
                 cardBmp.height = backBmp.height = 115;
                 card.getCard(cardBmp,backBmp);
                 card.x = 200 + i%6*110+79*0.5;
                 card.y = 100 + Math.floor(i/6)*140+115*0.5;
                 this.addChild(card);
                 var perspective:PerspectiveProjection = new PerspectiveProjection();
                 perspective.projectionCenter = new Point(card.x,card.y)
                 card.transform.perspectiveProjection = perspective;
             }
             setTimeout(turnTheCard,1000*2);
         }
         private function onCardClick(e:MouseEvent):void
         {
             turnTween(e.currentTarget as Card);
         }
         private function turnTheCard():void
         {
             for(var i:int = 0;i<this.numChildren;i++){
                 turnTween(this.getChildAt(i) as Card);
                 this.getChildAt(i).addEventListener(MouseEvent.CLICK,onCardClick);
             }
         }
         private function turnTween(card:Card):void
         {
             Tweener.addTween(card,{rotationY:90,time:0.3,transition:"linear",onComplete:onComplete,onCompleteParams:[card]});
             function onComplete(obj:Card):void
             {
                 obj.swapCard();
                 Tweener.addTween(obj,{rotationY:180,time:0.3,transition:"linear",onComplete:function():void{obj.rotationY = 0;obj.setRotationY();}});
             }
         }
     }
 }
 import flash.display.Bitmap;
 import flash.display.Sprite;

 class Card extends Sprite{
     private var _back:Sprite;
     private var _card:Sprite;
     private var _rotationY:Number;
     public function Card(){
         _back = new Sprite();
         _card = new Sprite();
         this.addChild(_back);
         this.addChild(_card);
     }
     public function getCard(card:Bitmap,back:Bitmap):void
     {
         card.x = back.x = -back.width*0.5;
         card.y = back.y = -back.height*0.5;
         _card.addChild(card);
         _back.addChild(back);
     }

     public function swapCard():void
     {
         this.swapChildren(_card,_back);
         setRotationY();
     }
     public function setRotationY():void
     {
         if(this.rotationY == 90){
             _card.rotationY = _back.rotationY = 180;
         }else if(this.rotationY == 0){
             _card.rotationY = _back.rotationY = 0;
         }
     }
 }