pureMVC简单示例及其原理讲解四(Controller层)

本节将讲述pureMVC示例中的Controller层。

Controller层有以下文件组成：

• AddUserCommand.as
• DeleteUserCommand.as
• ModelPrepCommand.as
• ViewPrepCommand.as
• StartupCommand.as

AddUserCommand 。顾名思义，它是添加用户命令。让我们首先看看代码。

1. package com.superwulei.controller
2. {
3. import com.superwulei.model.UserProxy;
4. import com.superwulei.model.vo.UserVO;
5. import mx.controls.Alert;
6. import org.puremvc.as3.interfaces.INotification;
7. import org.puremvc.as3.patterns.command.SimpleCommand;
8. public class AddUserCommand extends SimpleCommand
9. {
10. override public function execute(notification:INotification):void
11. {
12. var user:UserVO = notification.getBody() as UserVO;
13. var userProxy:UserProxy = facade.retrieveProxy(UserProxy.NAME) as UserProxy;
14. if(user.isValid){
15. userProxy.addItem(user);
16. }else{
17. Alert.show("请检查用户名和密码");
18. }
19. }
20. }
21. }

AddUserCommand是一个单一命令（SimpleCommand），自定义SimpleCommand必须继承SimpleCommand并重写execute方法。execute方法表示这个命令的执行。曾经在上一篇《pureMVC简单示例及其原理讲解——View层 》中提到的添加用户的逻辑代码，应该在这里编写。还记得上一篇中提到的“View层本身不处理各种操作，但是发送通知”么？

上一篇中发送通知的代码

sendNotification(ApplicationFacade.USER_ADD,userForm.user);

拿出这段代码是特意的想说明AddUserCommand的execute方法中的notification.getBody()其实就是userForm.user，严谨的说应该是userFrom.user作为参数传到execute方法中来。如此我们在这里通过userProxy.addItem(user)就实现了用户的添加。userProxy中的users就多了一个user。

DeleteUserCommand ，删除用户命令。代码如下，与添加用户道理一样，不多言。

1. package com.superwulei.controller
2. {
3. import com.superwulei.model.UserProxy;
4. import com.superwulei.model.vo.UserVO;
5. import org.puremvc.as3.interfaces.INotification;
6. import org.puremvc.as3.patterns.command.SimpleCommand;
7. public class DeleteUserCommand extends SimpleCommand
8. {
9. override public function execute(notification:INotification):void
10. {
11. var user:UserVO = notification.getBody() as UserVO;
12. var userProxy:UserProxy = facade.retrieveProxy(UserProxy.NAME) as UserProxy;
13. userProxy.deleteItem(user);
14. }
15. }
16. }

ModelPrepCommand、ViewPrepCommand分别是Model层注册和View层注册。说道注册就要道一道。在pureMVC中，一切总控制是facade，因此无论是Proxy、Mediator还是Command都要在facade中注册。上面四个Command全部为SimpleCommand，最后一个StartupCommand为MacroCommand（复合命令）。StartupCommand包含了多个SimpleCommand，通过addSubCommand方法添加了子命令，并在之后在facade上注册了AddUserCommand和DeleteUserCommand。

1. package com.superwulei.controller
2. {
3. import com.superwulei.model.UserProxy;
4. import org.puremvc.as3.interfaces.INotification;
5. import org.puremvc.as3.patterns.command.SimpleCommand;
6. public class ModelPrepCommand extends SimpleCommand
7. {
8. override public function execute(notification:INotification):void
9. {
10. /* 注册Model */
11. facade.registerProxy(new UserProxy());
12. }
13. }
14. }

1. package com.superwulei.controller
2. {
3. import com.superwulei.view.UserFormMediator;
4. import com.superwulei.view.UserListMediator;
5. import org.puremvc.as3.interfaces.INotification;
6. import org.puremvc.as3.patterns.command.SimpleCommand;
7. public class ViewPrepCommand extends SimpleCommand
8. {
9. override public function execute(notification:INotification):void
10. {
11. var app:MyPureMVCdemo = notification.getBody() as MyPureMVCdemo;
12. /* 注册View */
13. facade.registerMediator(new UserFormMediator(app.userForm));
14. facade.registerMediator(new UserListMediator(app.userList));
15. }
16. }
17. }

1. package com.superwulei.controller
2. {
3. import com.superwulei.ApplicationFacade;
4. import org.puremvc.as3.patterns.command.MacroCommand;
5. public class StartupCommand extends MacroCommand
6. {
7. override protected function initializeMacroCommand():void{
8. addSubCommand(ModelPrepCommand);
9. addSubCommand(ViewPrepCommand);
10. /* 注册添加、删除用户命令 */
11. facade.registerCommand(ApplicationFacade.USER_ADD,AddUserCommand);
12. facade.registerCommand(ApplicationFacade.USER_DELETE,DeleteUserCommand);
13. }
14. }
15. }

通过使用facade的registerCommand就好象添加一个监听器一样，当有sendNotification发送出来的时候，就会有对应的Command的execute方法被执行。

Controller层包含的应该是整个应用程序的逻辑业务。