（转）光照模型及cg实现

经典光照模型（illumination model）

物体表面光照颜色由入射光、物体材质，以及材质和光的交互规律共同决定。

由于环境光给予物体各个点的光照强度相同，且没有方向之分，所以在只有环境光的情况下，同一物体各点的明暗程度均一样。

环境光是对光照现象的最简单抽象，局限性很大。它仅能描述光线在空间中无方向并均匀散布时的状态。

还有一种是平行光，即光线都从同一个方向照射。通过模拟方向光和物体表面的交互模式，可以渲染出具有高真实感（明暗变化、镜面反射等）的三维场景。

漫反射与Lambert 模型

粗糙的物体表面向各个方向等强度地反射光，这种等同地向各个方向散射的现象称为光的漫反射（diffuse reflection）

对于仅暴露在环境光下的朗伯反射体，可以用公式(9-1)表示某点处漫反射的光强：

其中Ia表示环境光强度（简称光强），dk(0<dk<1)为材质对环境光的反射系数，Iam是漫反射体与环境光交互反射的光强。

当方向光照射到朗伯反射体上时，漫反射光的光强与入射光的方向和入射点表面法向夹角的余弦成正比，这称之为Lambert 定律，并由此构造出Lambert漫反射模型：

I是点光源强度，θ是入射光方向与顶点法线的夹角，称为入射(0≤θ ≤90°)

若N 为顶点单位法向量，L 表示从顶点指向光源的单位向量（注意，是由顶点指向光源，不要弄反了），则cosθ 等价于N 与L 的点积。所以公式(9-2)可以表示为公式(9-3)：

综合考虑环境光和方向来，Lambert 光照模型可写为：

漫反射渲染

漫反射光照模型顶点着色程序（使用结构体）

1. struct VertexIn
2. {
3. float4 position : POSITION;
4. float4 normal : NORMAL;
5. };
6. struct VertexScreen
7. {
8. float4 oPosition : POSITION;
9. float4 color : COLOR;
10. };
11. void main_v(VertexIn posIn,
12. out VertexScreen posOut,
13. uniform float4x4 modelViewProj,
14. uniform float4x4 worldMatrix,
15. uniform float4x4 worldMatrix_IT,
16. uniform float3 globalAmbient,
17. uniform float3 lightPosition,
18. uniform float3 lightColor,
19. uniform float3 Kd)
20. {
21. posOut.oPosition = mul(modelViewProj, posIn.position);
22. float3 worldPos = mul(worldMatrix, posIn.position).xyz;
23. float3 N = mul(worldMatrix_IT, posIn.normal).xyz;
24. N = normalize(N);
25. //计算入射光方向
26. float3 L = lightPosition - worldPos;
27. L = normalize(L);
28. //计算方向光漫反射光强
29. float3 diffuseColor = Kd*lightColor*max(dot(N, L), 0);
30. //计算环境光漫反射光强
31. float3 ambientColor = Kd*globalAmbient;
32. posOut.color.xyz = diffuseColor+ambientColor;
33. posOut.color.w = 1;
34. }

镜面反射与Phong 模型

Lambert 模型较好地表现了粗糙表面上的光照现象，但表现不出光泽，主要原因是该模型没有考虑这些表面的镜面反射效果。

Phong Bui Tuong 提出一个计算镜面反射光强的经验模型，称为phong模型，认为镜面反射的光强与反射光线和视线的夹角相关，其数学表达如公式(9-5)所示：

k 为材质的镜面反射系数， Ns是高光指数，V表示从顶点到视点的观察方向， R代表反射光方向。

高光指数反映了物体表面的光泽程度。Ns越大，反射光越集中，当偏离反射方向时，光线衰减的越厉害，只有当视线方向与反射光线方向非常接近时才能看到镜面反射的高光现象，此时，镜面反射光将会在反射方向附近形成亮且小的光斑； Ns越小，表示物体越粗糙，反射光分散，观察到的光斑区域小，强度弱。

反射光的方向R 可以通过入射光方向L（从顶点指向光源）和物体法向量N求出：

phong 模型渲染

phong 光照模型的顶点着色程序实现

1. struct VertexIn
2. {
3. float4 position : POSITION; // Vertex in object-space
4. float4 normal : NORMAL;
5. };
6. struct VertexScreen
7. {
8. float4 oPosition : POSITION;
9. float4 color : COLOR;
10. };
11. void main_v( VertexIn posIn,
12. out VertexScreen posOut,
13. uniform float4x4 modelViewProj,
14. uniform float4x4 worldMatrix,
15. uniform float4x4 worldMatrix_IT,
16. uniform float3 globalAmbient,
17. uniform float3 eyePosition,
18. uniform float3 lightPosition,
19. uniform float3 lightColor,
20. uniform float3 Kd,
21. uniform float3 Ks,
22. uniform float shininess)
23. {
24. posOut.oPosition = mul(modelViewProj, posIn.position);
25. float3 worldPos = mul(worldMatrix, posIn.position).xyz;
26. float3 N = mul(worldMatrix_IT, posIn.normal).xyz;
27. N = normalize(N);
28. //计算入射光方向、视线方向、反射光线方向
29. float3 L = normalize(lightPosition - worldPos);
30. float3 V = normalize(eyePosition - worldPos);
31. float3 R = 2*max(dot(N, L), 0)*N-L;
32. R = normalize(R);
33. // 计算漫反射分量
34. float3 diffuseColor = Kd * globalAmbient+Kd*lightColor*max(dot(N, L), 0);
35. //计算镜面反射分量
36. float3 specularColor = Ks * lightColor*pow(max(dot(V, R), 0), shininess);
37. posOut.color.xyz = diffuseColor + specularColor;
38. posOut.color.w = 1;
39. }

phong 光照模型片段着色实现的结构体

1. struct VertexIn
2. {
3. float4 position : POSITION;
4. float4 normal : NORMAL;
5. };
6. struct VertexScreen
7. {
8. float4 oPosition : POSITION;
9. float4 objectPos : TEXCOORD0;
10. float4 objectNormal : TEXCOORD1;
11. };

首先将几何顶点的模型空间坐标转换为用于光栅化的投影坐标；然后将顶点模型坐标和法向量模型坐标赋值给绑定TEXCOORD 语义词的变量，用于传递到片段着色程序中。

phong 光照模型顶点着色程序

1. void main_v(VertexIn posIn,
2. out VertexScreen posOut,
3. uniform float4x4 modelViewProj)
4. {
5. posOut.oPosition = mul(modelViewProj, posIn.position);
6. posOut.objectPos = posIn.position;
7. posOut.objectNormal = posIn.normal;
8. }

phong 光照模型片段着色程序

1. void main_f( VertexScreen posIn,
2. out float4 color : COLOR,
3. uniform float4x4 worldMatrix,
4. uniform float4x4 worldMatrix_IT,
5. uniform float3 globalAmbient,
6. uniform float3 eyePosition,
7. uniform float3 lightPosition,
8. uniform float3 lightColor,
9. uniform float3 Kd,
10. uniform float3 Ks,
11. uniform float shininess)
12. {
13. float3 worldPos = mul(worldMatrix, posIn.objectPos).xyz;
14. float3 N = mul(worldMatrix_IT, posIn.objectNormal).xyz;
15. N = normalize(N);
16. //计算入射光方向、视线方向、反射光线方向
17. float3 L = normalize(lightPosition - worldPos);
18. float3 V = normalize(eyePosition - worldPos);
19. float3 R = 2*max(dot(N, L), 0)*N-L;
20. R = normalize(R);
21. // 计算漫反射分量
22. float3 diffuseColor = Kd * globalAmbient+Kd*lightColor*max(dot(N, L), 0);
23. //计算镜面反射分量
24. float3 specularColor = Ks * lightColor*pow(max(dot(V, R), 0), shininess);
25. color.xyz = diffuseColor + specularColor;
26. color.w = 1;
27. }

Blinn-Phong 光照模型

phong光照模型中，必须计算V • R的值，其中R为反射光线方向单位向量，V 为视线方向单位向量，但是在Blinn-phong光照模型中，用N • H 的值取代了V • R。Blinn-phong光照模型公式为：

H 是“光入射方向L 和视点方向V 的中间向量”，通常也称之为半角向量。

Blinn-phong 模型片段着色程序

1. void main_f(VertexScreen posIn,
2. out float4 color : COLOR,
3. uniform float4x4 worldMatrix,
4. uniform float4x4 worldMatrix_IT,
5. uniform float3 globalAmbient,
6. uniform float3 eyePosition,
7. uniform float3 lightPosition,
8. uniform float3 lightColor,
9. uniform float3 Kd,
10. uniform float3 Ks,
11. uniform float shininess)
12. {
13. float3 worldPos = mul(worldMatrix, posIn.objectPos).xyz;
14. float3 N = mul(worldMatrix_IT, posIn.objectNormal).xyz;
15. N = normalize(N);
16. //计算入射光方向/视线方向/半角向量
17. float3 L = normalize(lightPosition - worldPos);
18. float3 V = normalize(eyePosition - worldPos);
19. float3 H = normalize(L + V);
20. // 计算漫反射分量
21. float3 diffuseColor = Kd * globalAmbient+Kd*lightColor*max(dot(N, L), 0);
22. //计算镜面反射分量
23. float3 specularColor = Ks * lightColor*pow(max(dot(N, H), 0), shininess);
24. color.xyz = diffuseColor + specularColor;
25. color.w = 1;
26. }

http://blog.csdn.net/doctorsc/article/details/6287059?reload