用mel编写自定义节点的属性编辑器界面

用mel编写自定义节点的属性编辑器界面比较麻烦，而且网上例子又少，下面给出一个范例，说明基本的格式

// 初始化节点时调用
global proc initControl(string $attrName)
{
    // 传进来的参数是节点属性名，使用这个方法获得节点名称
	string $nodeName = `plugNode $attrName`;
	setUITemplate -pst "attributeEditorTemplate";
		button -label "Compute Weight" -c ("cageDeform -init -name " + $nodeName) computeWeightButton;		
	setUITemplate -ppt;
}

// 修改节点时（例如点击另一个同类节点）调用
// 此函数的目的是对按钮绑定的命令做相应修改，使其能应用于相应节点
global proc modifyControl(string $attrName)
{
    // 当attrName = “cageDeformer1.noAttr”
// plugNode 命令能够提取节点名字cageDeformer1
	string $nodeName = `plugNode $attrName`;
	print $nodeName;
	button -e -c ("meshControl -init -name " + $nodeName) computeWeightButton;
}
 
// 函数名同文件名一样，同节点名cageDeformer对应
global proc AEcageDeformerTemplate(string $nodeName)
{
	editorTemplate -beginScrollLayout;	
        // 新建一个卷展栏	
		editorTemplate -beginLayout "Weight Scheme" -collapse false;
            // addControl自动指定合适类型的控件
			editorTemplate -addControl "maxNeighbourNum";
			editorTemplate -addControl "weightPower";
            // 在指定的时机调用前面的函数
			editorTemplate -callCustom "initControl" "modifyControl" "noAttr";	
		editorTemplate -endLayout;
		
		editorTemplate -suppress "outMesh";
		editorTemplate -suppress "inControlMesh";
		editorTemplate -suppress "refMesh";
		editorTemplate -suppress "refControlMesh";
		
		editorTemplate -beginLayout "Node Behavior" -collapse true;
			editorTemplate -addControl "nodeState";
			editorTemplate -addControl "caching";
		editorTemplate -endLayout;

		editorTemplate -addExtraControls;	
	editorTemplate -endScrollLayout;
}

下面是-callCustom的文档解释

Specifies that at this point in the template when building the dialog, the procedure specified by the first argument is to be called to create some UI objects when a new node type is edited. The procedure specified by the second argument is to be called if an attribute editor already exists and another node of the same type is now to be edited. The replacing procedure should connect any controls created by the creating procedure to the equivalent attributes in the new node. A list of zero or more attributes specifies the attributes which the two procedures will involve. The procedures should have the signature:

proc AEcustomNew(string attributeName1, string attributeName2)

The number of attributes specified in the call should correspond to the number of attributes in the procedure signature.

来源： <http://download.autodesk.com/us/maya/2010help/Commands/editorTemplate.html#flagcallCustom>

来自为知笔记(Wiz)