使用JavaService.exe(amd64)发布java服务(jdk x64)

最近项目中需要使用java服务，但是java服务已经写好了，就等待部署到windows服务中，遇到了种种困难------在x64服务器中部署jdk x64编译的jar时，遇到了各种纠结。

本文找到了一种解决方案（在x64服务器、jdk x64 java环境中部署java服务的解决方案）：

首先，我们选测的工具是JavaService.exe,目前最新版本是：2.0.10 

下载地址：http://forge.ow2.org/projects/javaservice/

之后，解压下载的

再最后，编译待部署的java服务程序jar包：

再之后，整理部署java服务的目录结构：

1，建立java服务安装目录为：D:\Java_Study\windowsservice\JavaService_2_0_10-amd64

2，拷贝编译好的TestTimer.jar包到服务安装目录的根目录下：D:\Java_Study\windowsservice\JavaService_2_0_10-amd64\TestTimer.jar;

及拷贝TestTimer工程依赖的外部包log4j-1.2.17.jar到服务安装目录的根目录下：D:\Java_Study\windowsservice\JavaService_2_0_10-amd64\bin\log4j-1.2.17.jar;

3，把JavaService_2_0_10-amd64.zip解压出的JavaService.exe文件拷贝到D:\Java_Study\windowsservice\JavaService_2_0_10-amd64\JavaService.exe;

4,  整理install.bat和uninstall.bat。

install.bat:

 @echo off
 rem 修改控制台颜色
 color 1d
 rem * 使用JavaService将TestTimer安装为Windows服务的脚本
 rem *
 rem * JavaService - Windows NT Service Daemon for Java applications
 rem * Copyright (C) 2006 Multiplan Consultants Ltd. LGPL Licensing applies
 rem * Information about the JavaService software is available at the ObjectWeb
 rem * web site. Refer to http://javaservice.objectweb.org for more details.
 rem 开始批处理文件中环境改动的本地化操作，在使用endlocal后环境将恢复到原先的内容
 SETLOCAL
 rem 设置环境变量,指向当前路径
 SET BASE_PATH=%CD%
 rem 设置Java path: jre_home
 SET JRE_HOME=D:\Java_Study\Java\jdk1.7.0_79

 rem 判断JRE_HOME是否正确
 if "%JRE_HOME%" == "" goto no_java
 if not exist "%JRE_HOME%\bin\java.exe" goto no_java

 rem 设置jvm内存分配情况
 set JVM_MEMORY=-Xms128m -Xmx256m
 rem 设置jvmdll使用哪一种模式
 SET jvmdll=%JRE_HOME%\jre\bin\server\jvm.dll
 if not exist "%jvmdll%" goto no_java  

 rem 设置JavaService路径
 set JSBINDIR=D:\Java_Study\windowsservice\JavaService_2_0_10-amd64
 set JSEXE=%JSBINDIR%\JavaService.exe

 rem 判断jar是否正确
 SET acctjar=%BASE_PATH%\TestTimer.jar
 if not exist "%acctjar%" goto no_peer

 @echo . Using following version of JavaService executable:
 @echo .
 "%JSEXE%" -version
 @echo .  

 rem parameters and files seem ok, go ahead with the service installation
 @echo .  

 rem 处理该批处理的输入参数，后台服务启动模式：自动
 SET svcmode=
 if "%1" == "-manual" SET svcmode=-manual
 if "%1" == "-auto" SET svcmode=-auto  

 rem 设置JAVA_OPTS
 set JAVA_OPTS=%JAVA_OPTS% -Djava.class.path="%BASE_PATH%\bin\log4j-1.2.17.jar;%BASE_PATH%\TestTimer.jar"
 set JAVA_OPTS=%JAVA_OPTS% %JVM_MEMORY%  

 rem 设置startstop
 SET START_STOP=-start cn.test.timer.TestTimer  

 rem 设置Log文件路径
 set OUT_ERR=-out "%BASE_PATH%\service_out.log" -err "%BASE_PATH%\service_err.log"  

 rem 设置desp
 set DESP=-description "TestTimer Service"   

 rem 设置执行命令行
 set runcmd="%JSEXE%" -install TestTimerService
 set runcmd=%runcmd% "%jvmdll%"
 set runcmd=%runcmd% %JAVA_OPTS%
 set runcmd=%runcmd% %START_STOP%
 set runcmd=%runcmd% %OUT_ERR%
 set runcmd=%runcmd% -current
 set runcmd=%runcmd% "%BASE_PATH%"
 set runcmd=%runcmd% %svcmode%
 set runcmd=%runcmd% -overwrite
 set runcmd=%runcmd% -startup 6
 set runcmd=%runcmd% %DESP%
 echo %runcmd%  

 rem 执行安装命令
 %runcmd%
 rem 启动服务
 net start TestTimerService

 if ERRORLEVEL 1 goto js_error
 goto end
 :no_java
 @echo . 没有Java运行环境，安装脚本不能运行
 goto error_exit
 :no_peer
 @echo . 启动文件TestTimer.jar不存在，安装脚本不能运行
 goto error_exit
 :no_jsexe
 @echo . 可执行文件JavaService.exe 不存在，安装脚本不能运行
 goto error_exit
 :js_error
 @echo . TestTimerService在安装为服务的过程中发生了错误，请检查相关日志文件
 goto error_exit
 :error_exit

 @echo .
 @echo . 安装失败，不能将 TestTimer安装为Windows服务
 @echo .
 @echo . 命令格式:
 @echo .
 @echo .  %~n0 [-auto / -manual] [-np]
 @echo .
 @echo . 其中:
 @echo .  -auto (默认) or -manual 参数说明了服务的启动模式：自动或者手动
 @echo .  -np 批处理命令执行完毕后不暂停
 @echo .
 @echo . 比如:
 @echo .  %~n0 -auto -np
 :end

 ENDLOCAL
 @echo .
 if "%2" NEQ "-np" @pause

uninstall.bat

 @echo off  

 rem 修改控制台颜色
 color 1d  

 rem * 使用JavaService卸载TestTimerService服务的脚本
 rem *
 rem * JavaService - Windows NT Service Daemon for Java applications
 rem * Copyright (C) 2006 Multiplan Consultants Ltd. LGPL Licensing applies
 rem * Information about the JavaService software is available at the ObjectWeb
 rem * web site. Refer to http://javaservice.objectweb.org for more details.  

 rem 开始批处理文件中环境改动的本地化操作，在使用endlocal后环境将恢复到原先的内容
 SETLOCAL  

 rem 设置环境变量
 SET BASE_PATH=D:\Java_Study\windowsservice

 rem 设置JavaService的路径
 set JSBINDIR=%BASE_PATH%\JavaService_2_0_10-amd64
 set JSEXE=%JSBINDIR%\JavaService.exe

 rem 卸载服务前先停止服务
 net stop TestTimerService  

 rem 设置执行命令行
 set runcmd="%JSEXE%" -uninstall TestTimerService  

 %runcmd%  

 @echo .  

 ENDLOCAL
 @echo .
 if "%2" NEQ "-np" @pause  

整理后的目录结构为：

使用JavaService.exe部署Java服务并启动服务：

运行ｉｎｓｔａｌｌ．ｂａｔ

运行过程中，如果正行，ｃｍｄ屏幕信息如下：

安装目录结构变化：

停止并卸载服务：

运行ｕｎｉｎｓｔａｌｌ．ｂａｔ．

运行过程中，如果正行，ｃｍｄ屏幕信息如下：

参考文章：《【JavaService】部署Java jar为Windows后台服务 http://blog.csdn.net/alibert/article/details/49944721》

《JavaService将jar发布为windows 服务  http://blog.csdn.net/alibert/article/details/49944823》