map实现

/*PLSQL实现Map*/

--建立序列
create sequence seq_map_param_id ;
--建立参数表
create table map_param(id number primary key , tname varchar2(30)) ;
--初始化
insert into map_param values (seq_map_param_id.nextval , 'EMP') ;
insert into map_param values (seq_map_param_id.nextval , 'DEPT') ;

CREATE OR REPLACE PACKAGE BODY utl_map_2 is
PROCEDURE output_map (p_in_tname VARCHAR2,p_in_idx_col_name VARCHAR2 DEFAULT '') IS
tb_count number ;
l_col_type user_tab_cols.DATA_TYPE%type;
main_sql varchar2(32767);
BEGIN
--各种判断
--表是否存在
select count(*) into tb_count from user_tables where table_name=p_in_tname ;
if tb_count = 0 then
raise_application_error(-20999,'Table not found') ;
end if ;
--列是否存在，map key column类型是否正确
begin
select data_type into l_col_type
from user_tab_cols col
where col.TABLE_NAME=p_in_tname
and col.COLUMN_NAME=p_in_idx_col_name ;
if l_col_type not in ('VARCHAR2') then
raise_application_error(-20999,'idx column only varchar2');
end if ;
exception
when no_data_found then
raise_application_error(-20999,'Column not found in table '||p_in_tname) ;
end ;

--example:declare cursor cur is select * from EMP ; begin for rec in cur loop utl_var_2.EMP_list(rec.ENAME) := rec ; end loop ; end;
main_sql := 'declare ' ||
'cursor cur is select * from '||p_in_tname||' ; ' ||
'begin ' ||
'for rec in cur loop ' ||
'utl_var_2.'||p_in_tname||'_list(rec.'||p_in_idx_col_name||') := rec ; '||
'end loop ; '||
'end;' ;
execute immediate main_sql ;
--dbms_output.put_line(main_sql) ;

END ;
PROCEDURE var_init is
pkg_dec_sql varchar2(32767) ;
CURSOR param_cur is select * from map_param ;
begin
pkg_dec_sql := 'create or replace package utl_var_2 is ' ;
for rec in param_cur loop
pkg_dec_sql := pkg_dec_sql || 'type t_'||rec.tname||' is table of '||rec.tname||'%rowtype index by varchar2(4000) ; '||
rec.tname||'_list t_'||rec.tname||' ; ' ;
end loop ;
/*
example :
create or replace package utl_var_2 is
type t_EMP is table of EMP%rowtype index by varchar2(4000);
EMP_list t_EMP;
type t_DEPT is table of DEPT%rowtype index by varchar2(4000);
DEPT_list t_DEPT;
end;
*/
pkg_dec_sql := pkg_dec_sql || ' end ; ';
execute immediate pkg_dec_sql ;
end var_init ;
END utl_map_2 ;

SQL> begin
2 utl_map_2.output_map(p_in_tname => 'DEPT', p_in_idx_col_name => 'LOC');
3 dbms_output.put_line('deptno : '||utl_var_2.dept_list('NEW YORK').deptno ||' loc : ' ||utl_var_2.dept_list('NEW YORK').loc ) ;
4 end ;
5 /

deptno : 10 loc : NEW YORK

PL/SQL procedure successfully completed

SQL> begin
2 utl_map_2.output_map(p_in_tname => 'EMP', p_in_idx_col_name => 'ENAME');
3 dbms_output.put_line('ename : '||utl_var_2.emp_list('SMITH').ename ||' job : ' ||utl_var_2.emp_list('SMITH').job ) ;
4 end ;
5 /

ename : SMITH job : CLERK

PL/SQL procedure successfully completed

不过每次配置后的时候需要手动重新执行以下初始化程序 utl_map_2.var_init

--map方法
MAP方法用于将对象实例映射为标量数值(number，date,varchar2等)。
对于相同对象类型不同对象实例来说，因为他们的数据类型是复合数据类型，所以对象实例之间不能直接进行比较。
为了排序多个对象实例的数据，可以在建立对象类型时定义MAP方法。
注意：一个对象类型最多只能定义一个MAP方法，并且MAP方法和ORDER方法不能同时使用。

CREATE OR REPLACE TYPE person_typ4 AS OBJECT
(
name VARCHAR2(10),
gender VARCHAR2(2),
birthdate DATE,
MAP MEMBER FUNCTION getage RETURN VARCHAR2
)
;

CREATE OR REPLACE TYPE BODY person_typ4 IS
MAP MEMBER FUNCTION getage RETURN VARCHAR2
IS
BEGIN
RETURN TRUNC((SYSDATE-birthdate)/365);
END;
END;
/

CREATE TABLE employee_tab4(
eno NUMBER(6),person person_typ4,
sal NUMBER(6,2),job VARCHAR2(10)
);

INSERT INTO employee_tab4(eno,sal,job,person)
VALUES(1,1500,'图书管理员',person_typ4('玛丽','女','11-1月-76'));
INSERT INTO employee_tab4(eno,sal,job,person)
VALUES(2,2000,'高级焊工',person_typ4('王明','男','11-5月-75'));
INSERT INTO employee_tab4(eno,sal,job,person)
VALUES(3,2500,'高级工程师',person_typ4('黎明','男','11-5月-70'));

DECLARE
TYPE person_table_type IS TABLE OF person_typ4;
person_table person_table_type;
v_temp VARCHAR2(100);
BEGIN
SELECT person BULK COLLECT INTO person_table
FROM employee_tab4;
IF person_table(1).getage()>person_table(2).getage() THEN
v_temp:=person_table(1).name||'比'||person_table(2).name||'大';
ELSE
v_temp:=person_table(1).name||'比'||person_table(2).name||'小';
END IF;
dbms_output.put_line(v_temp);
END;