五、u-boot 启动流程---u-boot.lds

6.1 u-boot.lds  链接脚本分析

　　uboot 编译出来的第一个链接脚本就是执行 u-boot.lds 链接脚本，去掉里面无用的和没有定义的，进行分析。

 /* 配置头文件，自动生成的，包含芯片SOC 相关的头文件 */
 #include <config.h>
 /* 主要是做一些 32位 和64 位的适配定义 */
 #include <asm/psci.h>
 /* 输出格式为 elf32-littlearm， */
 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
 OUTPUT_ARCH(arm)    /* 输出架构为 ARM */
 /* 用来指定整个程序的入口地址，所谓入口地址就是整个程序的开头地址，可以认为就是整个程序的第一句指令。有点像C语言中的main。 */
 ENTRY(_start)        /* _start 就是汇编的起始函数 */
 /* SECTIONS 就是整个链接脚本的指定 */
 SECTIONS
 {
     /*  指定程序的链接地址有2种方法：一种是在Makefile中ld的flags用-Ttext 0x20000000来指定；
         第二种是在链接脚本的SECTIONS开头用.=0x20000000来指定。
         两种都可以实现相同效果。这两种技巧是可以共同配合使用的，也就是说既在链接脚本中指定也在ld flags中用-Ttext来指定。两个都指定以后以-Ttext指定的为准。
         uboot的最终链接起始地址就是在Makefile中用-Ttext 来指定的，注意 TEXT_BASE 变量。最终来源是 Makefile 中配置对应的命令中，在make xxx_config时得到的。
         若没有配置，则由此处指定*/
     . = 0x00000000;

     . = ALIGN();    /* 4字节对齐 */

     /* 代码段 */
     /* 在代码段中，必须注意文件的排列顺序，这些顺序会影响编译的时候这些 .o 文件在生成的u-boot.bin 中的排列顺序 */
     /* 指定必须放在前面部分的那些文件就是那些必须安排在前4KB内的文件，这些文件中的函数在前4KB会被调用。在后面第二部分（4KB之后）中调用的程序，前后顺序就无所谓了。 */
     .text :
     {
         /* 映像文件赋值起始地址，它在文件 arch/arm/lib/sections.c 中定义：
         * char __image_copy_start[0] __attribute__((section(".__image_copy_start")));*/
         *(.__image_copy_start)
         /* arch/arm/lib/vectors.S 里有一句：.section ".vectors"  */
         /* 这里的 vectors 是让 vector.S 链接的二进制文件的开头部分 */
         *(.vectors)
         CPUDIR/start.o (.text*)        /* 执行 start.S */
         *(.text*)    /* 其他代码 */
     }

     . = ALIGN();
     .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }    /* 只读数据段 */

     . = ALIGN();
     .data : {            /* 普通数据段，即可读写数据段 */
         *(.data*)
     }

     . = ALIGN();

     . = .;

     /* 在u-boot的linker_list.h中通过宏定义，让编译器在编译阶段生成了一些顺序链表.u_boot_list*，链接阶段顺序存放到这个.u_boot_list节中。 */
     /* u-boot启动过程中，会从这个节读取模块驱动，命令行支持的命令等。 */
     . = ALIGN();
     .u_boot_list : {
         KEEP(*(SORT(.u_boot_list*)));
     }

     . = ALIGN();

     /* UEFI 段 */
     .__efi_runtime_start : {
         *(.__efi_runtime_start)
     }

     .efi_runtime : {
         *(efi_runtime_text)
         *(efi_runtime_data)
     }

     .__efi_runtime_stop : {
         *(.__efi_runtime_stop)
     }

     .efi_runtime_rel_start :
     {
         *(.__efi_runtime_rel_start)
     }

     .efi_runtime_rel : {
         *(.relefi_runtime_text)
         *(.relefi_runtime_data)
     }

     .efi_runtime_rel_stop :
     {
         *(.__efi_runtime_rel_stop)
     }
     /* UEFI 段结束地方 */

     . = ALIGN();

     .image_copy_end :
     {
         *(.__image_copy_end)
     }

     /* .rel_dyn* 段 */
     /* .rel_dyn_start，.rel.dyn和.rel_dyn_end提供了程序的重定位支持 */
     /* 重定位：
     　　　　在老的uboot中，如果我们想要uboot启动后把自己拷贝到内存中的某个地方，只要把要拷贝的地址写给TEXT_BASE即可，
     　　　　然后boot启动后就会把自己拷贝到TEXT_BASE内的地址处运行，在拷贝之前的代码都是相对的，不能出现绝对的跳转，否则会跑飞。
     　　　　在新版的uboot里，TEXT_BASE的含义改变了。它表示用户要把这段代码加载到哪里，通常是通过串口等工具。
     　　　　然后搬移的时候由uboot自己计算一个地址来进行搬移。
     　　　　新版的uboot采用了动态链接技术，在lds文件中有__rel_dyn_start和__rel_dyn_end，这两个符号之间的区域存放着动态链接符号，
     　　　　只要给这里面的符号加上一定的偏移，拷贝到内存中代码的后面相应的位置处，就可以在绝对跳转中找到正确的函数。*/
     .rel_dyn_start :
     {
         *(.__rel_dyn_start)
     }

     .rel.dyn : {
         *(.rel*)
     }

     .rel_dyn_end :
     {
         *(.__rel_dyn_end)
     }

     .end :
     {
         *(.__end)
     }

     _image_binary_end = .;

     /*
      * Deprecated: this MMU section is used by pxa at present but
      * should not be used by new boards/CPUs.
      */
      /* MMU 表项 */
     . = ALIGN();
     .mmutable : {
         *(.mmutable)
     }

 /*
  * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
  * __bss_base and __bss_limit are for linker only (overlay ordering)
  */
     /* bss 段，.bss节包含了程序中所有未初始化的全局变量 */
     /* 由链接指令(OVERLAY)可见，.bss_start与__rel_dyn_start，.bss与__bss_base，.bss_end与__bss_limit是重叠的。*/
     .bss_start __rel_dyn_start (OVERLAY) : {
         KEEP(*(.__bss_start));
         __bss_base = .;
     }

     .bss __bss_base (OVERLAY) : {
         *(.bss*)
          . = ALIGN();
          __bss_limit = .;
     }

     .bss_end __bss_limit (OVERLAY) : {
         KEEP(*(.__bss_end));
     }

     /* 其他段，这些节都是在编译链接时自动生成的，主要用于动态链接或调试使用： */
     .dynsym _image_binary_end : { *(.dynsym) }    /* 动态符号表`dynamic symbol`，但与`.symtab`不同，`.dynsym`只保存动态链接相关的符号，而`.symtab`通常保存了所有的符号； */
     .dynbss : { *(.dynbss) }    /* 动态未初始化数据表`dynamic bss`; */
     .dynstr : { *(.dynstr*) }    /* 动态字符串表`dynamic string`，用于保存符号名的字符串表; */
     .dynamic : { *(.dynamic*) }    /* 保存了动态链接所需要的基本信息，例如依赖哪些共享对象，动态链接符号表的位置，动态链接重定位表的位置，共享对象初始化代码的地址等； */
     .plt : { *(.plt*) }            /* 程序连接表`Procddure Linkage Table`，是实现动态链接的必要数据； */
     .interp : { *(.interp*) }    /* 解释器`interpreter`的缩写 */
     .gnu.hash : { *(.gnu.hash) }
     .gnu : { *(.gnu*) }
     .ARM.exidx : { *(.ARM.exidx*) }
     .gnu.linkonce.armexidx : { *(.gnu.linkonce.armexidx.*) }
     /*.gnu.hash .gnu .ARM.exidx`和`.gnu.linkonce.armexidx`是针对`arm`体系专门生成的段，用于调试时函数调用的`backtrace`，如果不需要调试，则可以不用这两段。 */
 }

6.2 其他

　　在 u-boot 的编译过程中会生成 3 个符号表文件：

• u-boot.map
• u-boot.sym
• System.map

　　可以通过查看 .uboot.cmd 显示 uboot 编译链接的数据：

 cmd_u-boot := arm-linux-ld.bfd   -pie  --gc-sections -Bstatic  --no-dynamic-linker -Ttext 0x0 -o u-boot
             -T u-boot.lds arch/arm/cpu/arm920t/start.o --start-group
             arch/arm/cpu/built-in.o
             arch/arm/cpu/arm920t/built-in.o
             arch/arm/lib/built-in.o
             board/samsung/common/built-in.o
             board/samsung/jz2440/built-in.o
             cmd/built-in.o  common/built-in.o
             disk/built-in.o  drivers/built-in.o
             drivers/dma/built-in.o
             drivers/gpio/built-in.o
             drivers/i2c/built-in.o
             drivers/mtd/built-in.o
             drivers/mtd/nand/built-in.o
             drivers/mtd/onenand/built-in.o
             drivers/mtd/spi/built-in.o
             drivers/net/built-in.o
             drivers/net/phy/built-in.o
             drivers/pci/built-in.o
             drivers/power/built-in.o
             drivers/power/battery/built-in.o
             drivers/power/domain/built-in.o
             drivers/power/fuel_gauge/built-in.o
             drivers/power/mfd/built-in.o
             drivers/power/pmic/built-in.o
             drivers/power/regulator/built-in.o
             drivers/serial/built-in.o
             drivers/spi/built-in.o
             drivers/usb/common/built-in.o
             drivers/usb/dwc3/built-in.o
             drivers/usb/emul/built-in.o
             drivers/usb/eth/built-in.o
             drivers/usb/gadget/built-in.o
             drivers/usb/gadget/udc/built-in.o
             drivers/usb/host/built-in.o
             drivers/usb/musb-new/built-in.o
             drivers/usb/musb/built-in.o
             drivers/usb/phy/built-in.o
             drivers/usb/ulpi/built-in.o
             env/built-in.o
             fs/built-in.o
             lib/built-in.o
             net/built-in.o
             test/built-in.o
             test/dm/built-in.o
             --end-group arch/arm/lib/eabi_compat.o  arch/arm/lib/lib.a -Map u-boot.map;
             true

　　-pic和-pie ，一个用于动态库的位置无关，一个用于动态可执行文件的位置无关。

　　-Ttext 用于指定指定链接的起始地址

　　-T u-boot.lds指定了链接使用的脚本文件，实际上，在这个脚本文件的.text节开始前同样也指定了起始地址：