批处理BAT替换与截取字符串的用法t1=%a:~3%是什么意思

在bat编写中，我们经常越到t1=%a:~3%之类的代码，这里简单介绍下用法，需要的朋友可以参考下:

一、替换用法 

例 

@echo off
set a=belcome to CMD borld!
set temp=%a:b=w%
echo %temp%
pause 

将显示 welcome to CMD world! 即用w替换了变量a中的b。

二、截取用法 

字符串最前面的光标所在处表示第0位，第一个字符后面的光标所在表示第一位，依次类推。 
为了更好的理解截取用法，下面给出了字符串superhero位数的相关示意图： 
s u p e r h e r o

0 1 2 3 …… -3 -2 -1 无表示

例 

@echo off
set a=superhero
set temp=%a:~0,5%
echo %temp%
pause 

将显示super 即显示了变量a的第0位至第5位中包括的所有元素。

若如下

@echo off
set a=superhero
set temp=%a:~3%
echo %temp%
pause 

将显示erhero 即显示了变量a的第三位以后的所有字符。

若如下

@echo off
set a=superhero
set temp=%a:~-3%
echo %temp%
pause 

将显示ero 即显示了变量a的倒数三个字符。

若如下

@echo off
set a=superhero
set temp=%a:~0,-3%
echo %temp%
pause 

将显示superh 即显示了变量a的第0位和第-3位中间包含的所有字符。

bat截取字符串实例

@echo off
set str=123456789
echo 第一个字符为：%str:~0,1%
echo 头两个字符为：%str:~0,2%
echo 头5个字符为：%str:~0,5%
echo 去掉最后一个字符后的字符串为：%str:~0,-1%
echo 去掉最后3个字符后的字符串为：%str:~0,-3%
echo 第4个字符为：%str:~3,1%
echo 第4个及其之后的3个字符为：%str:~3,4%
echo 最后一个字符为：%str:~-1%
echo 最后一个字符为：%str:~-1,1%
echo 最后两个字符为：%str:~-1,2%
echo 倒数第4个字符为：%str:~-4,1%
echo 倒数第4个及其之后的字符为：%str:~-4%
echo 倒数第4个及其之后的1个字符为：%str:~-4,2%
echo 倒数第4个及其之后的2个字符为：%str:~-4,3%
pause

为了说明这个问题,我在这里把批处理取字符,做下进一步的解释,希望对新手有所启发
如下:
echo %var:~n,k% 
我们在这里对每个参数做个说明:"%var",即我们要从中要截取字符的字符串." ~ "取字

符标志符(我是这么理解的),"n" 我们将其理解为指针,"k"我们将其理解为偏移地址.(注

:指针和偏移地址都是从零开始数的)
我们还是用namejm版主的例子做下说明:

@echo off
set str=123456789
rem 定义一个str字符串为123456789
echo 第一个字符为：%str:~0,1%
rem 指针为0,偏移地址为1,即从第0位开始,取1位
echo 头两个字符为：%str:~0,2%
rem 指针为0,偏移地址为2,即从第0位开始,取2位
echo 头5个字符为：%str:~0,5%
rem  指针为0,偏移地址为5,即从第0位开始,取5位
echo 去掉最后一个字符后的字符串为：%str:~0,-1%
rem 当"k"为负值时,我们可以这样理解:从指针开始处开始取其后面所有字符,然后减去
后面"abs(k)位"..所以这个句字我们可以做如下解释:从第0位开始取其全部字符
为:123456789然后从后面减去abs(k)位,所以最后结果为:12345678
echo 去掉最后3个字符后的字符串为：%str:~0,-3%
rem  该句解释同上↑
echo 最后一个字符为：%str:~-1%
rem  参数"n,"和"k"都可以为缺省,缺省"n,"时可以理解为:从abs(k)位开始取其全部
echo 倒数第4个及其之后的字符为：%str:~-4%
rem        解释同上↑
echo 最后一个字符为：%str:~-1,1%
rem  n为负值时,表示从后面开始截取字符,取k位(此时n应从1开始数)
echo 最后一个字符为：%str:~-1,2%
rem  解释同上↑
echo 倒数第4个字符为：%str:~-4,1%
rem  解释同上↑
echo 倒数第4个及其之后的1个字符为：%str:~-4,2%
rem  解释同上↑
echo 倒数第4个及其之后的2个字符为：%str:~-4,3%
rem 解释同上↑
pause