CDS标准视图：功能位置描述 I_FunctionalLocationText

• 视图名称：功能位置描述 I_FunctionalLocationText
• 视图类型：基本视图
• 视图代码：

点击查看代码

@EndUserText.label: 'Functional Location - Text'
@ObjectModel.dataCategory: #TEXT
@VDM.viewType: #BASIC
@AbapCatalog: { sqlViewName: 'IFLOCTEXT', preserveKey }
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck:#CHECK
@ObjectModel.representativeKey: 'FunctionalLocation'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@Metadata.ignorePropagatedAnnotations: true

@Analytics: {
  dataExtraction: {
    enabled: true,
    delta.changeDataCapture.automatic
    }
    }
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET]

define view I_FunctionalLocationText
  as select from iflotx
  association [0..1] to I_FunctionalLocation as _FunctionalLocation on _FunctionalLocation.FunctionalLocation = $projection.FunctionalLocation
  association [0..1] to I_Language           as _Language           on _Language.Language = $projection.Language
   -- Extension, do not expose as association:
  association [0..1] to E_FunctionalLocation as _FunctionalLocationExtension on _FunctionalLocationExtension.FunctionalLocation = $projection.FunctionalLocation
{

      @ObjectModel.foreignKey.association: '_FunctionalLocation'
  key iflotx.tplnr               as FunctionalLocation,

      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key iflotx.spras               as Language,

      @Semantics.text: true
      @EndUserText.label: 'Description'
      iflotx.pltxt               as FunctionalLocationName,

      iflotx.kzmla               as IsPrimaryLanguage,

      iflotx.kzltx               as FuncnlLocHasLongText,

      @Semantics.systemDateTime.lastChangedAt: true
      iflotx.textchangeddatetime as LastChangeDateTime,

      // Propagate association
      _FunctionalLocation,
      _Language
}

• 事务代码：IL03/IH06
  
  功能位置描述

• 视图结构：

字段名称	设备名称
功能位置	FUNCTIONALLOCATION
语言	LANGUAGE
描述	FUNCTIONALLOCATIONNAME
主要语言	ISPRIMARYLANGUAGE
长文本	FUNCNLLOCHASLONGTEXT
时戳	LASTCHANGEDATETIME