自定义 Generate POJOs.groovy

一、Generate文件

 import com.intellij.database.model.DasTable
 import com.intellij.database.model.ObjectKind
 import com.intellij.database.util.Case
 import com.intellij.database.util.DasUtil

 import java.sql.Date

 /*
  * Available context bindings:
  *   SELECTION   Iterable<DasObject>
  *   PROJECT     project
  *   FILES       files helper
  */

 packageName = "com.sample;"

 typeMapping = [
         (~/(?i)tinyint|smallint|mediumint/)      : "Integer",
         (~/(?i)int/)                             : "Integer",
         (~/(?i)bool|bit/)                        : "Boolean",
         (~/(?i)float|double|decimal|real/)       : "Double",
         (~/(?i)datetime|timestamp|date|time/)    : "Date",
         (~/(?i)blob|binary|bfile|clob|raw|image/): "InputStream",
         (~/(?i)number/)                          : "Integer",
         (~/(?i)/)                                : "String"
 ]

 FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
   SELECTION.filter { it instanceof DasTable && it.getKind() == ObjectKind.TABLE }.each { generate(it, dir) }
 }

 def generate(table, dir) {
   def className = javaClassName(table.getName(), true)
   def fields = calcFields(table)
   //当是maven项目的时候，需要解开下面的注释
 //  packageName = getPackageName(dir)
   new File(dir, className + ".java").withPrintWriter { out -> generate(out, className, fields, table) }
 }

 def generate(out, className, fields, table) {
   out.println "package $packageName"
   out.println ""
   out.println "import javax.persistence.*;"
   out.println "import java.io.Serializable;"
   out.println "import com.fasterxml.jackson.annotation.JsonIgnore;"
   out.println "import io.swagger.annotations.ApiModel;"
   out.println "import io.swagger.annotations.ApiModelProperty;"
   out.println "import lombok.Data;"
   out.println "import org.hibernate.annotations.DynamicInsert;"
   out.println "import org.hibernate.annotations.DynamicUpdate;"
   out.println "import org.springframework.data.jpa.domain.support.AuditingEntityListener;"

   Set types = new HashSet()

   fields.each() {
     types.add(it.type)
   }

   if (types.contains("Date")) {
     out.println "import java.util.Date;"
     out.println "import org.springframework.data.annotation.LastModifiedDate;"
     out.println "import org.springframework.data.annotation.CreatedDate;"
   }

   if (types.contains("InputStream")) {
     out.println "import java.io.InputStream;"
   }
   out.println ""
   out.println "/**\n" +
           " * @Description: \n" +
           " * @Date: Created in" + new java.util.Date().toString() +"\n"+
           " * @Author: Cenobitor\n" +
           " * @Modified By:\n" +
           " */"
   out.println "@Data"
   out.println "@Entity"
   out.println "@DynamicInsert"
   out.println "@DynamicUpdate"
   out.println "@EntityListeners(AuditingEntityListener.class)"
   out.println "@ApiModel(value=\"\",description=\"\")"
   out.println "@Table ( name =\"" + table.getName() + "\" )"
   out.println "public class $className  implements Serializable {"
   out.println ""
   out.println genSerialID()
   fields.each() {
     out.println ""
     // 输出注释
     if (isNotEmpty(it.commoent)) {
       out.println "\t/**${it.commoent}*/"
     }

     if (it.annos != "") out.println "   ${it.annos}"
     // 输出成员变量
     out.println "\tprivate ${it.type} ${it.name};"
   }
   out.println ""
   out.println "}"
 }

 def calcFields(table) {
   DasUtil.getColumns(table).reduce([]) { fields, col ->
     def spec = Case.LOWER.apply(col.getDataType().getSpecification())

     def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
     def comm = [
             colName : col.getName(),
             name    : changeStyle(javaName(col.getName(), false), true),
             type    : typeStr,
             commoent: col.getComment(),
             annos   : "\t@Column(name = \"" + col.getName() + "\" )"]
     if ("id".equals(Case.LOWER.apply(col.getName()))){
       comm.annos = "\t@Id\n"
       //自增主键需要
       comm.annos += "\t@GeneratedValue(strategy = GenerationType.IDENTITY)"
     }
     if ("create_time".equals(Case.LOWER.apply(col.getName()))){
       comm.annos += "\n\t@CreatedDate"
     }
     if ("update_time".equals(Case.LOWER.apply(col.getName()))){
       comm.annos += "\n\t@LastModifiedDate"
     }
     fields += [comm]
   }
 }

 // 处理类名（这里是因为我的表都是以t_命名的，所以需要处理去掉生成类名时的开头的T，
 // 如果你不需要那么请查找用到了 javaClassName这个方法的地方修改为 javaName 即可）
 def javaClassName(str, capitalize) {
   def s = str.split(/[^\p{Alnum}]/).collect { def s = Case.LOWER.apply(it).capitalize() }.join("")
   // 去除开头的T  http://developer.51cto.com/art/200906/129168.htm
   s = s[1..s.size() - 1]
   capitalize ? s : Case.LOWER.apply(s[0]) + s[1..-1]
 }

 def javaName(str, capitalize) {
   def s = str.split(/(?<=[^\p{IsLetter}])/).collect { Case.LOWER.apply(it).capitalize() }
           .join("").replaceAll(/[^\p{javaJavaIdentifierPart}]/, "_")
   capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
 }

 def isNotEmpty(content) {
   return content != null && content.toString().trim().length() > 0
 }

 static String changeStyle(String str, boolean toCamel) {
   if (!str || str.size() <= 1)
     return str

   if (toCamel) {
     String r = str.toLowerCase().split('_').collect { cc -> Case.LOWER.apply(cc).capitalize() }.join('')
     return r[0].toLowerCase() + r[1..-1]
   } else {
     str = str[0].toLowerCase() + str[1..-1]
     return str.collect { cc -> ((char) cc).isUpperCase() ? '_' + cc.toLowerCase() : cc }.join('')
   }
 }

 static String genSerialID() {
   return "\tprivate static final long serialVersionUID =  " + Math.abs(new Random().nextLong()) + "L;";
 }

二、自动生成的实体类

 package com.sample;

 import javax.persistence.*;
 import java.io.Serializable;
 import com.fasterxml.jackson.annotation.JsonIgnore;
 import io.swagger.annotations.ApiModel;
 import io.swagger.annotations.ApiModelProperty;
 import lombok.Data;
 import org.hibernate.annotations.DynamicInsert;
 import org.hibernate.annotations.DynamicUpdate;
 import org.springframework.data.jpa.domain.support.AuditingEntityListener;
 import java.util.Date;
 import org.springframework.data.annotation.LastModifiedDate;
 import org.springframework.data.annotation.CreatedDate;

 /**
  * @Description:
  * @Date: Created inWed Nov 06 17:08:23 CST 2019
  * @Author: Cenobitor
  * @Modified By:
  */
 @Data
 @Entity
 @DynamicInsert
 @DynamicUpdate
 @EntityListeners(AuditingEntityListener.class)
 @ApiModel(value="",description="")
 @Table ( name ="t_staff_role" )
 public class StaffRole  implements Serializable {

     private static final long serialVersionUID =  2663305203216589678L;

     /**自增ID*/
        @Id
     @GeneratedValue(strategy = GenerationType.IDENTITY)
     private Integer id;

     /**角色名*/
        @Column(name = "role_name" )
     private String roleName;

     /**备注*/
        @Column(name = "remark" )
     private String remark;

     /**创建人*/
        @Column(name = "create_user" )
     private String createUser;

     /**创建时间*/
        @Column(name = "create_time" )
     @CreatedDate
     private Date createTime;

     /**修改人*/
        @Column(name = "update_user" )
     private String updateUser;

     /**更新时间*/
        @Column(name = "update_time" )
     @LastModifiedDate
     private Date updateTime;

     /**是否删除   0否 1 是*/
        @Column(name = "is_deleted" )
     private String isDeleted;

 }